Today is February 29th, and that means, this year we have one more day to be awesome. So lets celebrate it in Excel style!
Lets learn 14 different ways to tell if an year is leap year, using Excel Formulas.
Why 14? because, we are awesome like that.
Why 14 methods to just find the year in cell D4 is leap year or not? Because, we all know that by learning different ways to solve a problem, we become smarter, more awesome and have more fun. So lets roll.
Before we start..,
Since all the 14 methods rely on certain calculations, I have created some names. See below:
All the names are self-explanatory, except the febDays. So lets take a look at it.
febDays formula
For one of the methods, we need to have all the dates in February in a list. If we want the first of Feb as a date, we can use =DATE(year,2,1). But we want all dates in February. That means, we need to use a list (array) in third parameter of DATE like this:
=DATE(year,2,{1,2,3,4,….,28,29})
Instead of typing all the 28/29 numbers, we can use ROW formula to generate these, like:
=ROW($A$1:$A$29) would give me a numbers from 1 thru 29.
But the problem is in many years Feb has only 28 days, and for rest, it has 29 days. So we modify the second part of row formula and use the last DAY of the Feb, like this:
=ROW($A$1: INDEX($A$1:$A$29,DAY(EOMONTH(feb1st,0))))
To get the last day of a month, we use = DAY(EOMONTH(1st date, 0))
I think you can put the rest of pieces together to solve this puzzle.
Moving on,
#1 – The year has 366 days
This is the obvious one. We use =DATE(year+1,1,1)-jan1st=366 to check if there are 366 days between January 1st of next year and this year.
#2 – February 29th is not March 1st
Because in Excel all dates are numbers, when we use a formula like =DATE(2011,2,29), Excel gives us the date of March 1st, even though we wanted 29th Day of February in 2011. So a simple leap year check is to see if February 29 is March 1st or not!
=DATE(year,2,29)<>mar1st
#3 – February has 29 days
This is another obvious test. In a leap year, February has 29 days. So=DAY(EOMONTH(feb1st,0))=29 will be true for leap years.
#4 – February 1st and March 1st are not on same day of week
In non leap years, Feb has 28 days (a multiple of 7), so both Feb and March start on same day of week. So, =WEEKDAY(feb1st)<>WEEKDAY(mar1st) will be TRUE for leap years.
#5 – Adding 365 to January 1st does not change year
Well, that is obvious too. =YEAR(jan1st)=YEAR(jan1st+365) is TRUE for leap years.
#6 – 30th Day of February is March 1st
If an year is leap year, 30th day of February [DATE(year,2,30)] is same as March 1st. So, =DATE(year,2,30)=mar1st is TRUE for leap years.
#7 – 0th Day of March is Feb 29th
In real world there is no zeroth day for any month. But in Excel, since all dates are numbers, 0th day refers to last day of previous month. So, =DAY(DATE(year,3,0))=29 will be TRUE in leap years.
#8 – April 1st and January 1st are on same day of week
In leap years, there are 91 days between January 1st and April 1st. And since 91 is a multiple of 7, both April 1st and January 1st start on same day of week. Hence, =WEEKDAY(jan1st)=WEEKDAY(apr1st) will be true for leap years.
#9 – Only 2 more months start on same day of week as January
In leap years, both April and July start on same day of week as January. (Where as in non-leap years, Only October starts on same day of week as Jan).
To test this, we will of course use the SUMPRODUCT. like this:
=SUMPRODUCT(–(WEEKDAY(DATE(year,ROW($A$2:$A$12),1))=WEEKDAY(jan1st)))=2
The portion WEEKDAY(DATE(year,ROW($A$2:$A$12),1)) gives all the first day of weeks from February to December. And then we just check how many of these are same as January 1st’s week day.
#10 – Next year’s February 1st and this year’s February 2nd are NOT on same day of week
In non-leap years, there are 364 days between February 2nd and next year’s February 1st. Since 364 is a multiple of 7, both of these days are on same day of week. Which is not the case in leap years (as the difference becomes 365). So, =WEEKDAY(feb1st+1)<>WEEKDAY(EDATE(feb1st,12)) will be TRUE for leap years.
#11 – February 1st’s day of week occurs 5 times in that month
This a bit tricky to test, but then again we have SUMPRODUCT. So, =SUMPRODUCT(–(WEEKDAY(febDays)=WEEKDAY(feb1st)))=5 will be TRUE for leap years. The name febDays has all dates in February. I think the rest is easy to understand.
#12 – February starts and ends on same day of week
29 days means both 1st and 29 are on same weekday. So, =WEEKDAY(feb1st)=WEEKDAY(EOMONTH(feb1st,0)) will be true for leap years.
#13 – Spreadsheet day (October 17) and February 1st are on same day of week
Debra, who is a well known Excel blogger & author started the whole spreadsheet day thing. She says, we should celebrate October 17 as spreadsheet day. I love that idea, mainly because, it is just 3 days before my birthday and I like celebrations. And I also like Excel 🙂 So blame her if you do not like this way of testing for leap years.
In leap years, there are 259 days between February 1st and October 17. And since 259 is a multiple of 7 (and 37), we know that they are both on same day of week. So, =WEEKDAY(feb1st)=WEEKDAY(DATE(year,10,17)) is true for leap years.
#14 – Finally, the year is divisible by 4 and if it is divisible by 100, then also by 400
Finally, we are going to test the whole “an year is leap year if it is divisible by 4 and if it is divisible by 100, then it is also divisible by 400” thing. This is a slightly tricky one to test. The formula, =((MOD(year,4)=0)*((MOD(year,100)<>0)+(MOD(year,400)=0))=1) will be TRUE for leap years and false for non-leap years.
Download Leap Year Test Workbook
Click here to download the workbook with all these 14 examples. Play with the formulas, named ranges to understand these techniques.
How do you check it is a leap year?
If you are working and you get paid on first day of a month, then one clear way of knowing leap year is that you get your salary one day later. Other than this, what method would you use to find if an year is leap year. Go ahead and be creative. Share your ideas and formulas using comments. Next leap day is 4 years away. Go
Want to learn how to Dates & Times in Excel – Read these:
If you deal with data that has a lot of date / time stuff, then understanding various Excel features in this area is a must. Read below pages to learn more.
- 10 tips on working with dates & times in Excel
- Calculate difference between 2 dates
- Find thanksgiving day for any year
- Check if 2 ranges of dates overlap
- Rolling months in Excel
- How to convert text to dates
- Even more on Excel dates & times
Want to master Date & Other Excel Formulas?
If you want to learn how various formulas in this post work and know more about everyday Excel formulas, please consider joining my Excel Formula crash course. It has detailed video tutorials on more than 40 everyday Excel formulas and teaches you all the powerful techniques to become a formula ninja.
37 Responses to “Quickly Change Formulas Using Find / Replace”
Chandoo,
this is a really cool stuff what I use quite often. In addtion this method also could be a good choice to switch the reference type of the formulas from relative to absolute or vice versa. (just simply replace the $ in the same way).
Andras
@Andras: you are right, we can use find / replace to change references, reference types etc. Now, only if they had regex in find/ replace, we could so much more 🙂
@Tony Rose: Thank you. This is very useful and powerful feature. I even use it for cleaning up data. While formulas are good, they are not the solution for every problem. Often when I need more powerful cleanup / changing, I copy paste the stuff to text editors like notepad++ and then use their find/replace to do the dirty task.
What if i have to change the formula from ='Analysis'!C1 to 'Analysis 1'!C1?
I tried doing it using Find /Replace but could't. Encountered some errors.
And is there a way to change this using VBA???
Hi,
Did you ever get a reply to this?
Thanks
Ollie
to make your life easier, suggest you to avoid (Space) in worksheet names whenever possible. Consider (underscore) instead.
As the first formula wouldn't have the single apostrophes (since there's no space) need to include that in replace. So, search for:
Analysis
and replace with:
'Analysis 1'
This could be the most useful tips I've seen in a while. I use this all the time and can instantly change 400 formulas with a few clicks. Like so many other functions in Excel, I don't know what I would do without this one.
Keep 'em coming!
[...] on formulas: 5 areas where mouse kicks keyboard’s butt | Edit formulas in bulk using Find / Replace | Excel Formulas Online [...]
THANKS BRO
You, sir, are a god among men...
This is really cool. Your just save me hours of work. Thanks.
Thanks so much for this fix! It saved me tons of work. I'm muddling my way through and this really helped!
Oh... My... God!
This tip just saved me about 2 hours every month! I can't believe how easy it is to use. Now, can somebody tell me who I should call to get a refund for the previous 100 hours I spent manually changing formulas cell by cell?
Thanks so much!
THANK YOU!!!
THANK YOU!!!!
You saved me hours, I had a sheet that has more than 500 formulas, and i needed to replace the year in all of them, you saved me hours
Awesome info on replacing cell addresses in formulas. I have never heard about Ctrl+` before. Thank you!
I have something inside a formula like:
=sum(A1, A2*10) all over I now need to get rid of the *10 {=sume(A1, A2)} I thought to use the find replace trick above but with a blank in the replace but it then outputs just zeros. I thought I could trick it by doing *1 but then it just turns into =*1) with none of my references. Does anyone have an idea how to do this?
The Ctrl+ trick is cool.
@T
Instead of replacing with a blank try replacing
*10)
with
)
Thank you! This literally will save me hours and hours of time, and that's without losing my sanity in the process!
I have Sheet(1), Sheet(2), Sheet(3), etc ... Sheet(100).
Then there's a summary tab where I want to recap information on all those different sheets. Is there anyway to create a formula on the Summary tab to get ='Sheet(1)'!B$29 copied down for all 100 sheets without having to change each sheet # within the formula by hand?
@Brigitte
If you have a list of the sheet names in A2:A100
In B2: =INDIRECT("'"&A2&"'!$B$29")
Copy down
or if you don't have a list of the sheets names you can make it up on the fly
=INDIRECT("'sheet("&ROW()-1&")'!$B$29")
Copy down
Thanks for the suggestion. However, I copied your formula right back to my file and it didn't work. So I did it another way. I put the tab/cell reference in one cell and then did an =INDIRECT() to capture that information.
K2="'Sheet("&L2&")'!B$29" which has a value of 'Sheet(1)'!B$29
B2=INDIRECT(K2) which now has a value of 40 (contents on Sheet(1).
Thank you!!!!
Thank you ..
Hi, Out of all the formulae, I wish to replace the formula which has generated 0 value with blank space? I am unable to do it with find and replace function,
Please suggest.
Thanks.
Chandoo, you literally just saved me about 2 hours of work. I had a document with a daily report in two formats. The second formate just linked to all the appropriate cells in the other format (different sheets). This was 180 references that needed to be changed and I had to make this for a 4 week period (aka 28 different sheets at 180 references to change per sheet).
Thanks so much.
I have tried this way and without using the Ctrl-` formula view
Either way, I am trying to do something simple, but it won't let me.
I have a bunch of cells with a simple math formula like
=-(0.5*20)
various values in each cell, multiplied by 20
I simply want to change the multiplier globally from 20 to 25. But when I tell it to find *20 and replace it with *25, it replaces the entire cell contents with *25, rather than just replacing the *20 portion of the cell contents.
Can anyone assist with this? Seems so simple, but Excel isn't letting me do it.
Search/Replace 20 or 20) with a cell Reference eg A1 or A1)
Then put the value 25 in A1
By using a * in the search it replaces all the text
how to find a specific cell's value in a column & replace replace it with another cell value i actually need a method to replace a data in ca column and replace with the value i have in a specific cell can i give a [ location ] of data to what i need to find and then give row or column range to where i need to find and the given value & then give a [ location ] of data to what i want to be replace with the find and replace by row & column range & than by specific criteria and than by specific location.
please help.
how to find a specific cell’s value in a column & replace replace it with another cell's value.
i actually need a method to find a specific cell's data in a column and replace it with the value i have in a specific cell.
can i give a [ location ] of data to what i need to find and then give row or column range from where i need to find the given value & then give a [ location ] of data to what i want to be replace with.
find and replace by row & column range & than by specific criteria and than by specific location.
please help.
how to find a specific cell’s value in a column & replace it with another cell’s value.
i actually need a method to find a specific cell’s data in a column and replace it with the value i have in a specific cell.
can i give a [ location ] of data to what i need to find and then give row or column range from where i need to find the given value & then give a [ location ] of data to what i want to be replace with.
"find and replace by row & column range & than by specific criteria and than by specific location."
in more than 100 sheets in entire workbook
please help.
This is a great tool, does anyone knows an easiest way??
I'm working with a system that has over 59000 references... so every time the replace all is activated. I lose an entire day.
i actually needs to find cell number "D12" in column "D" and replace with Cell Number "B8" for example
find what = Cell Number "D12" John McNamara
find Where = in Column "D"
Replace with = Cell Number "B8" Bieber D'Souza
Replace Range = Column "D"
In which Sheet = All Sheets in Work Book (more than 100 Sheets)
Note: in every Sheet Cells Number "D12" & "B8" containing Different Employ Name but the find rang and replace rang are same in every sheet and find what cell number and replace with cell number are same also.
please help!
thank you. saved lot of time.
Thank you from the bottom of my heart!
Hi, I am trying to figure out how to use RE to find and replace several values in a column. Using find and replace does not work because of the values I am working with. I have a column with hundreds of rows that have a description of several operating systems and other info, which looks like this: Windows Server 2008 R2 Member Server Security Technical Implementation Guide; Windows 2008 Member Server Security Technical Implementation Guide; Solaris 10 10 SPARC SECURITY TECHNICAL IMPLEMENTATION GUIDE; and Windows Windows 2003 Member Server Security Technical Implementation Guide.
I need to be able to find and replace (or basically curtail the descriptions) to be Windows 2008 R2; Windows 2008; Windows 2003; and Solaris 10. BUT when I run find and replace with just *2008*, it finds every instance, including the ones with R2 at the end. I need it to only change the ones with 2008 to Windows 2008 and the ones that have 2008 R2 to Windows 2008 R2. I know it is possible, but I have no clue on how to write a macro to do this.
Thanks for your help,
Gerard
Wickedly efficient workaround. Excel really is a powerhouse program, all you have to do is dig into it. Ctl ~ exposes the formulas, and Ctl H allows for the multi edit. Brilliant, Chandoo!