Office 365 now boasts a powerful successor to the VLOOKUP function – XLOOKUP formula. Think of XLOOKUP as VLOOKUP 2.0. In this article, learn all about the function, syntax, optional parameters and 13 xlookup examples.
What is XLOOKUP?
XLOOKUP is the newest member of Excel lookup function family. You may already know its siblings – VLOOKUP, HLOOKUP, INDEX+MATCH, LOOKUP etc.
XLOOKUP allows us to search for an item in a range (or table) and return matching result. In a way, it is similar to VLOOKUP, but offers so much more.
When using XLOOKUP, you just provide 3 basic parameters (and 3 more optional parameters) and Excel does the rest.
- The value you are looking for
- The list where this value should be found
- The list from which you want the result
- [optional] value if not found
XLOOKUP example:
=XLOOKUP(“Jamie”, Sales[Sales Person], Sales[Net Sales])
Returns [Net Sales] for Jamie if the name exists in [Sales Person] column.
If you compare this with VLOOKUP, then you see that we no longer need to specify column_number or true/false to perform the search.
This also means, unlike VLOOKUP, XLOOKUP can actually look anywhere in the data and find the result, not just on the left.
No more complex INDEX+MATCH formulas or weird VLOOKUP concoctions.
How is XLOOKUP better?
- XLOOKUP makes the most used formula in Excel straight forward and less error prone. You just write =XLOOKUP(what you want to find, the list, the result list) and boom, you get the answer (or #N/A error if the value is not found)
- Looks up exact match by default: One of the annoyances of VLOOKUP is that you must mention FALSE as last parameter to get correct result. XLOOKUP fixes that by doing exact matches by default. You can use match mode parameter to change the lookup behavior if you want.
- 4th parameter to support value not found scenario In most business situations, we are forced to wrap our lookup formulas with IFERROR or IFNA formulas to suppress errors. XLOOKUP offers 4th parameter (read more about it below) so you can tell what default output you want if your value is not found.
- XLOOKUP offers optional parameters to search for special situations. You can search from top or bottom, you can do wild card searches and faster options to search sorted lists.
- It returns reference as output, not the value. While this may not mean much for normal users, pro Excel user’s eyes light up when they discover a formula that can return refs. That means, you can combine XLOOKUP outputs in innovative ways with other formulas.
- It is so much cooler to type, you just type =XL. I am not sure if this is a happy coincidence, but saying =XL to get this formula is just awesome.
XLOOKUP Syntax
Simple case:
=XLOOKUP(what you want to look, lookup list, result list)
=XLOOKUP("Jackie", sales[Sales Person], sales[Net Sales])
returns Jackie’s [Net Sales] if the name can be found in [Sales Person]
Optional parameters:
By default, you just need 3 parameters for XLOOKUP, as shown above. But you can also use 4th, 5th and 6th parameter to specify how you want the lookup to be done.
4th parameter for XLOOKUP: IF not found (no more IFERROR!!!)
The newly introduced XLOOKUP has an even newer feature. It now supports if not found option. This is the 4th parameter.
For example, use:
=XLOOKUP(“Chandoo”, sales[Sales Person], sales[Net Sales],”Value not found”) to return “Value not found” if the lookup value is not available in the search column – sales[Sales Person].
5th parameter for XLOOKUP: Match mode or type:
Use this to tell Excel how you want your MATCH to happen. The default is 0 (exact match) but you can also use these other options, shown below.
6th parameter for XLOOKUP: Match direction
Try this if you want to search from bottom to top. The default direction is top down (1).
XLOOKUP Introduction & Examples – Video
Here is a video that explains XLOOKUP in easy terms. Watch it below or go to my YouTube channel.
XLOOKUP replaces INDEX+MATCH
Since you can specify lookup column and return column as two parameters, XLOOKUP now replaces INDEX+MATCH combination. I haven’t used INDEX+MATCH for looking up in over a year now. If you want to understand this use case, check out below video or example file.
13 XLOOKUP examples to really understand it
My computer received XLOOKUP update just 90 minutes ago and I have been playing with it ever since. Here are 13 different, fun & creative examples to really understand it. Have a read. If you already have XLOOKUP, feel free to download the sample workbook and have a play.
For all of these examples, we will use the [Sales] table data shown below. XLOOKUP works just as well with cell references too, but I am using structural references for ease of understanding.
XLOOKUP Examples – Table
All the examples are listed in this table. Browse it and feel free to copy the formulas to test.
Note about references in the formula:
- Input or search values are in column H. The value used for searching is shown in first column. I used references rather than hardcoded values to make the formula relateable.
- Search is done against Sales Table as shown above.
| Criteria | Question | Answer | Formula | Notes |
|---|---|---|---|---|
| Jackie | What is the net sales? | 1610 | XLOOKUP(H5,sales[Sales Person],sales[Net Sales]) | Nice and simple. Finds H5 (Jackie) in the sales[Sales Person] list and returns macthing [Net Sales] if found. |
| 2133 | Whose sales are this? | Jamie | XLOOKUP(H6,sales[Net Sales],sales[Sales Person]) | This time, we lookup in the middle but return the name at front. Normally we would use INDEX+MATCH for something like this, but XLOOKUP just kills it. |
| Who has most sales? | Jamie | XLOOKUP(MAX(sales[Net Sales]),sales[Net Sales],sales[Sales Person]) | Of course, we can mix formulas too. MAX() finds the maximum sales and then XLOOKUP does the rest. Try other formulas like MIN(), SMALL(), LARGE() too. | |
| 8 | Who has this many customers? | Joseph | XLOOKUP(H8,sales[No. Customers],sales[Sales Person]) | Another example with find the middle, return from front. |
| 8 | Who is the last person to have this many customers? | Jamie | XLOOKUP(H9,sales[No. Customers],sales[Sales Person],,0,-1) | Now we are talking!!!, you can use the optional parameters for XLOOKUP to specify match type (0 is for exact match) and match direction (-1 is for bottom to top). |
| 1800 | Whose sales are closest to this number, but not more? | Jagjit | XLOOKUP(H10,sales[Net Sales],sales[Sales Person],"value not found",-1) | We can search for a value that is closest but not more by using match type -1. |
| Ju | What is the profit of person whose name begins with this? | 1023 | XLOOKUP(H11&"*",sales[Sales Person],sales[Profit / Loss],,2) | You can do wild card searches too. * for any number of letters and ? for single letter. |
| Who has least sales? | Jimmy | XLOOKUP(0,sales[Net Sales],sales[Sales Person],,1) | Time for a trick!!! When searching fields like [Net Sales] which will usually have just positive values, you can look for 0 with match type as 1 (next highest value). | |
| What is the sales for very last person? | 1415 | XLOOKUP("*",sales[Sales Person],sales[Net Sales],,2,-1) | Another trick! Search for "*" from end to get the last value's matching sales. | |
| Who is the very last person? | Karl | XLOOKUP("*",sales[Sales Person], sales[Sales Person],,2,-1) | Of course, you can search and return from the same column to find out the last person's name. | |
| Net Sales | What is H11 for Johnson? | 1540 | XLOOKUP("Johnson",sales[Sales Person],XLOOKUP(H15,sales[#Headers],sales)) | 2 way lookups by nesting XLOOKUP. Remember, inner XLOOKUP returns a list of [Net Sales] |
| Jamie | What is the Net Sales for second person with this name? | 2724 | XLOOKUP(H16&"2",FILTER(sales[Sales Person],sales[Sales Person]=H16)&SEQUENCE(3),FILTER(sales[Net Sales],sales[Sales Person]=H16)) | You can combine XLOOKUP with other new formulas like FILTER() to create something crazy and fun too. Try it yourself. |
| Chandoo | What is the net sales? | Value not found | XLOOKUP(H17,sales[Sales Person],sales[Net Sales],"Value not found") | And of course, when the data can't be found XLOOKUP simly #N/As. To prevent this, you can use the 4th parameter to specify output value. |
How can I get XLOOKUP?
You need Microsoft Office 365 to use XLOOKUP. You can purchase it from here.
I am using different version of Excel, Can’t get XLOOKUP…
Don’t beat yourself up if you can’t lay your hands on that sweet sweet XLOOKUP yet. Excel already has 100s of powerful functions to perform magic on your data. See below list for alternatives.
| Scenario | ? | XLOOKUP Alternative |
| Regular lookups | Use VLOOKUP or INDEX+MATCH | |
| Lookup in the middle, get value from elsewhere | Use INDEX+MATCH | |
| Get the last item (lookup from last) | Lookup last value trick | |
| Wild card lookups | VLOOKUP does wildcard search too | |
| Nearest value lookups | See this example | |
| 2-way lookups (lookup row & column intersection) | Use INDEX MATCH MATCH | |
| IF not found option | Use IFERROR |
Download XLOOKUP examples workbook
Click here to download the 13 XLOOKUP examples file. Kindly note that it will not work if you do not have XLOOKUP. So upgrade your office first.
Here is another Example workbook, this is used in the video above.
And one more example file, this with INDEX+MATCH replacements.
NEW
Mini Course by Chandoo on XLOOKUP & Other Lookups in Excel
As Excel evolves, many of the traditional ways to lookup and analyze data are now slow or unnecessary. That is why I created a 1 hour crash course to explain XLOOKUP & other lookup functions for data analysis work. Please consider purchasing this course to learn more (and support my mission).
Click here for details on XLOOKUP course.
Got XLOOKUP yet? Share your thoughts
Have you played with XLOOKUP yet? I have been using it for an year now and I am still excited everytime I type it. What about you? Please share your thoughts and creative uses of it in the comments section.
61 Responses to “What is XLOOKUP? 13 formula examples to really understand it”
Sure it's a nice new command. It would be useful if everyone had access to it. But if there is any chance you will be sharing the file with someone who has a onetime payment Office license, or an older version of Office you can't use it.
That is my biggest gripe with many new features MS is launching. With such vast userbase and existing spreadsheet "systems", all of these formulas are going to create more trouble than imagined. That said, we should learn new things, especially if you move to a new job chances are you will be using a different version of Excel there.
I love to learn new things, like this new command. But I can't afford, literally don't have the money, to keep paying for 365.
This is the thing that especially offends me about the Office 365 pricing scam/scheme. Sure, if they want to milk more money from users using the rental scam, fine I know I don't have to fall for it. But restricting new "features", like new commands to 365 is offensive. It makes one-time payment users "second class" customers, especially anyone who has paid for Office 2019. At least in the past new features/commands came only came out every few years, with new versions so there was some logic to the separation. But now the new features are coming every few months and there is no real separation between 2019 and 365, but still they limit the new features to 365. Even 2016 is close enough. MS "accidentally" pushes a few new features to 2016, when they feel like it or when they are too lazy to do the extra work to prevent them from going to 2016.
Yes, of course this is the latest and excellent update from Microsoft but this feature will take years to come in the market because most of the people or offices are still using Office 2007 or 2013.
Dear Chandoo Sir
Thank you for updating latest idea this idea is centralized lookup formula all about.
this idea is realy impressive and samart
I couldn't observe any benefit, over MATCH+INDEX.
Hmm, the base scenario is similar to index+match, but XLOOKUP makes life simple with single formula and default "exact match" setup. Plus I find the "lookup from last" and "less than" "greater than" options very useful and less cryptic than MATCH options.
Thanks for sharing, it added some excitement to my Friday morning! I don't have 365 but am still excited to be aware of the existence of these features! I know that vlookup on larger sets of data can really take up some resources--it makes sense, it's performing a lot of operations for us while we sit and sip on coffee. 😉 However, I'm wondering if you've you noticed a difference in performance with xlookup? Is it slower, faster, or pretty much the same in terms of calculation speed?
I haven't tested it against VLOOKUP or INDEX+MATCH. If anything, I would guess that the performance should be similar as they could all use same logic internally. I will try this and share some outcomes later.
I would love to know the results. We're crunching a ton of data and I love the simplicity of XLOOKUP, but we can't handle the sluggishness of VLOOKUP. I hope XL is faster!!!
I believe XLOOKUP has been written to deliver exact matches at the same speed as a binary (vlookup's approximate) search.
Here is a nice overview of differences in performance of different lookup formulas. Unexpected, but XLOOKUP is not always fastest.
https://professor-excel.com/performance-of-xlookup-how-fast-is-the-new-xlookup-vs-vlookup/?amp#What_is_the_8220binary_search_mode8221_of_XLOOKUP
You can use an if logic to wrap around a vlookup with a TRUE argument to speed up lookups.
A nice addition to the function list. Very usefull and easier to use then INDEX + MATCH.
Since XLOOKUP is in beta testing, it would be great if Microsoft development team added a 5th. argument: if_na. That is: if XLOOKUP returns #N/A, an alternate value could be returned instead. Therefore, it wouldn't be necessary to do =IFNA(XLOOKUP(...), value_if_na).
Good idea. But I feel this can be a dangerous precedent as no other formula in Excel has fail-safe option (other than IFERROR and IFNA ofcourse). So may be leave it to return error.
Don't overlook the new FILTER function. That has a final [if_empty] setting.
Although I don't have and expecting to be around soon in EXCEL 2019, my question is there a way to work around the new function "xlookup" but not the old ones.
However it is appreciated tip,thanks
Chandoo
You can also use XLookup like
=Sum(xlookup():Xlookup())
Refer the example 4 at:
https://support.office.com/en-us/article/xlookup-function-b7fd680e-6d10-43e6-84f9-88eae8bf5929?ui=en-US&rs=en-US&ad=US
This makes it hugely powerful as it is returning an address like Index can do
Great point Hui. I am yet to find a practical use case for summing between lookups, but I am pretty sure others will find this useful.
Here is an idea.
If you wish to analyse data for a given month, the relevant portion of the Sales table (sorted by date) is given by
= XLOOKUP( EOMONTH(month,0), EOMONTH(+sales[Date],0), sales,0,1 ) :
XLOOKUP( EOMONTH(month,0), EOMONTH(+sales[Date],0), sales,0,-1 )
which can be referred to as a named formula 'selected'. Being a reference to the original table, range intersection with columns works. Hence
= XLOOKUP( MAX(selected sales[Net Sales]),
selected sales[Net Sales], selected sales[Sales Person] )
provides an answer to
Who had most sales for February?
Caution: The formula requires 7 separate searches of the data but they are very fast.
I use VLOOKUP a lot with named ranges, are you able to reference those in XLOOKUP?
@Hamish... you should be able to use any reference styles that work with other formulas in XLOOKUP. So yes for names, structural, cell and references to other sheets / workbooks.
Hamish, Yes it all works perfectly. That includes cases in which the data table does not comprise raw data but rather is made up of dynamic arrays. Naming the anchor cell of each dynamic array allows expressions such as
= XLOOKUP( MAX(selectedNetSales#), selectedNetSales#, selectedSalesPerson# )
Conversely, if the returned field is comprised of anchor cells for separate dynamic lists (e.g. employment data for the specified salesman) then the list can be returned by adding '#'
=XLOOKUP(0,sales[Net Sales],EmployeeInfo,1)#
Since the documentation says it returns a reference array, could you write formulas that could answer questions that need to perform a function upon a result set that contains multiple rows such as:
1. What is the total Profit/Loss for SalesPersons named [Jamie]?
2. What is the MAX/MIN Net Sales for SalesPersons named [Jamie]?
3. What was the Average Net Sales for everyone that had exactly [8] Customers?
I think the answer to your question is 'no' unless you are willing to sort the table so that the records you wish to aggregate form a continuous range. That is, the formula
= SUM(
XLOOKUP(salesPerson,sales[Sales Person],sales[Profit / Loss],,,1):
XLOOKUP(salesPerson,sales[Sales Person],sales[Profit / Loss],,,-1))
only works if the data is sorted by Sales Person.
Otherwise it looks like SUMIFS (and similar) offers the best solutions with FILTER a close second.
= SUMIFS( sales[Profit / Loss], sales[Sales Person], salesPerson )
= SUM( FILTER(sales[Profit / Loss], sales[Sales Person]=salesPerson ) )
XLOOKUP allows us to look for a variable in a column and return a value from a row: combining VLOOKUP ad HLOOKUP in essence.
I watched a video last night in which the presenter showed an example that returned an error. The solution that the presented was using is this: =XLOOKUP(A4,B7:B9,C6:E6)
To see the problem in action, put a b c in the range B7:B9 and 1 2 3 in the range C6:E6 and in A4 enter a or b or c
I solved this problem in this way:
=XLOOKUP(A12,B15:B17,TRANSPOSE(C14:E14))
I have also set up a financial analysis example in which I wanted to find, for every line item in an income statement, which month was exactly equal to the mean of that row or which was immediately below the mean or immediately above it. Or Median, or Standard Deviation ...
I used XLOOKUP() and IFS() together with Data Validation (although that is optional) and while the formula is a little unwieldy, again I am effectively combining vertical and horizontal lookups.
Excellent find and tip Duncan 🙂
Hi,
Can you please tell me if there is any way to return multiple values with a single match.
Thanks in Advance
when will be in excel 2019
Thanks
Never.
"New features" like the XLookUp() command are only added to Office 365. They will never be added to Office 2019. They may show up in Office V-Next, when ever it comes out, in the near future. MS has not yet announced a new version. If they follow the pattern in the last few versions that would be fall 2021. But that is only a guess.
I have it now in office 2021
I downloaded your sample spreadsheet and three of your first seven examples are incorrect. Then I stopped.
Which version of Excel are you running? XLOOKUP doesn't work in any version except Office 365.
Hi, Chandoo.
Great tips, thanks!
In example #11, "What is the 'net sales' for Johnson? = 1540" the formula only takes into account the first match for Johnson (D10)?
In row 21 Johnson appears again so the correct answer should be 4192 (D10 + D21).
Imagine a DB with hundreds of records!
How can we deal with duplicates using XLOOKUP?
Thanks.
Is there an easy way to handle if the cell is blank in the data table to prove the result of a blank? With VLOOKUP, previously to get this result, I had to do:
=IF(VLOOKUP($B2,data,6,FALSE)="","",VLOOKUP($B2,data,6,FALSE))
I am hoping that I don't have to resort to the same lengthy format. I did try the "Value Not Found" example you provided (love it). However that is when the search value is not listed, not when the search value is found and the result value is a blank cell.
Thanks for everything you do!!!!
Hi Sherry,
Are you using the IF formula to show "" instead of 0 ?
If so, you can use this structure
=XLOOKUP($B$2, data[col1], data[col6]) & ""
This will force 0 to convert to empty space. It won't impact other results though, (assuming column 6 is text)
column 6 is a date.
A bit longer, but to force the 'value not found' you could remove the entry from the lookup array
= XLOOKUP(lookupValue,
IF(data[col6]"", data[col1]),
data[col6], "Missing data")
Hi Chandoo,
I've been waiting for this function for months so that I could replace all my INDEX / MATCH / MATCH statements. However, I have hit a snag with using nested XLOOKUPs as replacements. If the inner XLOOKUP can't find a value, then whatever value I specify as the [if not found] value causes the outer XLOOKUP to fail and return #VALUE. So the [if not found] functionality works if a single XLOOKUP can't find the search value, but it causes nested XLOOKUPs to fail. Can you see any way around that?
Thanks
Hey Stuart... Can you share an example of what result you are expecting in nested case? One option is to use a single IFERROR outside all the nested functions.
@Stuart
Do not limit yourself to thinking of [if_not_found] as being a text string, e.g. "Oops"; it can be a formula in its own right, returning a default row from the original table or even a lookup from an alternative table.
What it must return is an array in order to form a valid parameter for the outer XLOOKUP.
Hi Peter,
You've got it! As you suggest, by setting the inner XLOOKUP to return an array full of zeroes (or whatever) solves the problem. The outer XLOOKUP can of course just have 0, or whatever, stated its if_not_found value.
I am surprised that I haven't come across this issue or solution anywhere else. There are lots of blogs / videos which mention using nested XLOOKUPs as a replacement for INDEX / MATCH / MATCH. I can't say I've read or watched them all, but the ones I have don't mention this issue. I suspect there are / will be a lot of people getting #N/As or, worse, #VALUES depending on what they specify as the inner function's if_not_found.
Thanks for your help!
I am trying to lookup a date and name and return the number of hours from another worksheet? If I'm mixing text and dates, will this still work?
Great article. But,...two questions:
1) I do have Office 365. Yet, the XLookup is not recognized by Excel. Your sample file displays a #NAME? Why?
2) In your samplefile you have a leading '_xlfn.' in front of the formula. Why is that?
Hi Michael...
Can you confirm what is your current version of Excel is? Also see if you can update to newer version. You can do both from File > Account.
Great Job..
My values that I want to join are not exact, i.e.
000025868 and 0000258 68 Total
Is there a way to join the data?
Interesting. Assuming the space is in the lookup column, try this:
=xlookup("000025868", substitute(lookup_col, " ",""), result_col)
Getting a #N/A as the results.
Is there a way to convert "0000258 68 Total" to 000025868 (or visa versa) before I run the =XLOOKUP?
If you just want to remove the word "total" at the end, use SUBSTITUTE for that. If there can be other words, you are better off first running the data thru Power Query so you can clean it.
One thing that is possible is to take a numeric lookup value and convert it to text before searching a text lookup array. For example
= XLOOKUP(TEXT( value, "0000000\?00\*" ), array, return, , 2 )
will perform a search with wildcards that allow "Total" to be appended or any character to be inserted two digits before the end of the number.
That would pick up
"0000258 68 Total"
but you would need an alternative test to match the number 25868, itself.
Check the reference, while selecting data the xlookup function automatically starts from new line. Try changing it to the first row and it would work.
YOU ARE THE EXCEL KING!
Thank you
Hi Chandoo,
I have 2 sheets with 5 columns. data in columns A:C is similar except that changes are made in columns A and C. I want to lookup in column C in Sheet2 and update Sheet1 columns A:C.
for example
Sheet1
ColA ColB ColC
123 AB12 One
234 BC23
323 CB22 Six
Sheet2
ColA ColB ColC
123 AB12 One
234 BB22 Two
323 CB22 Six
I don't think we can claim that XLOOKUP "replaces" INDEX+MATCH. Yes, it provides a suitably powerful alternative, and is absolutely a full replacement for VLOOKUP and HLOOKUP, but it can't easily play some of the "math" games that are possible with INDEX+MATCH and sometimes even necessary when the data isn't in a convenient layout.
What if you needed the row above or below the match or if the data was laid out in repeating sections where you first needed to know the location of the section header and then the location of a given item within each section? Both of those problems can be solved with plus/minus shifting of the number returned from the MATCH.
So I would argue that INDEX+XMATCH are the true replacement for INDEX+MATCH, thus taking full advantage of the X -- defaulting to exact matches, virtual sorting, and so on -- while preserving the ability to "shift" the match as needed.
I'm looking for a price in a multiple column price list. With Vlookup, I specified the entire table and for the column, looked at the user selected model/column. In Xlookup, how to specify the column number and the range up and down or can I just specify the column number only?
One advantage that VLOOKUP retains over XLOOKUP is the ability to supply a lookup column number dynamically, as a purely numerical result of a calculation. To replicate this functionality using XLOOKUP, you would need seperate logic to calculate the column reference (i.e. the column's number, range name or range address) and pass it to the XLOOKUP formula. You could do this inside the XLOOKUP function by setting up the 3rd param of XLOOKUP to be based on your "user selected model/column".
Using Xlookup with "match mode" = -1 and "if not found" = "ABC"
Now if the lookup value is not found in the lookup_array excel gives the the highest value from the return_array.
This is not what I expect from xlookup.
It should return "ABC"
Can you explain why?
Chandoo,
I am having trouble with XLookUp. How do I get it to return multiple values such as employees with salary greater than $45,000 or to sum all the sales in the East region? Are these more pivot table inquires?
Is XLOOKUP more useful for finding one record than multiple records?
Thank you,
Jennifer Jeffords
Hi Chandoo,
Is it possible to use XLOOKUP to return a status such as "Checked" and "NoCheck"(something similar to IF stmt)
Thank you.
I used the index and match to look up the hourly rate for a job classification as a part of a drop down. Now, I want to calculate the hourly rate multiplied by hours worked and the cell will not calculate. What might be the problem? The results cell of the look-up is formatted to be currency?