Recently I optimized a pretty long nested IF formula using a simple but elegant trick. I made it 80% shorter! In this article, let me explain the process and share the formulas.
The Situation: Discount Calculation
Imagine you have to calculate the appropriate discount using below rules.
And you have transaction data like below:
How would we write the formula in column H?
Option 1: Long, Nested IFs
We can calculate the discount by writing a complex, lengthy and nested IF formula.
Here is one such formula:
=LET(cat, XLOOKUP(F5,products[Name], products[Category]),
IFS(OR(D5="India", D5="USA",D5="UK"),
IFS(AND(G5>=200, G5<=999),
IF(OR(cat="Bars", cat="bites"),
IF(E5="New",Rules!$F$7, Rules!$F$8),
0),
AND(G5>=1000, G5<=1999),
IFS(cat="Bars",
IF(E5="New",Rules!$F$11, Rules!$F$12),
cat="Bites", Rules!$F$14,TRUE, 0),
G5>=2000,
IF(E5="New", Rules!$F$16,
IFS(
cat="Bars",Rules!$F$17,
cat="Bites", Rules!$F$18,
TRUE, 0)
)
)
)
)
What this formula is doing?
- We start by calculating the “category” of the product using XLOOKUP and storing it in the variable cat
- Then we check the rules (refer to picture 1 above)
- Once we reach the lowest level of the rule, we get the matching discount from the rules worksheet cells.
- If no discount applies, we return 0
What is wrong with this formula?
Long and error prone
Such formulas are too long to write correctly and errors are not easy to catch.
Not easy to update
When the business rules change, the formulas become hard to edit.
Hard to maintain
The formulas become a nightmare to maintain and document.
Option 2: A smart alternative
What if we can rewrite the rules so that we can write shorter formulas?
I suggest rewriting such business rules as a table like this:
Once you have such a table, we can then rewrite our formula using SUMIFS & wildcard characters. Like below:
=LET(cat, "*"&XLOOKUP(F5,products[Name],products[Category])&"*",
SUMIFS( discount[Discount],
discount[Country],"*"&D5&"*",
discount[Category],cat, discount[Customer Type],"*"&E5&"*",
discount[Quantity from],"<="&G5,
discount[Quantity to],">="&G5))
How does this formula work?
- We start by calculating the “category” of the product using XLOOKUP, pad this with * and store it in the variable cat
- Then we use SUMIFS to add up [Discount] column by
- Checking the country (in D5) against [Country] column of discount table
- cat against [Category] column
- Customer type (E5) with [customer type] column
- Quantity (G5) with the to & from ranges
- If there are no discounts then the SUMIFS would be 0
- Else it would tell us what the discount is.
Advantages of the SUMIFS approach
Easy to write & test
The formula is easier to write and test. Hence fewer errors.
Easy to maintain & update
Whenever the business rules change or new products are added, updating the discount table is all you need to do.
Scalable
Even when you have 100s of rules, this table approach is easy to scale and won't increase the formula size.
Use FILTER to work with text
If you need to get a non-numeric value as the output, we can use FILTER() instead of SUMIFS.
Video Tutorial - Honey, I shrunk the formulas
I made a video about this concept. See it below or click here to watch it on my YouTube channel.
Try it yourself - Here is a sample file
Want to have a play with the data and see which formula is easier to write?
Your thoughts on this approach?
What do you think about this approach? Leave a comment.
Also, do check out below pages for more on other ways to make advanced Excel formulas.
4 Responses to “A clever technique to simplify your long, nested IF formulas”
Love the method, very nice and clean. I just have a feeling that with manually created table for the discounts that errors or duplications will creep in, and it doesn't have discounts change over time. Presumably the real data set had dates in it, so start dates are useful in discount lookup. I would recommend a countifs just to double check you are only getting one result, but it's a minor thing
How can we choose a large number of tables and pages within a single PDF, then repeat that process for the remaining PDFs within the same folder, and finally use power query to extract just those tables and pages?
I love it thanks a lot
Love this technique, it's very well-organized and tidy. However, I do have a concern that when using a manually created table for discounts, there might be errors or instances of repetition creeping in. Additionally, this method doesn't account for changes in discounts over time. Assuming the original data set included dates, having start dates would be beneficial for looking up the applicable discount.