fbpx
Search
Close this search box.

10 Advanced IF formula tricks you must know

Share

Facebook
Twitter
LinkedIn

IF is the most used Excel function out there. Here are 10 advanced IF tricks to take your formulas to next-level 🚀

In this article, you will learn:

  • Only one of, two out of three type rules
  • Between condition check with MEDIAN
  • Replacing Nested IF with shorter function
  • Using boolean logic to replace IF formulas
  • Arrays with IF function
  • Wildcard checks with IF function
  • How to use IF formula in other places
    • Conditional formatting
    • Data validation
    • Charts

Sample data for the examples

All examples in this article use below sample data. Assume it is in the range C8:G23sample-data-if-formula-advanced-tricks

You can download this data alone for practice purpose from here.

Includes sample data for practice, completed Excel workbook

#1 - Only one of condition

Situation

Identify employees who are only one of gender=male or salary under $85,000

Formula

				
					=IF(XOR(D8="Male",G8<85000),"Include", "Exclude")
				
			

Explanation

XOR function will return TRUE if an odd number inputs are TRUE, else FALSE. 

So, our XOR(D8=”Male”, G8<85000) will be useful for checking only one of condition.

Note: XOR doesn’t work when you want to check only one of when you have more than 2 conditions. For that refer to next trick.

Also read: Either Or formula in Excel

#2 - Two out of Three Check

Situation

Flag employees when they meet any two out of below three conditions.

  • Department is Website
  • Year of join is 2019
  • Salary is above $90,000

Formula

				
					=IF((E8="Website")+(YEAR(F8)=2019)+(G8>90000)>=2,
        "Include", "Exclude")
				
			

Explanation

The trick is in understanding Excel treats TRUE as 1 and FALSE as 0.

So, the expression (E8=”Website”)+(YEAR(F8)=2019)+(G8>90000)

will be converted a bunch of 1s & 0s and added up, depending on the details of employee.

We can then simply check if such number is >=2 to see if any two out of three conditions are met.

More: Two out of three – other ways to do it

#3 - Using MEDIAN for Between Condition

Situation

Identify employees joined between 1-Jan-2019 and 30-Jun-2019.

Formula

				
					=IF(MEDIAN(F8,DATE(2019,1,1),DATE(2019,6,30))=F8,
        "Review","")
				
			

Explanation

Normally, we use AND() function to check for between condition. But, you can also use MEDIAN for this. 

The pattern goes like,

=MEDIAN(your value, above, below) = your value

The above will be TRUE if your value is between above and below values.

For example, =MEDIAN(7, 3,9) = 7 is TRUE.

Read more: How to write BETWEEN formula in Excel

#4 - Replacing Nested IF functions

Situation

Calculate staff bonus based on below rules:

  • 1% for Website staff
  • 3 % for Sales staff joined in 2018
  • 2% for others

Formula

				
					=IFS(E8="Website",1%,
        AND(E8="Sales",YEAR(F8)=2018),3%,
        TRUE,2%)
				
			

Explanation

Nested IF functions can be hard to write and tricky to maintain. That is why, you should use the newly introduced IFS() function. 

The syntax for IFS goes like this:

=IFS(condition1, value1, condition2, value2…)

But, IFS() doesn’t have ELSE option…?

Well, you can use TRUE as last condition to fix this.

In the above formula TRUE, 2% part handles the ELSE case beautifully.

#5 - Boolean Logic to avoid IF formulas

Situation

Calculate staff bonus based on below rules, but don’t use any IF formulas:

  • 1% for Website staff
  • 3 % for Sales staff joined in 2018
  • 2% for others

Formula

				
					=2% - (E8="Website")*1% + AND(E8="Sales",YEAR(F8)=2018)*1%
				
			

Explanation

You can use boolean logic checks to altogether avoid IF formulas. This works well when your outputs are numbers.

The above formula calculates staff bonus by using TRUE=1 & FALSE=0 notion.

Let’s test it out for below staff:

boolean-replacement-if-sample-data

For Gigi:

  • 2% – (FALSE)*1% + (TRUE)* 1% = 3%

For Curtice:

  • 2% – (FALSE)*1% + (FALSE)*1% = 2%

Read more: Daniel Ferry’s excellent I heart IF

#6 - Checking if a value is in another list

Situation

Check if an employee is part of on call support team
(range: C32:C36)

Formula

				
					=IF(COUNTIFS($C$32:$C$36,C8),"On call","Not on call")
				
			

Explanation

We can use COUNTIFS or MATCH functions to do this. I prefer COUNTIFS.

Just count if a given data point is in another list.

Why don’t we check >0?

Remember, Excel treats any number other than 0 as TRUE. So we don’t need to write COUNTIFS($C$32:$C$36,C8)>0. 

#7 - Arrays with IF formula

Situation

Calculate median salary of website staff

Formula

				
					=MEDIAN(IF(E8:E23="Website",G8:G23))
				
			

Explanation

When you use arrays in the IF formula, it will return an array of outcomes too.

So for eg. =IF({TRUE,TRUE,FALSE}, {1, 2, 3}, {“A”,”B”,”C”}) will return {1, 2, “C”} 

We can use this powerful idea to calculate median salary of website staff too.

What about ELSE part? It’s missing no?

If you don’t mention the ELSE part of IF formula, it will simply return FALSE for those values.

So, in our case, we get 

{FALSE;90700;48950;FALSE;FALSE;107700;…FALSE}

When MEDIAN reads those values, it will ignore the FALSEs and calculate MEDIAN for rest.

Read more: Calculating RANKIFS with Excel

Situation 2

Show all names of “Finance” staff in one cell, comma seperated.

Formula

				
					=TEXTJOIN(",",,IF(E8:E23="Finance",C8:C23,""))
				
			

Explanation

This works same as the MEDIAN(IF()) structure. For more applications of this technique, see the Excel Risk Map

#8 - Wildcard based conditions

Situation

Identify if an employee’s name contains letters bo

Formula

				
					=IF(COUNTIFS(C8,"*bo*"),"bo person","not a bo person")
				
			

Explanation

IF function is not aware of wildcards. But we can use one of the other wildcard aware functions inside IF to solve the problem. You can use either of XLOOKUP, XMATCH, MATCH, VLOOKUP, COUNTIFS for this. 

I prefer COUNTIFS.

The COUNTIFS(C8, “*bo*”) will be 1 if name in C8 has bo in it, else 0.

Rest is self-explanatory.

Read more: Making VLOOKUP formula go wild | Not so wild lookups

#9 - IF formula with Conditional Formatting

Situation

Highlight employees that meet conditions specified in below cells.

input-rules for conditional formatting

Rule

				
					=AND($E8=$J$50,$D8=$J$51)
				
			

Explanation

When checking rules in conditional formatting you don’t need to use IF formula. Just use the condition part of the formula alone.

Here is the result of our rule.

result of conditional formatting

 

Read more: 5 simple & useful conditional formatting tricks

#10 - Using IF with Charts

Situation

Make a chart with employee salaries, but highlight staff making above average salary in a different color.

Process

  1. Add an extra column in your data and use IF formula to check if a person’s salary is above average.
  2. Make chart with both original salary & the new column.
  3. Overlap the bars (or columns) 100%
  4. Color them accordingly. 

Formula

				
					=IF(G8>AVERAGE($G$8:$G$23),G8,NA())
				
			

Outcome

This is how my chart looks.

highlighting staff with above average salary

Read more: How to highlight important points on your chart

Resources - File & Video

Includes sample data for practice, completed Excel workbook

Watch the video & learn these techniques

More on IF formula

Resources

Check out below tutorials to master IF formulas & business logic

Homework problems

What is your favorite IF formula trick?

Share it in the comments. Let’s learn from each other.

Facebook
Twitter
LinkedIn

Share this tip with your colleagues

Excel and Power BI tips - Chandoo.org Newsletter

Get FREE Excel + Power BI Tips

Simple, fun and useful emails, once per week.

Learn & be awesome.

Welcome to Chandoo.org

Thank you so much for visiting. My aim is to make you awesome in Excel & Power BI. I do this by sharing videos, tips, examples and downloads on this website. There are more than 1,000 pages with all things Excel, Power BI, Dashboards & VBA here. Go ahead and spend few minutes to be AWESOME.

Read my storyFREE Excel tips book

Excel School made me great at work.
5/5

– Brenda

Excel formula list - 100+ examples and howto guide for you

From simple to complex, there is a formula for every occasion. Check out the list now.

Calendars, invoices, trackers and much more. All free, fun and fantastic.

Advanced Pivot Table tricks

Power Query, Data model, DAX, Filters, Slicers, Conditional formats and beautiful charts. It's all here.

Still on fence about Power BI? In this getting started guide, learn what is Power BI, how to get it and how to create your first report from scratch.

Weighted Average in Excel with Percentage Weights

Weighted Average in Excel [Formulas]

Learn how to calculate weighted averages in excel using formulas. In this article we will learn what a weighted average is and how to Excel’s SUMPRODUCT formula to calculate weighted average / weighted mean.

What is weighted average?

Wikipedia defines weighted average as, “The weighted mean is similar to an arithmetic mean …, where instead of each of the data points contributing equally to the final average, some data points contribute more than others.”

Calculating weighted averages in excel is not straight forward as there is no built-in formula. But we can use SUMPRODUCT formula to easily calculate them. Read on to find out how.

15 Responses to “10 Advanced IF formula tricks you must know”

  1. Michael says:

    Great examples! Thanks so much for sharing.

  2. Thank you so much Chandoo. It is a great post to be honest, with many super good functional tricks. Once again thank you!

  3. Robert Clark says:

    Minor point - in the first example on Median, you refer to above and below values, but in the example you then use a low and high value - may confuse some people!

  4. Tetonne says:

    Thank you so much Chandoo. your site is great.

  5. Hi Chandoo
    Thanks for sharing.
    You could add an 11th tip.
    The IF function and IFS can return a range.
    Instead of
    =IF(A1=B1,SUM(C1:C10),SUM(D1:D10)
    you could use
    =SUM(IF(A1=B1,C1:C10,D1:D10))
    Regards
    Neale

  6. Duncan Williamson says:

    As always, you have posted something very useful, Chandoo. As I read through your examples, though, I thought the FILTER() function could probably be used as well.

    I know you know this and I know you have FILTER() function examples elsewhere but I thought I would share some of them here to provide a contrast. I also want to say that there is absolutely nothing wrong with your examples and my suggestions are not trying to be corrections at all!

    My answers return the name of the person rather than Include, Exclude and so on

    Either Male or Salary <85,000:
    Yours =IF(XOR(D8="Male",G8<85000),$H$4,$H$5)
    Mine =FILTER(C8:C23,(D8:D23="Male")-(G8:G23 90,000" is easy
    Yours becomes =IF((E8="Website")*(YEAR(F8)=2019)*(G8>90000),$I$4,$I$5)
    Mine =FILTER(C8:C23,(E8:E23="Website")*(YEAR(F8:F23)=2019)*(G8:G23>90000))
    BUT as it is, I don't have a solution to your question ... yet!

    For Joined between 1-Jan-2019 and 30-Jun-2019
    Yours =IF(MEDIAN(F8,DATE(2019,1,1),DATE(2019,6,30))=F8,$J$5,"")
    Mine =FILTER(C8:C23,(F8:F23>=DATE(2019,1,1)*(F8:F23<=DATE(2019,6,30)))) ... BUT it gives me a rogue answer to Barr

    For Check if an employee is part of on call support team in C32:C36
    I used VLOOKUP: =IFERROR(VLOOKUP(C8:C23,C32:C36,1,0),"Not on Call")

    Name contains bo
    Yours =IF(COUNTIFS(C8,"*"&$O$5&"*"),"bo person","not a bo person")
    Mine =FILTER(C8:C23,ISNUMBER(SEARCH("bo",C8:C23)))

    Duncan

  7. Lino Wchima says:

    Thanks Chandoo for this great post, as always.
    In response to your request of sharing our favorite IF formula tricks, I will add these grains of sand:

    1)
    On tip “#5 - Boolean Logic to avoid IF formulas” I would add that it is also possible to avoid the “AND” boolean operator using “*” instead (i.e. multiplication operator).
    Thus, your formula:
    =2% - (E8="Website")*1% + AND(E8="Sales",YEAR(F8)=2018)*1%
    may be written as follows with same results:
    =2% - (E8="Website")*1% + (E8="Sales")*(YEAR(F8)=2018)*1%

    2)
    The above technique of replacing OR and AND with + and * may be used to reduce the clutter in a complex “logical_test” of an IF function whose outputs are any type (not limited to numbers).

    3)
    Your tip “#3 - Using MEDIAN for Between Condition” works nicely as it flagged five employees with the word “Review”.
    But, sometimes is quite convenient flagging them instead with numbers: 1 for “Review”, 0 for not to “Review”. One reason for this convenience is that the numbers 1 and 0 may be used directly as TRUE and FALSE in other subsequent “logical_test” (i.e. in other columns). Another reason is that this technique eases counting.
    Thus, your formula:
    =IF(MEDIAN(F8,DATE(2019,1,1),DATE(2019,6,30))=F8, "Review","")
    may be written as follows with same “logic” results, with the aforementioned advantages for subsequent uses:
    =--(MEDIAN(F8,DATE(2019,1,1),DATE(2019,6,30))=F8)
    where obviously “--” is not a typo.

    Best regards,
    Lino.

  8. Achyutanand Khuntia says:

    Dear Sir,

    Thank you for this great post , i appreciated all above logic.

    but i asked about #7 formula that is =MEDIAN(IF(E8:E23="Website",G8:G23))

    as per my understanding answer should be obtain

    this row - Ches Bonnell Male Website 22-Jul-18 $88,050 .

    i will love to understand how it can answer is $69,120

    • Philippe Briand says:

      Dear Achyutanand,

      The Median function gives the value which separates a group of value in two. In the Website department, there is seven persons, so if we order the values from the minus to the max, the function will give us the value un the forth position, $69,120. There are 3 values under and 3 values upper.

      Best regards
      Philippe

  9. Philippe Briand says:

    Hi Chandoo,
    Many thanks for these tips.

    With tip 7, if we want to obtain the median salary of female working in finance department, we can use this formula :
    =MEDIAN(if(D8:D23="female",SI(E8:E23="finance",G8:G23)))

    Best regards,
    Philippe

  10. nana says:

    hello need help with formula.. we need to incorporate this three formulas to one formula

    SATURDAY FORMULA
    =IF($K2=6,($J2+3),$J2)

    SUNDAY FORMULA
    =IF($K2=7,($J2+2),$J2)

    MONDAY FORMULA
    =IF($K2=1,($J2+1),$J2)

  11. Emad says:

    Thank you
    I need more,
    In IFS and Boolean examples
    Please add another condition:
    For each category of bonus there is a minimum and maximum value condition
    For example sakes %age is 2% but no less than x value (or whatever cell it contains it) and not more than another value
    How it is done?

  12. LOVE THE TIPS!
    HATE THE GOOGLE ADS!!

    CHEERS,
    -SAYNOTOGOOGLEADS

Leave a Reply