Time for some good, old fashioned VLOOKUP love. Let’s say you are writing VLOOKUP()s to get data from an unusually fat table, ie one with heaps of columns. You want to get to lookup ID in first column and get thingamajig in what is that column number. Well, better get counting from 1 and after 19 seconds and lots of squinting you arrive at column number 53 – which has thingamajig.
If this sounds like your VLOOKUP routine, check out these three amazingly simple tips to save some time and effort with your lookups.
#1 Switch to R1C1 view
This is a quick and easy fix. Head to File > Options > Formulas and enable R1C1 reference style. This will tell you what each column is in number format. Problem solved.
Of course, this also means all your formula references will be turned in to R1C1 style. But once you disable the R1C1 reference style in Formula Options, your VLOOKUP will be back to A1 style.
#2 Use Tables
While the R1C1 view can quickly tell you what each column is in numbers, it won’t work if your data starts from 17th column or something like that. A better option is to turn your raw data in to tabular format using Insert > Table. Give this table a name from Design ribbon, like mydata. This way, you can use simpler lookup formulas.
[Related resources: VLOOKUP with Tables is awesome | Introduction to Excel Structural Referencing for table formulas]
Original VLOOKUP: =VLOOKUP(something, data!$A$2:$BK$123, 53,false)
VLOOKUP using tables: =VLOOKUP(something, mydata, 53,false)
But we still have to figure out the column for thingamajig. Simple, we use MATCH() formula inside VLOOKUP, like this:
VLOOKUP using tables & MATCH(): =VLOOKUP(something, mydata, MATCH("thingamajig", mydata[#Headers], 0), false)
That is right, you can access table headers using the #Headers keyword and get position of any header.
#3 Use INDEX + MATCH
This will make the problem altogether irrelevant. Simply use INDEX and MATCH formulas to get the result you need, like this:
=INDEX(mydata[thingamajig], MATCH($C$3,mydata[ID],0))
Now, you don’t care if thingamajig is 53rd column or 217th column and if ID is at the start or somewhere else. It works all the same.
For more about using INDEX in your formulas, check out this beautiful tutorial.
Here is a summary of all formula techniques
| Normal Lookup [help] | |
| Formula | =VLOOKUP(something,'really fat data'!$A$2:$BK$123,53,FALSE) |
| Comments | You need to know which column (53) has the data you need. Either count manually or enable R1C1 style to quickly to know. |
| Using Tables [help] | |
| Formula | =VLOOKUP(something,mydata,53,FALSE) |
| Comments | Create a table for your source data (using CTRL+T) and give it a name. Use the name in your formulas. You still need to know column number. |
| Using Tables + MATCH() | |
| Formula | =VLOOKUP(something,mydata, MATCH("thingamajig",mydata[#Headers],0),FALSE) |
| Comments | Use MATCH() to find out which column header has the value you want to lookup. |
| Using INDEX + MATCH [help] | |
| Formula | =INDEX(mydata[thingamajig], MATCH($C$3,mydata[ID],0)) |
| Comments | Now, you don’t even need to know where everything is. Just lookup the value in ID column and get corresponding value from thingamajig column. Done 🙂 |
Download Example Workbook
Click here to download workbook with all vlookup techniques discussed in this page. Play with formulas to learn more.
Get your VLOOKUP on…
Check out our complete guide to VLOOKUP and for more lookup pizzazz get my VLOOKUP book.
How do you deal with fat tables?
I use tables and INDEX+MATCH whenever my data is more than a few columns or can change often.
What about you? How do you deal with several columns situation? Please post your tips in the comments section.
22 Responses to “Formula Forensic No 019. Converting uneven Text Strings to Time”
Why not let the TIME function take care of the math:
=TIME(LEFT(TEXT(A1,"000000"),2),MID(TEXT(A1,"000000"),3,2),RIGHT(TEXT(A1,"000000"),2))
I was going to point out the same thing, except to note that useing the time function and doing the divide method are not interchangeable.
I have spent hours investigating a spreadsheet working with a couple of years worth of hourly data, and found that the reason things weren't working is because the rounding on the divide method is only close to the correct time values. In order to have it work for comparisons, (like sub-totaling by time value, or pivoting) you MUST use the TIME function.
Great use of the TEXT function, Hui. I will be using this concept for sure.
Why not just.
=TEXT(A1,"00\:00\:00")*1
Regards
Elegant!
Hi Elias,
I tried to use your formula. But, it doesn't seem to work for me. I am getting an error message "The formula you typed contains an error". It seems I have the problem in using \: in the format. How can I overcome this?
Thanks
Manick, it isn't the /: that causes the problem. If you copy/paste it, you're getting “'s instead of the actual quotation marks that Excel uses. Change the quotation marks by deleting from the pasted formula and retype them.
Hi Manick...
use this alternate formula :
=1*TEXT(A1,"00"":""00"":""00")
note twice double quote each side of :
@Manick,
Did you copy the formula and pasted in Excel or did you typed? Also, do you use , or ; as separator of arguments?
Regards
@Elias: I had no problem using your formula, in fact, I have used your method to convert a number such as 20120419 to an Excel date using =TEXT(A1,"0000\/00\/00")*1. Thanks for posting.
@Joe: For date convertion you can use this as well.
=TEXT(A1,"00-00-00")*1
Regards
Sweet! It appears this also works with =TEXT(A1,"0-00-00")*1. I come from the old days when you counted every byte. I also like to try an make formulas as small as possible for the fun of it 🙂
Elias's suggestion is the simplest, but here is yet another way with TIME and MOD functions...
=TIME(MOD(A2/10000,100),MOD(A2/100,100),MOD(A2,100))
Since the seconds appear to always be 0, why not simply the input to minutes and above and save yourself the trouble of typing those zeroes...
0 => 0:00
1 => 1:00
10 => 10:00
100 => 1:00:00
etc.
Then just use this formula...
=TEXT(A1,"0\:00\:")*1
@ Rick, the numbers to convert are no typed, they are imported. Then your formula will return the wrong result.
Regards.
Hmm! My formula lost some backslash-zero combinations (two of them to be exact). The formula was supposed to be this...
=TEXT(A1,"0\:00\:\zero\zero")*1
where the words "zero" should actually be the number 0. Another way to write the formula is this...
=TEXT(A1,"0\:00\:""00""")*1
Hi Master,
While writing the formulae you have considered only upto "seconds factor" . I think you should take the centi-seconds factor also to achieve best results. Please look into it and rectify the problem...?
For Example.
In horse racing timings are noted in minute, seconds and centi-seconds, like if a horse finished in 70 seconds over a scurry of 1200 metres, is noted as 1.10 min. Nowadays it is noted in centi-seconds everywhere, like 70.00 if you want to convert it to centi seconds (should multiply by 100) = 7000 centi seconds. If you put this figure into your formula as a general number (7000) it will return as 1:10:00. As per your formula, it should be taken as 1 hour 10 seconds 0 minutes. However for a racing enthusiast like me it can be taken as 1 minute 10 seconds also.
Just look what happens if we race goers use this figure as 7000 centi seconds in your formulae, it will correctly show as 1 minute 10 seconds(?) Suppose a horse finishing over a 1200m in 70.60 seconds or in racing terms written as 1.10.60 mins, where 1 minute 10 seconds, & 60 centi-seconds can be counted as 7060, if you put this figure in the formula it will return as 1 minute 11 seconds, that is correct.
My point is if you can incorporate Centi Seconds in the formulae, it would be of great help to us also.
Thanks and regards.
Rajagopal (Mumbai)
Awesome techniques !
I tried with 235960 just to see if it will fail but this is great.
Although a little longer, this too work:
=CHOOSE(LEN(A2);A2/(24*3600);A2/(24*3600);LEFT(A2;1)/(24*60) + RIGHT(A2;2)/(24*3600);LEFT(A2;2)/(24*60) + RIGHT(A2;2)/(24*3600);LEFT(A2;1)/24 + MID(A2;2;2)/(24*60) + RIGHT(A2;2)/(24*3600);LEFT(A2;2)/24 + MID(A2;3;2)/(24*60) + RIGHT(A2;2)/(24*3600))
Converting uneven Text Strings to Time I have imported some data that comes in as a number that I need to convert to h:mm.
Just come across this while googling
find interesting challenge and come up with this
=TEXT(TEXT(SUBSTITUTE(A1,RIGHT(A1,1),""),"000000"),"00\:00\:00")
I need to convert a string of numbers representing average minutes, to reflect correct time values. For example, the numbers below currently represent 5.79 minutes, 15.82 minutes, etc.
I need to convert these values to their correct corresponding value within time parameters. So 5.79 would be something close to 5 minutes and 45 seconds.
5.79
15.82
3.92
12.40
6.70
3.62
I know there has to be a way to compute this in Excel, it can do anything, I believe!
Thank you for any and all assistance~
@Renee... You can use a formula like this. Assuming A1 has the minutes.seconds,
=INT(A1) + MOD(A1, 1)*0.6
If you want to see it in 5 minutes 45 seconds format, use
=INT(A1) & " mins " & ROUND(MOD(A1, 1)*0.6,2) & " secs"