The use of the Sumproduct function for doing multiple criteria Sum If’s is possibly one of the greatest extensions of an Excel function beyond what it was primarily designed for. Maybe it was actually designed with that in mind ?
However Sumproduct can be extended even further through use 2D Ranges together with carefully constructed queries.
The examples below are included in the Example File, Excel 2003 Example File.
Scenario 1: Lookup a value within a 2D Range matching 2 criteria
You have a table of Dates and Fruit Sold and Number Sold each Day
How many Bananas did I sell on the 4thMay?
In the above I have setup 3 Named Ranges
Named ranges are used as it makes the reading of forthcoming formulas easier.
Fruit: C2:H2
Dates: B3:B12
FruitData: C3:H12
So, How many Bananas did I sell on the 4th May?
Using the equation =SUMPRODUCT((Fruit=D16)*(Date=D15)*FruitData)
Returns the correct answer 31
Related: Doing 2way lookups in Excel
Scenario 2: Sum all values within a 2D Range matching 2 criteria
You have a table of Dates and Cars Sold and Number Sold each Day. There are multiple entries for on various days, possibly from various salesmen.
How many Holden cars did I sell on the 3rd May?
So, How many Holden cars did I sell on the 3rd May?
Using the equation =SUMPRODUCT((Dates=D17)*(Cars=D18)*CarData)
Returns the correct answer 9 = (1 + 5 + 3)
Scenario 3: Sum values within a 2D Range matching multiple unordered criteria
You have a table of Dates and Cars Sold and Number Sold each Day, There are multiple Entries for on various days.
How many Ford and Suzuki cars did I sell on the 10th May?
So, How many Ford and Suzuki cars did I sell on the 10th May?
Using the equation =SUMPRODUCT((Dates=D24)*((Cars=D25)+ (Cars=E25))*CarData)
Returns the correct answer 13 = (4 + 5 + 3 + 1)
Note that this can be extended to add additional queries where the Car Type can be entered in any cell in the Range D25:H25
=SUMPRODUCT((Dates=D24)*((Cars=D25)+ (Cars=E25) + (Cars=F25) + (Cars=G25) + (Cars=H25))*CarData)
Scenario 4: Sum values within a 2D Range matching multiple ordered criteria
You have a table of Dates and Cars Sold and Number Sold each Day, There are multiple Entries for on various days.
How many Toyota and Holden cars did I sell on the 10th May?
How many Toyota and Holden cars did I sell on the 10th May?
Using the equation =SUMPRODUCT((Dates=D30)*(Cars=D31:H31)*CarData)
Returns the correct answer 21 = (3 + 6 + 6 + 6)
Note that this can be extended to allowing additional queries but the Car Type must be entered into the same position as in the Header Row.
How Does This Work?
The above techniques is using matrix arithmetic to setup a conjunctive truth table within the Sumproduct formula.
Using =SUMPRODUCT((B4:B6=D10)*(C3:E3=D9)*(C4:E6))
The conjunctive truth table logic (B4:B6=D10)*(C3:E3=D9) is simply saying make a matix of elements that are true when the conditions are met and false otherwise
Sumproduct then takes this and multiplies and it by the data values and accumulates the values to get the sum of the matching values.
It is important to note that the Width and Height of the Criteria Row and Column must match the Width and Height of the data area or a #Value! error is returnd.
The Maths
To understand and explain how this works I will use a simple model with 3 rows and 3 columns see below
The formula: =SUMPRODUCT((B4:B6=D10)*(C3:E3=D9)*(C4:E6)), shown above consists of 3 areas
(B4:B6=D10) is a 3 Rows x 1 Column range
(C3:E3=D9) is a 1 Row x 3 Columns range
(C4:E6) is a 3 Row x 3 Column range
Breaking the formula into components
=SUMPRODUCT((B4:B6=D10)*(C3:E3=D9)*(C4:E6))
(B4:B6=D10)*(C3:E3=D9) is the same as multiplying 2 arrays, representing the 2 areas as shown below
You can see that where the components are True I have put a 1 and a 0 where they are false
Where the Date was 3-May Excel evaluates this to 1 and similarly where the Fruit was a Banana, Excel evaluates this to 1.
Where the criteria isn’t met Excel evaluates this to a 0
The multiplication of a 3 x 1 and a 1 x 3 array is a 3 x 3 array
Representing the (B4:B6=D10)*(C3:E3=D9) part of the equation
Next this is multiplied by the data area
=SUMPRODUCT((B4:B6=D10)*(C3:E3=D9)*(C4:E6))
This is the same as multiplying two 3×3 arrays which produces a 3 x 3 array, below:
Sumproduct then adds up all the array components to get the final answer of 3.
Modifications
The Data Area can be included in the Truth Table Logic or as a seperate component of Sumproduct.
=SUMPRODUCT((B4:B6=D10)*(C3:E3=D9)*(C4:E6)) and =SUMPRODUCT((B4:B6=D10)*(C3:E3=D9), (C4:E6)) are both equal
Multiple “OR” crietria can be added by use of the+ operator within criteria
In Scenario 3 above, we sum the number of Ford or Suzuki cars sold on the 10th May.
SUMPRODUCT((Dates=D24)*((Cars=D25) + (Cars=E25) + (Cars=F25) + (Cars=G25) + (Cars=H25))*CarData)
The Or logic is added to the criteria by use of the + operator above within the criteria for Cars
the And logic is added by use of the * between the Dates and Cars criteria
Other Logic Elements
You can add Greater Than (>), Less Than (<) etc and other logic elements to the queries to suit your requirements.
Sample File
The examples below are included in the Example File, Excel 2003 Example File.
What do you think of the above technique ?
What do you think of the above technique ?
Let us know in the comments below.
40 Responses to “Lost Excel Functions”
Of all the functions, I think the BAHTTEXT function is the biggest "Why is this here???"
It's use would be limited to a very, very small demographic. A better function would have been a generic translate function where you pick the language (even if it was only the top 5 or something...)
Lost by whose definition? Some people use these functions(me). There are alot of words in English dictionary that aren't used.
This is a great post, especially because I love Lost. Thanks!
See the following blog post on Excel Semi-Pro which identifies the flaws with the DATEDIF function.
http://excelsemipro.com/2011/01/how-many-years-months-and-days-has-it-been/?utm_source=feedburner&utm_medium=feed&utm_campaign=Feed%3A+ExcelSemi-pro+%28Excel+Semi-Pro%29
Nice Post Hui. It is amazing what is in the program that you have never heard of. I typed in =d and looked at the functions. "Delta" popped out although it is documented, why would you ever use it vs. just comparing with an equal sign (=1=1).
I use Datedif at times. What will be nice is if alternatives to these "Lost" functions can also be posted with examples. That'll be a good reading and also deter users from using functions "soon to be made obsolete"
I don't think the intersect AND logic is very well documented:
=B1:B3 A2:C2 One intersection
=SUM(D9:F9 E8:F10) Two intersections
=SUM(D9:F9 E8:E10 F8:F10) No intersection --> #NULL! Not seen very often
There might be a OR logic lurking as well
//Ola
Interesting post! 😉
I found out that only "evaluate" isn't available in my excel 2007.
Great post, thanks Hui! 🙂
@Fred
Evaluate is a Excel 4 Macro Function and not a spreadsheet function
It can only be used in Named Ranges and VBA, not as a spreadsheet function.
@OlaSa
I forgot all about the 2 Operators you mention.
Daniel at Excel Hero has done a story about them at: http://www.excelhero.com/blog/2010/06/which-function-to-use---part-1.html
@Steve T
Yes, Delta and Gestep are odd functions and easily replaced with alternative logic.
These 2 functions may have uses in handling ranges and not just single cells.
I read somewhere not too long ago (at Daily Dose, possible) that BAHTTEXT is "rumoured" to be a self-interested joke by the MS Excel programmers: although this function would be at least equally useful for other currencies, they did the baht first because they're extremely partial to Thai takeaways and wanted to speed up the turnaround time
...and why isn't there a reverse ROMAN?
there is, just replace Roman with Arabic
=ROMAN(2023) is MMXXIII
=ARABIC("mmxxiii") is 2023
Hi Hui,
I think you have mis-defined the Result range name because you have made the name relative. The proper formula should have been
=EVALUATE($A$1).
NB: I use the technique in this post: http://www.jkp-ads.com/articles/chartanequation00.asp
Found this posting with some User Defined Functions and VBA for reversing Roman Numerals:
http://www.excelbanter.com/showthread.php?t=141566
Hi Hui - Thanks for the post - a little off the excel topic, but wondering what does "you"ll be the full bottle" mean? Have never heard this expression before. 🙂
@Tra
“you'll be the full bottle” is Aussie slang for "You'll know all about it"
@Jan Karel Pieterse
Thanx for the input
.
=Evaluate(A1) is ok as long as A1 is the active cell
It can create problems if it isn't.
.
Ideally it should be entered as =EVALUATE(SheetName!$A$1)
I have updated the post accordingly
Further info on DELTA:
Have 1 cell formatted to number (a1), and the other formatted to text (a2).
Type the number 1 into both cells
The formula:
=A1=A2
returns FALSE (number does not equal text)
formula:
=DELTA(A1,A2)
returns 1 (the equivalent of true). I see limited places where this would be useful, but wanted to point out that they do function differently.
In Excel2010
I just tried Delta with
2 2 =Delta(A2, B2) =1
'2 '2 =Delta(A3, B3) =1
'2 2 =Delta(A4, B4) =1
C C =Delta(A5, B5) =#Value!
Lines 3 & 4 should also give errors but don't ?
The formatting of the cells shouldn't affect the results as that is just for display
Great post.
Interesting that the roman function returns a #value! if you go any higher than 3999
@Chandoo Not trying to be a shameless self promoter (I just want to spread the Excel awesomeness) but I've found an obscure way to create a mouse-over effect in Excel using the Hyperlink() formula and some VBA. I've used this technique in some of my dashboards at work, and as an example of how it's useful, you could use it in the Grammy Bump chart to simply let users rollover a year instead of clicking on it. I talk about it in the latest post of my rarely updated blog which is linked on my name in this post. Or, here's the long and short of it:
.
=HYPERLINK(MyFunction(), "Mouseover me!")
.
Then in some module:
Public Function MyFunction()
Msgbox "hi!"
End Function
.
To test: place your mouse over the underlined portion of the cell. To make the entire-cell a mouse over target (not just the underlined portion), word wrap it. Also, if you want the function to change parts of your spreadsheet, you'll need to wrap the Hyperlink formula in an IFERROR (you'll see what I mean when you try it). Or you can read about it by clicking on my name, either way, make sure to have fun!
@Hui
Seems like DELTA has the advantage in being able to recognize "text as numbers". And yes, thanks for clarifying my statement about formatting. I should have been clearer in the fact that I just wanted to compare a text string with a number...in which case, maybe I should have just written:
=DELTA(1,"1") 'Results in 1
@Jordan... wow, that is a beautiful trick. I have not yet tested it, but seems like it has lots of potential. Let me play with the idea and may be write a follow-up article on this.
Btw, you are welcome to share information and links. That is the whole point of commenting. 🙂
Alright, i am no engineer, but a simple formula can also do what Delta does without having a whole function for it. That is like creating a function called Add (Syntax =Add(a1,a2) that results in the addition of A1+A2
This will do what delta does on numbers and textNumbers and its not rocket science or structural engineering 🙂 🙂
=VALUE(A1)=VALUE(A2) will also yield true/false
And if you need the result as a number =(VALUE(A3)=VALUE(A4))*1
@SteveT
You know, they invented this function you described in Excel. It is called SUM, not ADD 🙂
There are also functions PRODUCT, SUMPRODUCT and others. All of them simple definied, and it doesn't mean they aren't to be in Excel.
Of the under-used functions, I think Evaluate is probably the most useful.
The short UDF presented here:
http://newtonexcelbach.wordpress.com/2008/04/22/evaluate-function/
allows Excel to evaluate functions entered as text, without the need to create named ranges.
An application using this function can be downloaded here:
http://newtonexcelbach.wordpress.com/2008/03/25/section-properties-of-defined-shapes-spreadsheet/
thanks for this. I hope to use "convert" more frequently henceforth
@ruvelk and @Chandoo
I checked out the link you provided (ruvelk) and the explanation given of the intervals 'MD' 'YM' AND 'YD' provided above (Chandoo) and the information is not quite correct.
'MD' returns the number of days since the last completed month.
'YM' returns the number of months since the last completed year.
'YD' returns the number of days since the last completed year.
As far as I can see there is no flaw in the function just perhaps a misunderstanding of what is does.
eg
using the 'MD' interval
02/28/2010 to 01/11/2011
Last completed month = 12/28/2010
Number of days between 12/28/2010 and 01/11/2011 = 14
Using 03/01/2010 to 01/11/2011
Last completed month = 01/01/2011
Number of days between 01/01/2011 and 01/11/2011 = 10
Cheers
Andrew
@Andrew
I think we are talking about the same thing in different ways.
From the post:
"md" Days Excluding Years And Months Complete calendar days between the dates as if they were of the same month and same year.
so using your dates
28/2/10 to 11/1/11 will count 29, 30 and 31 as if they are in January and then the first 11 days in January = 14 days.
That is, it is counting the dates as if they are both in January, same year, and so there is 14 days between them.
Hi,
Can any one tell how to enter data into range of cells through a single cell without the help of VBA.
Regards
Chandra
@ Chandra
Can you be more specific?
@Chandra
If you type this into A1:
={1,2,3;4,5,6;7,8,9}
then select A1:C3 and use Control+Shift+Enter
You will get a 3x3 array in A1:C3
The formula in each cell in that range will be:
{={1,2,3;4,5,6;7,8,9}}
Commas separate columns. Semicolons separate rows,
This is of limited use since the cells in this array cannot be individually edited.
There is at least 1 Excel 4 macro that provides functionality that cannot (AFAIK) be replicated in later versions of Excel. GET.CHART.ITEM is used to get the exact coordinates of chart elements, including the coordinates of individual points in a line graph (or edge and corner cordinates of bars, or columns for those types of graphs). For example:
sngXPos = ExecuteExcel4Macro("get.chart.item(1,1, ""S2P" & lX & """)")
returns the X position of each point in series 2 of a line graph as you iterate from 1 To ActiveChart.SeriesCollection(2).Points.Count
Documentation file for Excel4 macros available at:
http://support.microsoft.com/kb/128185
Excel 2010 has incorporated most (but not all?) of this functionality as described here:
http://blogs.office.com/b/microsoft-excel/archive/2010/02/16/migrating-excel-4-macros-to-vba.aspx
Unfortunately, I don’t see Evaluate working in Excel 2010.
I have Microsoft Office Professional Plus 2010.
When I try it myself, or download the example file, I have #NAME?
result in the cell containing “=Result” formula.
The Evaluate function does work in Excel 2010 and 2013.
It is called from a VBA function, so maybe the problem is that macros are not enabled.
[…] To know how many months are left between TODAY() and date in A1, use = DATEDIF(TODAY(), A1, “m”). Related: How to use DATEDIF function. […]
[…] To know how many months are left between TODAY() and date in A1, use = DATEDIF(TODAY(), A1, “m”). Related: How to use DATEDIF function. […]
I once ran across an undocumented version of GETPIVOTDATA. The syntax was something like "GETPIVOTDATA($A$3, ...", where $A$# would reference the pivot table then you could concatenate text fields to select the specific data you were after. I found this useful as I could use an IF("condition", "place field text", ""). This way if the "condition" was met it would field data requested otherwise nothing was included. This worked well if nested condition were not available. Hope this is clear. I can't find the alternate syntax for GETPIVOTDATA anywhere. Does someone have it?
@Marty
Yes, GetPivotData is a usefull function but I believe it has been documented since 2007
https://support.office.com/en-us/article/GETPIVOTDATA-function-8c083b99-a922-4ca0-af5e-3af55960761f