Recently I posted about how you could construct dynamic (cascading) dropdowns that could easily handle multiple levels, like this:
…and we saw that users could subsequently change upstream dropdowns in a way that would make downstream choices invalid, like this:
In my previous post I used some VBA to clear out any ‘downstream’ choices if anything ‘upstream’ changed:
Updated for 2024:
Please see my latest article on Dependent Drop-downs using XLOOKUP to implement a simpler and scalable technique. It works great when you have two or multiple levels and can be expanded to an entire table column or sheet column.
A much simpler alternative
My sample file drew on Roger Govier’s excellent approach on the Contextures website, which used two dynamic named ranges to feed the data validation lists, one called MainList and one called SubList. Roberto commented that you could achieve pretty much the same thing with no VBA and with just one validation formula. His approach is pure genius!
Here’s a sample file that utilizes Roberto’s approach:
Click here to download the file
This approach uses a validation formula with a couple of relative references in it. Relative references look for cells that are some predetermined distance left/right and up/down from the active cell. Here’s his formula, which was entered into the Name Manager while cell B8 was selected:
=IF(ISBLANK(Sheet1!C8),IF(DataEntry[#Headers] Sheet1!B:B = DataEntry[[#Headers],[Main Category]],OFFSET(ValidationLists[[#All],[Main Categories]],1,,COUNTA(ValidationLists[Main Categories])),OFFSET(ValidationLists,0,MATCH(Sheet1!A8, ValidationLists[#Headers],0)-1,COUNTA(OFFSET(ValidationLists,,MATCH(Sheet1!A8, ValidationLists[#Headers],0)-1,,1)),1)))
This formulas assumes:
- You use Excel Tables for both the Validation List and the data entry area, and so uses the associated Structured References that Table functionality allows.
- Your validation table is called ValidationLists
- Your data entry table where the dropdowns are is called table is called DataEntry.
- The column containing your initial dropdowns is called ‘Main Category’
- The validation list in your validation table that contains your initial categories is called ‘Main Categories’
You will have to amend this formula accordingly if your tables or initial columns have different names.
The relative reference in this formula checks both the cell to the immediate left AND the cell to the immediate right of your current selection. Entering relative references into the Name Manager can be tricky…you first need to select the cell where the formula was originally created – in this case B8 – before you fire up the Name Manager dialog box. (Note that it doesn’t actually matter whether your own file has anything in C8 or not, or whether in fact your dropdowns are somewhere else entirely…rather it’s just that the above formula happens to refer to A8 and C8, and because we want our formula to always reference the cell on the immediate left and immediate right, then we’ve got to select the cell B8 which is in the middle.
Excel Tables – known as ListObjects to VBA developers – were introduced in Excel 2007, and are a very powerful and simple way to store things like lists, chart data, and PivotTable data…especially if you might need to add more data to your spreadsheet at a later date, and want to avoid having to repoint all your formulas to include the additional data. If you’re not familiar with Excel Tables – or you don’t know what that Table1[#Headers] guff above means – then I strongly suggest you check out Chandoo’s Introduction to Structural References or give GOOGLE a spin.
How does this awesome beast work?
Let’s step through it, bit by bit. Note that I’ve put some extra spaces in after each opening formula bracket, purely so this formula will wrap nicely on your monitor. Excel just ignores these extra spaces, so don’t bother taking them out.
=IF(ISBLANK(Sheet1!C8),IF(DataEntry[#Headers] Sheet1!B:B = DataEntry[[#Headers],[Main Category]],OFFSET(ValidationLists[[#All],[Main Categories]],1,,COUNTA(ValidationLists[Main Categories])),OFFSET(ValidationLists,0,MATCH(Sheet1!A8, ValidationLists[#Headers],0)-1,COUNTA(OFFSET(ValidationLists,,MATCH(Sheet1!A8, ValidationLists[#Headers],0)-1,,1)),1)))
That first bit in bold above checks the cell on the immediate right. If that cell on the right is not blank, then that means that the user has already made ‘downstream’ selections. We don’t want the user to change this ‘upstream’ dropdown without clearing those out. Thanks to the IF statement, if that’s the case then none of the rest of the formula gets executed, and the formula just returns FALSE. Data validation can’t handle this FALSE, so users can click on the dropdown button all they like, but nothing will come up. Consequently, the user simply can’t change this ‘upstream’ selection until they’ve first cleared out any selections they previously made in the cells to the right. Pure genius.
Here’s what that looks like:
Sweet! Okay, let’s take a look at the rest of the formula:
=IF(ISBLANK(Sheet1!C8),IF(DataEntry[#Headers] Sheet1!B:B = DataEntry[[#Headers],[Main Category]],OFFSET(ValidationLists[[#All],[Main Categories]],1,,COUNTA(ValidationLists[Main Categories])),OFFSET(ValidationLists,0,MATCH(Sheet1!A8, ValidationLists[#Headers],0)-1,COUNTA(OFFSET(ValidationLists,,MATCH(Sheet1!A8, ValidationLists[#Headers],0)-1,,1)),1)))
That bit in bold above checks whether the dropdown is the Main Category column. It does this using the INTERSECT operator, which is a space between two references (in this case of DataEntry[#Headers] B:B the INTERSECT operator is the space between DataEntry[#Headers] and the column reference B:B. Such a space tells Excel to go to the overlap or intersection of those two references, which in this case is the junction between the header row and the column that our dropdown is in.
- If the current dropdown is in the Main Category column, then this bold bit:
=IF(ISBLANK(Sheet1!C8),IF(DataEntry[#Headers] Sheet1!B:B = DataEntry[[#Headers],[Main Category]],OFFSET(ValidationLists[[#All],[Main Categories]],1,,COUNTA(ValidationLists[Main Categories])),OFFSET(ValidationLists,0,MATCH(Sheet1!A8, ValidationLists[#Headers],0)-1,COUNTA(OFFSET(ValidationLists,,MATCH(Sheet1!A8, ValidationLists[#Headers],0)-1,,1)),1)))
…serves up just the list containing our initial categories (i.e. ‘Fruit’, ‘Vegetables’, or ‘Other Stuff’ in this example). - If the current dropdown is not in the Main Category column, then this bold bit:
=IF(ISBLANK(Sheet1!C8),IF(DataEntry[#Headers] Sheet1!B:B = DataEntry[[#Headers],[Main Category]],OFFSET(ValidationLists[[#All],[Main Categories]],1,,COUNTA(ValidationLists[Main Categories])),OFFSET(ValidationLists,0,MATCH(Sheet1!A8, ValidationLists[#Headers],0)-1,COUNTA(OFFSET(ValidationLists,,MATCH(Sheet1!A8, ValidationLists[#Headers],0)-1,,1)),1)))
…serves up the particular list relevant given the previous choice made in the dropdown to the left.
Wicked, eh!
Normally I don’t advocate the use of volatile functions such as OFFSET if there is a non-volatile alternate (and you’ll hear more about volatility from me in a forthcoming post). But as Roberto points out in his original comment, in this case it doesn’t matter…choices made via dropdowns are not considered volatile by Excel, even if the formulas used to populate that dropdown are volatile.
Like Roger’s approach, Roberto’s approach can handle any number of cascading levels, provided all the category names are unique. All you need to do is simply add the new subcategories to the right hand side of the validations table.
Thanks Roberto…I learned a lot from those comments. Readers, be sure to visit the Frankens Team and check out the crazy things Roberto, Kris & Gábor get up to with Excel.
Download the sample file
Here’s a sample file that utilizes Roberto’s approach:
Click here to download the file
Updates
Check out the updated 2024 version of this technique with XLOOKUP. The formulas are much simpler and it works with any level of validations.
You may also want to check out my good pal Doug Glancy’s approach to this. His version of dependent dropdowns uses Conditional Formatting to alert the user, and ultimately, the analyst, that something is amiss. Be sure to say hi to him in the comments while you’re there, and to subscribe to his blog. Anyone who makes up sample files about fictional International Pie Lovers Associations deserves our eyeballs!
About the Author.
Jeff Weir – a local of Galactic North up there in Windy Wellington, New Zealand – is more volatile than INDIRECT and more random than RAND. In fact, his state of mind can be pretty much summed up by this:
=NOT(EVEN(PROPER(OR(RIGHT(TODAY())))))
That’s right, pure #VALUE!
54 Responses to “6 Tips for Writing Better VLOOKUPs”
Hi, I am loving the VLOOKUP series this week. 🙂
Could you please expand a little on why you don't recommend using 1 or 0 in place of true or false? I am in the habit of doing this.
"You can even omit the last argument if it is 0"
Excel's default for the last argument is TRUE. Because of this, it's dangerous to omit the last arguement. I would use either FALSE or 0. Never omit if you want an exact match.
Nice series, Chandoo!
.
Your readers may be interested to know that the quickest formula method to do lookups in Excel is an array-entered INDEX.
.
This is one of the many topics covered in the Excel Hero Academy:
Excel Hero Academy
.
Regards,
Daniel Ferry
Excel Hero Academy
Dear Daniel,
I had used index-match with absolute reference for the ranges but when I am resorting the table the formula is not recalulating the lookup value combination.
Regards,
Anish Menacherry
@Anish
Can you post the question at the Chandoo.org Forums
http://chandoo.org/forum/
Please include a sample file so we can review the issue
1. Never use VLOOKUP/HLOOKUP - Always use Match /Index
2. Sort your data before performing a Loookup
3. Use 1/-1 option Match as it is at least 10 times faster than the 0 option- But modified to perform an exact match rather than an approximate match as described below
a) A Column containing a Match Fucntion to Find the Position with the 1/-1 option
b) A Status column containing a Index to check the status (present/not present)
c) Multiple array entered Index colums to pick
In tip number 5 you state, "you can even omit the last argument if it is 0" which is not correct. If you omit the last argument, Range_Lookup, is TRUE, as Mike Alexander points out.
Excellent series - Need some help from the expert. how easy it is to add/expand a named range in a lookup formula?
@Mike & Gregory: I am sorry for the confusion. The formula =VLOOKUP(value, range, column #) assumes last argument as TRUE.
Where as the formula =VLOOKUP(value, range, column #, ) assumes last argument is blank or empty which internally gets treated as 0.
And that is what I mean by you can even omit last argument. I state that "Remember, you must place a comma (,) after the column number if you are planning to use this." otherwise, this will not work.
@Andrew: I suggest not using 0 or 1 as they are more cryptic and lead to confusion when your spreadsheet gets to someone else's hands.
@Daniel: Thanks for that.
@Sam: Good tips. I would just add that using VLOOKUP / HLOOKUP is ok as long as they solve the problem you have and do not take too much time. The performance improvements you get with array entered index or other techniques are minimal when dealing with small and moderately sized data sets.
@Sundeep
Very easy
Have a read of: http://chandoo.org/wp/2009/10/15/dynamic-chart-data-series/
Particularly Point 3. Create a new named range and type OFFSET formula
@Hui - Thanks.
If I have a large workbook with many Vlookups and if I change the range to named range...is there an easy way to change all the formulas? It is more of wishful thinking than a question 🙂
@Sundeep... You can use Apply names from formulas ribbon to apply names to a selected range. This technique works when the ranges are mapped to static references. Dynamic refs. thru OFFSET are bit more tricky.
You can use the find / replace to automatically replace all $A$1:$C$1000 with dynamic range lstData. See this: http://chandoo.org/wp/2009/02/17/spreadsheet-formulas-edit/
@Sundeep
On the Formulas Tab, Click on the Drop Down on the Define Name button and select Apply Names
Select one or all Named Ranges and apply
Excel will go through your worksheet/s and change the Ranges for Named Ranges.
i cannot believe i missed the new to 2007 formula "IFERROR". your mention of this will help reduce the number of characters in many formulars i use (with "ISERROR") by at least 40% along with commensurate reductions in spreadsheet size and calculation speed... not to mention future reduction in typing and debugging time in formulas. thank you. and thank excel.
Newbie here.
I am not able to understand the Tip#1. Use of "val", "tbl". I tried and it kept on giving error.
Chandoo's Tip#1: =VLOOKUP(valSalesPerson,tblData,3,FALSE)
Does it need column headings? And how do you l lookup the value I am looking.
Thanks in advance.
[...] 6 VLOOKUP Tips [...]
[...] VLOOKUP, INDEX, and MATCH: Useful for looking up any text values [...]
I need some help with creating a formula. I have a list of names on tab 1. (About 20) On tab 2 I have a list of names and there total sales (About 3,500) I created a name range for both the first list of names on tab 1 (Producer) and a name range for the second list on tab 2 (Agent_List) The sales on tab 2 for each producer is in the 7th colume.
I need the formula to identify name of Producer (Tab1) from the Agent_List and then choose the total sales for that producer.
This is the formula I put together and I only get #REF!
VLOOKUP(PRODUCER,AGENT_LIST,7,FALSE)
@JimH
I assume you are adding a column next to the Agent_List on Tab 2 and looking up values from the Agent_List and retrieving values from the Producer list
.
So the format for your equation will be:
=VLOOKUP(A2,Producer,7,FALSE)
or
=VLOOKUP(Agent_List,Producer,7,FALSE)
.
Note that the named range Producer must be at least 7 columns wide, not just Column A or you will get the #REF! error also
Hi
Can anyone please help or this totally impossible in excel? I am trying to do a vlookup with a range of cells that contains "comments" in them and unsuccessful.
Thank you
@Lala
You cannot search within comments unless you use VBA
My tips are:
Pay attention to data types - no fly if mixing text and numbers. I run into this problem a lot with files downloaded from access that have a tendency to mix data types on me when it hits excel.
Pay attention to $ - If pulling from the same workbook, $ won't auto fill on your range and you will potentially miss hits.
Yeah, the data type mixing has bitten several folks I work with in the rear.
EG: I work at a company where marketing source codes are 10-alphanumeric. But, some codes are like "12345" while others are "123abc". When access or sql dumps to excel, the numerical ones convert to numbers while the text ones stay text.
So, what I do is create a reference column next to them in which I do a =TRIM([column]). Trim not only removes front/back spaces, it converts a value to text data type. This is useful, b/c sometimes sql db admins will store data with a fixed string length (eg: a column may get stored as char(50), which means it will have 50 chars no matter if it has to add extra spaces at the end to pad it out.) When you dump this to excel, the extra spaces remain at the end. So, the Trim command not only converts numbers to text, it removes padded spaces at the end. Very useful when working with sql dumps.
I have two sheets, in first sheet i have given a criteria of month (like jan, feb), then on another sheet i have month wise sheet like
jan feb mar
a 2 5 8
b 5 9 8
c 9 12 89
now i need in first sheet if i give criteria jan then answer is 2+5+9, or if i give feb then answer is 5+9+12 and like that, how to get that??
I am pretty well versed in VLOOKUP but I have a challenge I can't figure out. When I complete the VLOOKUP in one cell, it works fine. When I drag the formula down (using $ where necessary) the value from the first LOOKUP populates in the new cell. If I double click on the cell and hit 'enter' then the correct value is pulled in from the vlookup. Any suggestions why the formula isn't executing correctly until I hit enter?
@Nicole
It sounds like Calculation is set to Manual
Goto the Data Tab Calculation and set it to Automatic
Absolutely FANTASTIC!! Thank you so much. Slight variation on my version of Excel. I had to go to Formulas Tab then to Calculation sub-tab, Calculation Options, change setting to Automatic. Thank you thank you thank you. Saved me hours of more frustration!
[...] than maybe sorted, which it usually is anyway).Use COUNTIF or MATCH to speed up calculationAs many others have pointed out, VLOOKUP returns #N/A if the lookup value is not found. Instead of using a [...]
I have more than 2 columns in a table I'm so confused cuz the results i get is #N/A =(
I have a 2-sheet database. Sheet 2 has a list of Accronyms in column A and their description in column B. On sheet 1, column A is where you input your Acronym. In column B, the formula takes Acronym from column A, looks it up on sheet 2, and displays it on column B.
After some research, I found how to make custom text if there is not a match on the Acromyn. The question i have is, is that when there is no text in comumn A, sheet 1, column B, sheet 1 displays my custom text "ABBREVIATION NOT FOUND". I'm trying to write a forumla that leaves column B blank unitl there is an input in column A.
This is my current forulma:
=IF(ISNA(VLOOKUP(A4,Description!A:B,2,FALSE)),"ABBREVIATION NOT FOUND",(VLOOKUP(A4,Description!A:B,2,FALSE)))
Any help out there?
Thanks,
Jerome
Hi Jerome... Thanks for your question. Try this formula instead:
=IF(A4<>"", IFERROR(VLOOKUP(A4,Description!A:B,2,FALSE),”ABBREVIATION NOT FOUND”), "")
Works in XL 2007 or above. For older versions use this:
=IF(A4<>"", IF(ISNA(VLOOKUP(A4,Description!A:B,2,FALSE)),”ABBREVIATION NOT FOUND”,(VLOOKUP(A4,Description!A:B,2,FALSE))), "")
Btw, to learn more about IFERROR see this: http://chandoo.org/wp/2011/03/11/iferror-formula/
I have 2 worksheet, the first one is like this:
A B C D
1 DOG 1 BROWN
1 DOG 2 WHITE
2 CAT 1 SMALL
2 CAT 2 MEDIUM
2 CAT 3 BIG
THE SECOND WORKSHEET IS LIKE THIS:
A B C D
ENTER# fORMULA 1 WITH VLOOK ENTER # FORMULA 2
(RETURN ANIMAL) RETURN TYPE
FOR EXAMPLE i NEED WORKS LIKE THIS:
2 CAT 2 MEDIUM
FIRST FORMULA IS EASY NOT PROBLEM. bUT FOR THE SECOND i DO NOT FIND HOW TO DO IT. PLEASE HELP.
This would be how I would handle your second formula, in your first worksheet, I would insert a column between C & D. In that column I would have a formula to concatenate the values in column A & C (example =concatenate(a2,c2)) which would result in:
A B C D E
1 DOG 1 11 BROWN
1 DOG 2 12 WHITE
2 CAT 1 21 SMALL
2 CAT 2 22 MEDIUM
2 CAT 3 23 BIG
Then in the second worksheet formula 2 would be:
=vlookup(concatenate($a2,$c2),AnimalType columns D&E,2,false)
Great Stuff Chandoo
In your 6th post you say use SUMIF instead of VLOOKUP as it runs faster.
What if you have a spread sheet with repeated data and you only want to pull one value back?
would it be best to use a simple VLOOKUP
or something like: IF(COUNTIF < 2, SUMIF, VLOOKUP)
I have set COUNTIF < 2 (not just = 1) to take advantage of the fact that if COUNTIF = 0 you won’t get an error
Now if only you could use the column header name instead of the column index number in the VLOOKUP function.
Scenario: I have a list/table in one spreadsheet that I use to lookup values in other spreadsheets. If I insert columns in my list/table, I have to go into the other spreadsheet(s) and increment the VLOOKUP formulas' column index number to capture the right column of values.
Example: if I inserted a column in Table1, my formula:
=VLOOKUP(A1,Table1,2,FALSE) would have to change to:
=VLOOKUP(A1,Table1,3,FALSE),
it would be so much better if you could code something like:
=VLOOKUP(A1,Table1,Table1[price],FALSE)
If my lookup result is numeric data I could use sumif as suggested and use the list/table references; is there a similar function I can use for alphanumeric data lookups that uses list/table references?
[…] Read more – 6 VLOOKUP tips […]
tip:
you can use dynamic column reference for your look up if you want to pull multiple column values from another sheet with the same row reference without having to rewrite the the formula, e.g.
range a1:d1 = "header", 2 , 3, 4
b2 = vlookup($a2, LookUpRange, b$2, 0)
c2 = vlookup($a2, LookUpRange, c$2, 0)
b3 = vlookup($a3, LookUpRange, b$2, 0)
the above will bring back the value two columns away from LookUpRange in b2, 3 for c2 and 4 for d2 for the same reference, a2. By freezing just the column for your lookup reference value and just the rows for your column reference, you can drag your forums both down and right while keeping all reference both constant and dynamic... as oxymoronic as that sounds.
my TIP, building on what Andy says above re using a dynamic refrence: if you use the column functon in the header row - should someone add extra columns to the source sheet your lookup will adapt and still return the right result.
With the below formula I am getting "too many arguments for this function. any help?
=IFERROR(VLOOKUP(RIGHT(M3,7),notes!A:A,1,FALSE),"Failure to process correctly",IFERROR(VLOOKUP(RIGHT(n,2),notes!A:A,1,FALSE),"Failure to process correctly"))
Chaz - IFERROR only requires 2 arguments, you have entered 3 (the vlookup, the error message, the 2nd IFERROR).
Change your formula to the following:
=IF(isERROR(VLOOKUP(RIGHT(M3,7),notes!A:A,1,FALSE)),”Failure to process correctly”,IFERROR(VLOOKUP(RIGHT(n,2),notes!A:A,1,FALSE),”Failure to process correctly”))
Ian
Hmm, I'm not sure my formula will return the required output.
This tests if there is an error in the 1st vlookup, then checks the 2nd, and only returns the error message if both vlookups are errors. Is that what you wanted to do?
=IF(isERROR(VLOOKUP(RIGHT(M3,7),notes!A:A,1,FALSE)),IFERROR(VLOOKUP(RIGHT(n,2),notes!A:A,1,FALSE),”Failure to process correctly”),VLOOKUP(RIGHT(M3,7),notes!A:A,1,FALSE))
I am trying to use a vlookup with a named range for the lookup array. This works fine. However now I would like to replace this named range with a cell reference (which obviously contains the name of the named range) but get a N/A error message. Is this really not possible?
vlookup ( A1, named range, 2, 0 ) . This works
vlookup ( A1, F1, 2, 0 ) . Where cell F1 contains the the text with named range. This does not work.
Any tips or thoughts would be appreciated. Thank you in advance
@Erik
Use: vlookup ( A1, Indirect(F1), 2, 0 )
Works like a charm. Thank you!
Some opinions on the pros and cons of using named ranges on http://www.excelvlookuphelp.com along with a few other hot tips
Hello,
Chandoo,
Can u explain me how to use vlookup formula in 2 sheets in one excel workbook.
Hi am Using Index match function to overcome the limitation of Vlookup. But I am failed to get the same result as i get in Vlookup. in vlookup as we can expand the Columns of Vlookup in one single shot. Like Vlookup($A4,A1:G9,3,0) but same Result i Not get in Index match Function. Please help
@Satish
I will suggest that your list is unsorted and it is possible that VLookup is returning a wrong answer
Can you post a question at the Chandoo.org Forums
http://chandoo.org/forum/
Post a sample file and someone will review
I want to upload a Sample file Contain my Question. but i can't see and upload file button on the page. Please Tell how to upload the File
@Satish
You can't upload a file here
But you can on the Forums
Goto:
http://chandoo.org/forum/
Select a Forum
Start a New Thread
Upload a File, is at the Bottom next to the Post Button
Refer: http://chandoo.org/forum/threads/posting-a-sample-workbook.451/#post-73705
thanxx... Soon i will Upload It.
Dear Excel super-users,
Sourcing data from different sheets.
I'd like to specify in the vlookup formula which sheet to source data from.
This source sheet will change depending of the name of the person selected in a specific cell C1 on the sheet where the vlookup formula is being run from.
I'd be grateful for any tips to achieve this.
Regards,
Sean
dear sir /madam
please proved me lookup formula
and exp--------- insert picture formula attched excel sheet
Us the Column formula in place of the 3rd argument will save you time when you want to bring in all data columns!