Today lets tackle a very familiar problem. You have a bunch of very long, complicated file names & paths. Your boss wants a list of files extracted from these paths, like below:
Of course nothing is impossible. You just need correct ingredients.
I cannot help you with a strong cup of coffee, so go and get it. I will wait…
Back already? well, lets start the formula magic then.
Extracting file name from a path
If you observe the file paths carefully, to extract the file name, we need to know,
- Position of last \ in the full path text
Of course there are many methods find where the last \ is. You can find a very excellent summary of these techniques in our formula forensics #21 – finding the 4th slash.
Today, let us see a new technique (well, sort of).
Finding the position of last \ using formulas
Before writing any formula, first let me clarify the only assumption:
- File path is in cell B4
Now, last \ is nothing but first \ when read from right.
Read that line again.
Got it? Good, lets move on.
How do we find the first \ from right?
If we can list down all individual characters from path right to left, then we just have to find the first \ in that.
Listing down individual characters from a given text
To get 5th character from text in B4, we can use MID formula like this:
=MID(B4,5,1)
Suppose you want both 5th and 6th characters from B4, you can use:
=MID(B4,{5,6},1)
This formula returns an array of 5th and 6th characters from the text in B4.
Cool, extending the logic, =MID(B4, {6,5},1) would give 6th & 5th characters in B4.
Idea!
If we can replace {6,5} with decreasing numbers starting from length of text B4 all the way to 1, then we can list all characters in B4, right to left.
But this leads us to next problem – listing numbers from a specific value (length of B4) to 1 in descending order.
Listing numbers from n to 1 in that order
We can use ROW() formula to generate sequence of numbers like this:
=ROW(1:10) will give {1,2,3…,10}
note: this returns an array, so you need to use it with Ctrl+Shift+Enter
So if we can use =ROW(1:LEN(B4)) we could get numbers from 1 to length of text in B4 {1,2….LEN(B4)}
Unfortunately this will not work as 1:LEN(B4) is not a valid reference.
But we can fix that with INDIRECT, like this:
=ROW(INDIRECT(“1:” & LEN(B4)))
Tip: INDIRECT formula lets you construct a reference by using values in other cells as shown above.
Alternative: You can also use OFFSET to get the same result like this: =ROW(OFFSET($A$1,,,LEN(B4))). More on OFFSET here.
But wait…
So far, we have only generated numbers from 1 to n. But we need numbers from n to 1.
No sweat, we just subtract the numbers {1,2…n} from n+1 to get the list {n,n-1,n-2….2,1}
Like this:
=LEN(B4)+1 – ROW(INDIRECT(“1:” & LEN(B4)))
Using these numbers to list characters in file path in reverse order
Take a sip of that coffee, its getting cold!
Now, lets integrate our numbers in to MID like this:
=MID(B4, LEN(B4)+1 – ROW(INDIRECT(“1:” & LEN(B4))), 1)
The blue portion gives you numbers {n…2,1}
The orange portion gives you letters from right to left.
But we wanted the last \
Oh right. We do not need these letters from right to left. We instead want to find the last \ in our file path. So now we just ask Excel where the first \ is in this reversed text.
=MATCH(“\”, MID(B4, LEN(B4)+1 – ROW(INDIRECT(“1:” & LEN(B4))), 1), 0)
Blue portion gives you letters in reverse order
Orange portion finds the first \ in that.
Tip: Learn more about MATCH formula.
Extract the file name
Once you know where the last \ is, finding the file name is easy.
use =MID(B4, position_of_last_slash + 1, LEN(B4))
We need to +1 because we do not want the slash in our file name.
Demo of the entire formula in action
Okay, lets see all these steps in action in one go.
How to find the extension?
Extension is few letters added at the end of file to indicate its type. For example, excel files usually have xls, xlsx, xlsm as extension.
So how to find this extension?
Extension & file name are separated by a dot .
But often file name itself can have a dot.
In other words, Extension is text in the file name followed by last dot.
Sounds like same problem as finding the last \ and extracting file name. So I will skip the details.
But assuming the file name is in D4, extension can be found with =RIGHT(D4,MATCH(“.”,MID(D4,LEN(D4)-ROW(INDIRECT(“1:”&LEN(D4))),1),0))
NOTE on both formulas
Both file name & extension formulas are array formulas. This means after typing them, you need to press Ctrl+Shift+Enter to see correct result.
Bonus tip: Getting the file names & path from a folder
If you ever want to list down all files in a folder use this.
- Open command prompt (Start > Run > Cmd or Start > Cmd)
- Go to the folder using CD
- Type DIR /s/b >files.csv
- Close command prompt
Now you can see all the files in that folder in files.csv. Double click on it to open in Excel and run your magic 🙂
Download Example workbook
Click here to download the example workbook. The file uses slightly different formulas. But works just the same. Examine it and learn more.
How do you extract file names & as such?
Do you use formulas or do you rely on some other technique to extract portions of text like file names, mail addresses etc. Please share your tips & ideas using comments.
Extract often? You will dig this.
Analysts life is filled with 3 Es – extraction, exploration & explanation. And like a good assistant, Excel helps you in all 3.
If you find yourself with a shovel, bucket and boat load of data often, you are going to enjoy these articles:
41 Responses to “Calculate Elapsed Time in Excel [Quick Tips]”
Hi Chandoo,
To calculate time lapses in excel I usually use the DATEDIF function. Even though is undocumented by MS there is a great explanation of its use in Chip Pearson's site :
http://www.cpearson.com/excel/datedif.aspx
Is pretty easy to use and has great flexibility.
See you and keep Excelling!!!
Another great article, I will be linking to it on my blog.
Oliver:
Yes, I think that DATEDIFF do it better.
Great post! This a fantastic tutorial on calculating elapsed time in Excel that could be helpful even to a novice user. Keep up the useful tips!
Also, the Office community on Facebook could really benefit from you knowledge! Check it out at http://www.facebook.com/office
Cheers,
Andy
MSFT Office Outreach Team
hi, Chandoo !!!
for elapsed time , we can use this unique formula either for hours, minutes or seconds : NOW()-A1)
but using respective special number formats
for hours : [h] ==> 46553
for minutes : [m] ==>2793212
for seconds : [s] ==> 167592763
We can also use mean duration for years (orbital period of the Earth around the Sun : i-e tropical year) which is : 365.25 days
and mean duration for month : 365.25/12 days
be Excelent !!!!
@Oliver... Thanks for the pointer to datediff(). I will update the post with information about this as well.
@Glen... thanks for the linklove 🙂
@Andy... Welcome. Thanks for telling us about the office community on FB.
@Modeste ... that is very cool. I will remember these formatting codes for an upcoming article on number formatting codes 🙂
Great tip Chandoo! I use the formula to calculate years elapsed all the time. It can seriously help save a ton of time with calculations. Also, NETWORKDAYS is one that helps and can seriously impress a boss. Keep up the great work here!
No problem! I will definitely be directing people with tough Excel questions to your blog. Keep up the great posts!
Andy
MSFT Office Outreach Team
Hi,
always great posts and a good way to start my day
but regarding the elapsed time calculations: have you never noticed that there is a result difference between using =TODAY()-A1 and using =NETWORKDAYS(A1,TODAY())?
try it for A1= a Monday such as 21sep09 and "today" is e.g. a Thursday; you get 3 or 4 respectively as a result, depending on the formula used; this is because formula =networkdays() always includes both the startdate and the end date and not only the time between these 2.
This is easily corrected/compensated bij always adding a -1 to the =networkdays() formula because the majority of us will count startday as day 0 and then the result will be consistent across the different formulas.
However, you then get into trouble if you calculate the networkdays for a date further in the past and where either the start or end date falls in a weekend.
just thought to point this out as to me these formula's are not interchangeable just like that!
have a great day!
Paul
=DATEDIF([DOJ],TODAY(),"Y") & " Y, " & DATEDIF([DOJ],TODAY(),"YM") & " M, " & DATEDIF([DOJ],TODAY(),"MD") & " D"
This will fix your 30 Days problem
I calculated the time diff between two date+ times by subtracting 2 cells & custom formatted it to "d hh:mm" format.
E.g.
Cell A1 04-Jan-12 6:00 PM
Cell A2 05-Jan-12 4:45 PM
Cell A3 0 22:45 (formula: =A1-A2)
Wat shud i do 2 not display the "zero" values i.e. no. of days in this case is zero hence the cell shud display " 22: 45" and not "0: 22: 45".
@Amol
Try the Custom Format code:
[
<1] hh:mm ; [>=1] d “d” hh:mmHi Chandoo,
If possible to compute the interval of time and date in one column.
In column C I would like to compute the total days and hours . What formula ? Please help
Example.
Column A Column B
2/13/12 3:30 AM 2/14/12 12:00 AM
In referenc to Elapsed time in months
To calculate the elapsed time in months, we can use the formula =(NOW()-A1)/30. This returns the value in 30 day months.
I use to apply formula =ROUND((TODAY()-A1)/30,0). Today, I faced a peculiar situation, A1 has date 01-Mar-2009, and today being 01-Mar-2012, it should be 36 months, but it is showing 37 months!!
Any suggestions to avoid such errors?
Regards,
Prasad DN
All I want to do is add up a series of times and receive a reply that gives me a total. What I used to do was subtrace the end time from the start time and format the result as [hh]:mm but this doesn't seem to work anymore. How has Bill Gates confounded me?
@Pete
I use Excel 2010 and it still works
The times must be entered as times in the format hh:mm:ss or hh:mm without seconds
Adding up times is as simple as =Sum(Range) or =Sum(A2:A10)
then using a Custom Number format as you have mentioned [h]:mm
If this isn't working, 2 ideas
1. Check your times are times and not text
2. Can you share your data or file with us?
My hospital tracks times from patient arrival to various procedures or treatments. When those times cross over midnight, the regular formulas (2nd time minus first time) don’t work because the result is negative and Excel (2007) won’t show a negative number in time format.
I couldn’t find a solution here (chandoo.org) but found one elsewhere that worked and it’s very simple. I would like to share it.
Assuming 1st time in A1 (column for patient arrival time) (11:00 PM), and 2nd time in B1 (column for x-ray given) (12:30 AM)). Should be 1:30 elapsed time.
=B1-A1+(B1<A1) [This comparison is the key to the solution.]
=12:30 AM – 11:00 PM + (12:30 AM < 11:00 PM)
=0.0208 – 0.9583 + (True)
=-0.9375 + (1) [This is the key! If it is false, Excel adds 0. If it’s true, Excel adds 1 and that is what corrects the negative number. Now Excel can interpret the number as a time.]
=0.0625
Converted to hh:mm = 1:30
I wrapped this formula inside an IFERROR one to alert my data entry person if she messed up and applied it to lots of different columns and it has worked wonderfully. No more complaints from the data entry person who just plugs in times from medical charts.
Very interesting solution. Thank you so much for sharing it with all of us.
HI,
I am working on a Xl application..
I want to capture time between two clicks.
Ex, in my application during run somewhere I press OK button and then I click Cancel.. I want to measure time between these two clicks... Is it possible??
Pls help on this...
@shashidhar
The answer is Yes
You will have to add an appropriate VBA event to start and stop a timer.
There are techniques which can time to the millisecond so maybe look those up on the net
WOW!!!!!! I truly love your excel time format program! WHOOOO! I am very interested in how the time formats "update" (manually on a physical keyboard) that "updates" the time into its respective decimal time formats, such as:
YYYY.yyyy, HH.hhh, etc...
How do those formulas or equations work if not in Excel mode? Example: TI calculators, Word, or any other computer language programming? Just wanted to see how it works. E-mail me at Ultra64848689Ti@gmail.com.
Thanks again for an EXCELLENT Excel program into decimal time formats!
Here's an idea: how about creating an APP for iOS and Android? Just wanted to point that out. =-D
Regarding the elapsed time in months:
I made this function to determine the time elapsed since a date using the number of days in each respective month. It's a simple subtraction and I think it works very well:((Year Today-Year A1)*12++(Month Today - Month A1)+(Day Today/Days in Month Today)-Days A1/Days in month A1)
Here's the function:
=((YEAR(TODAY())-YEAR(A1))*12)+(MONTH(TODAY())-MONTH(A1))+(DAY(TODAY())/DAY(DATE(YEAR(TODAY()),MONTH(TODAY())+1,0))-DAY(A1)/DAY(DATE(YEAR(A1),MONTH(A1)+1,0)))
Have a Merry Christmas everyone!!
I need the ability to calculate how much progress we have made between two dates and I want to represent that as a percentage.
I am thinking this would be a combination of today, networkdays & dividing the days elapsed vs the total days. Then it should be as easy as formatting my cell. Any help would be greatly appreciated.
@Christian
Your correct
dates are just numbers and so you can use simple math to derive the percentage
=(Date Now-Start Date)/(End date-Start date)
that will give you a number between 0 and 1
which you can format as a %'age
is there a way out to calculate the productivity for an employee
The day start is at 08:00 and day end is 20:00
The start date / time is recorded and end date / time is recorded
I want to calculate the timelapse taking into consideration the day begin and dayend time.
If the work begins and ends the same day, a simple formula b1-a1 would compute the productivity.
But if the process remains incomplete and is carried over to the next day, then timelines to be computed accordingly
to clarify,
if start time of an activity is 03/15/2015 18:00 hrs and end time is 03/16/2015 11:00 hrs, then the resultant formula should be 5 hrs (ie 18:00 to 20:00 hrs on day1 + 08:00 to 11:00 hrs on day2) ie 2+3
please guide.
Venkatesh, try (b1-a1)-0.5
This will subtract the fixed amount of time between shifts, 12 hours. If the time between shifts varies, then you could reference other cells that contain the variables.
Please help. when I use the networking days formula I get a date (2-may-00) I want actual number of days. I managing projects and I need to know how many days have passed since we received a project to the current date. Please help Thanks
@Aria: Just format the cell as general or number. that will fix the problem.
You rock! I looked at 17 other sites and they all did not work. Yours did. Thanks!
Hi folks ...
calculating age in years , months and days
=text(now()-a1,"yy")&" y " &text(now()-a1,"mm")-1 &" m "&text(now()-a1,"dd") & " d"
Hi, the Elapsed time in days [ =TODAY()-A1 ] works great however, if I do not have a date in A1, it shows 42157. Anyway to get it to display 0 or a Null value?
@Dan
=If(A1="",0,TODAY()-A1)
I get #NAME? and the formula does not work.
Hi Chandoo,
This might be a challenge - I am looking to calculate elapsed time between two columns
Start date Complete date
9/9/2015 7:21 10/2/2015 11:01
I need to take into account the following:
1) The employee works 7:00-3:15 pm each day
2) Std Work hours are 7hrs 45 min each day
3) Need to take into account all holidays in between start and end date
4) Work week is Mon through Friday.
Can you help?
Thanks!
Hi, i have a certain name (wilium) in column A and against this name i have 2 option, 1 Done and 2 Inprogress. i want that i count done again wilium and count inprogress against wilium separately. which formula will work for it??
Hi, i have a certain name (wilium) in column A and against this name i have 2 option, 1 Done and 2 Inprogress in column C. i want that i count done again wilium and count inprogress against wilium separately. which formula will work for it??
Year, month, day results for DoB.
The formulas I have found on the net and the datedif function do not work. This is what I came up with using a Microsoft support paper dated April 1997 with some modifications:
IF(OR(A2>$A$1,ISBLANK(A2)),"",IF(YEAR($A$1)=YEAR(A2),0,IF(MONTH($A$1)>=MONTH(A2),YEAR($A$1)-YEAR(A2),YEAR($A$1)-YEAR(A2)-1))&" years "&MONTH($A$1)-MONTH(A2)+IF(AND(MONTH($A$1)<=MONTH(A2),DAY($A$1)<DAY(A2)),11,IF(AND(MONTH($A$1)=DAY(A2)),12,IF(AND(MONTH($A$1)>MONTH(A2),DAY($A$1)=DAY(A2),ABS(DAY($A$1)-DAY(A2)),DAY(EOMONTH(A2,0))-DAY(A2)+DAY($A$1))&" days")
Check it out...
Hi, Augustin
what about :
calculating age in years , months and days
=YEAR(NOW()-DoB)-1900 & " y " & MONTH(NOW()-DoB)-1 & " m " & DAY(NOW()-DoB) & " d"
Hi Chandoo,
I am looking for help with the elapse time formula. I have a recruitment tracking sheet where we track the number of days the positions are opened, and when they are finally closed.
The opened positions will have a running turnaround time (TAT) formula and I am using this formula:
=NETWORKDAYS (start_date, TODAY (), Holidays2018)
Now, without disrupting the running TAT formula, how do I then get the TAT to stop when we have a final end date? All the information below is row:
- start_date --> Cell A
- TODAY () --> cell B
- end_date --> Cell C
Hope you are able to help. Thanks!
Interesting question. Try this:
Thank you for this helpful article. I was trying for days now to figure it out. Now the only issue I have is that if I do not have a value inputed for =TODAY()-[@[Date Precured]] Date Precured then it shows 44055. How can I get it to leave it blank if there is no data? Thanks again!!!