fbpx
Search
Close this search box.

Quickly filter a table by combination of selected cell values using VBA

Share

Facebook
Twitter
LinkedIn

Filtering is one of the most used feature in Excel. It is a quick way to take lots of data and narrow down to the subset we want.

Naturally, there are many powerful ways to work with filters. To name a few,

But here is one common filtering scenario that is slow as snail.

Imagine you are looking at some sort of sales data (if you can’t imagine, look at the below demo).

Now, you want to filter this list for a combination like, gender=male, profession=self-employed, product category = chocolates and  quantity = 1.

If you use the right click, filter > filter by selected value approach, this will take several clicks.

Wouldn’t it be cool if you can select the entire combination and say filter?

Unfortunately, no such feature exists in Excel.

But you are not aiming to be ordinary in Excel.  You are aiming to be awesome in Excel. That means, you don’t take no for answer.

Fortunately, we can quickly write a VBA macro that filters a list by selection. So let’s do that. Here is what you will learn to create:

filter-by-selected-cell-combination-macro-demo

Filtering a table by selected combination of values using VBA

What we need to achieve?

Our goal is simple. User (that is you) selects a range of cells depicting the conditions for filtering. Something like this.

After selection, we fire up the filtering macro and instantly our list is filtered.

We can select a single-range or multiple cells (using CTRL+select technique)

Just to keep things simple, let’s assume the data is always in a table.

Algorithm / Steps for the VBA macro

Whenever you attempt to write VBA code, it is a good idea to start by writing down the steps in plain English. This is called as algorithm. By writing down the steps, we force our mind to think clearly about the problem at hand and come up with best possible solution.

Here are the steps for filtering the table by selected combination

  1. Make sure user has selected some values in a table
  2. Check if more than one row is selected. If so, exit as we don’t want to filter based OR conditions, we just want to filter based on AND conditions.
  3. For each cell in the selection
    1. Find out the corresponding column number
    2. Apply filtering on the table for corresponding column number with the cell’s value
  4. Repeat for next cell
  5. Done

VBA code – Filtering based on selected combination

Here is the VBA code for filtering based on selected combination. First examine the code. Then, we will understand key segments of it.



Sub combinationFilter()
    Dim cell As Range, tableObj As ListObject, subSelection As Range
    Dim filterCriteria() As String, filterFields() As Integer
    Dim i As Integer
    
    'If the selection is in a table and one row height
        
    If Not Selection.ListObject Is Nothing And Selection.rows.Count = 1 Then
        Set tableObj = ActiveSheet.ListObjects(Selection.ListObject.Name)
        
        i = 1
        ReDim filterCriteria(1 To Selection.Cells.Count) As String
        ReDim filterFields(1 To Selection.Cells.Count) As Integer
        
        ' handle multi-selects
        
        For Each subSelection In Selection.Areas
            For Each cell In subSelection
                filterCriteria(i) = cell.Text
                filterFields(i) = cell.Column - tableObj.Range.Cells(1, 1).Column + 1
                i = i + 1
            Next cell
        Next subSelection
        
        With tableObj.Range
            For i = 1 To UBound(filterCriteria)
                .AutoFilter field:=filterFields(i), Criteria1:=filterCriteria(i)
            Next i
        End With
        Set tableObj = Nothing
    End If
End Sub

How does the combinationFilter() macro work?

Checking if selected cells are inside a table

We start by checking if the selection is inside a table by checking if the Selection.ListObject is not nothing. (Aside: there is no direct way to ask if there is a listobject. So we ask indirectly, by saying Not Selection.ListObject Is Nothing.)

Once we know that Selection is inside a table, we grab the table object and set it to the variable tableObj.

Finding out what to filter

To set filters on a table, we need to know the field number (ie column number inside the table) and filter criteria.

Filter criteria is denoted by cell values in the selection.

We are extracting filter criteria values & determining the column numbers for each of the selection’s cells using a simple For Each loop.

Setting up the filters

Once all the filter criteria are determined, we simply loop thru the criteria and set the filters on table using tableObj.Range.AutoFilter method.

How to use this macro for your data?

This macro is designed to work with any table. I have tested it in Excel 2010 & Excel 2013 and it seems to work alright.

To use it with your data, follow below steps.

  1. Open your personal macros file
  2. Copy the combinationFilter() macro and paste it in your Personal Macros workbook in a module
  3. Save and close personal macros file.
  4. Add this macro to Excel ribbon or quick access toolbar (QAT)
    1. To add to ribbon: Refer to below picture.adding-macros-to-ribbon-tabs-howto
    2. To add to Quick Access Toolbar – click here for instructions.
  5. Once you select the combination to filter, click on the ribbon / QAT button.
  6. Done!

Download Selected Combination Filter Macro

Please click here to download the example workbook. Play with the macro to understand it better.

New to VBA? Learn how to exploit its awesome power

If you are new to VBA, you might find above example both awesome & hard to digest. But don’t worry. Start with this simple crash course on VBA. Check out more VBA examples. Very soon you will be automating parts of your work and impressing your boss. All the best.

Do you find the combination filter useful?

When I first thought about this macro, I feared the code might be too long or confusing. But I am happy with the outcome. It is a crisp, simple and powerful macro that I can use often when working with lots of data.

What about you? Do you find this macro useful? How are you planning to deploy it for your work situations. Let me know in the comments area.

Facebook
Twitter
LinkedIn

Share this tip with your colleagues

Excel and Power BI tips - Chandoo.org Newsletter

Get FREE Excel + Power BI Tips

Simple, fun and useful emails, once per week.

Learn & be awesome.

Welcome to Chandoo.org

Thank you so much for visiting. My aim is to make you awesome in Excel & Power BI. I do this by sharing videos, tips, examples and downloads on this website. There are more than 1,000 pages with all things Excel, Power BI, Dashboards & VBA here. Go ahead and spend few minutes to be AWESOME.

Read my storyFREE Excel tips book

Excel School made me great at work.
5/5

– Brenda

Excel formula list - 100+ examples and howto guide for you

From simple to complex, there is a formula for every occasion. Check out the list now.

Calendars, invoices, trackers and much more. All free, fun and fantastic.

Advanced Pivot Table tricks

Power Query, Data model, DAX, Filters, Slicers, Conditional formats and beautiful charts. It's all here.

Still on fence about Power BI? In this getting started guide, learn what is Power BI, how to get it and how to create your first report from scratch.

Weighted Average in Excel with Percentage Weights

Weighted Average in Excel [Formulas]

Learn how to calculate weighted averages in excel using formulas. In this article we will learn what a weighted average is and how to Excel’s SUMPRODUCT formula to calculate weighted average / weighted mean.

What is weighted average?

Wikipedia defines weighted average as, “The weighted mean is similar to an arithmetic mean …, where instead of each of the data points contributing equally to the final average, some data points contribute more than others.”

Calculating weighted averages in excel is not straight forward as there is no built-in formula. But we can use SUMPRODUCT formula to easily calculate them. Read on to find out how.

29 Responses to “Quickly filter a table by combination of selected cell values using VBA”

  1. Desk Lamp says:

    Nice idea, definitely one to go alongside the other filter macros in my personal ribbon.

    I'd make a couple of changes to the beginning of the code though. At present if you haven't selected cells within a table or you're selecting multiple rows within a column, the macro simply ends without the user knowing why. I'd do something like this at the begining:

    If Selection.ListObject Is Nothing then
    MsgBox "Please select a table and try again."
    Exit Sub
    End If

    If Selection.rows.Count = 1 Then
    MsgBox "Cannot apply filter to multiple rows within the same column. Please make another selection and try again."
    Exit Sub
    End If

    Then you can remove the IF criteria that surrounds all the code.

  2. Chandoo,

    interesting post. An alternative option is using the double click event (Worksheet_BeforeDoubleClick) instead of command buttons:

    http://www.clearlyandsimply.com/clearly_and_simply/2012/11/filter-excel-tables-by-double-clicking.html

  3. MF says:

    This is awesome! Would be even more AWESOME if it allows multiple rows selection under same column. 🙂

    I am not good in VBA, so that I cannot contribute to the codes.

    Nevertheless, here is my favorite shortcut keys for Filter by Selection:
    http://wmfexcel.com/2015/04/25/keyboard-shortcut-tip-filter-by-selection-with-menu-key/

    • Hi MF,

      To add multiple values from the same column we use an array and FilterByValues operator

      Sub combinationFilter()

      Dim oRange As Range
      Dim oArea As Range
      Dim oCell As Range
      Dim oLO As ListObject
      Dim sColumn() As Variant
      Dim n As Long

      ' Create Filter
      Set oLO = Selection.ListObject
      If Not oLO Is Nothing Then
      ReDim sColumn(1 To oLO.ListColumns.Count)
      Set oRange = Intersect(Selection, oLO.DataBodyRange)
      For Each oArea In oRange.Areas
      For Each oCell In oArea.Cells
      n = oCell.Column - oLO.Range.Column + 1
      sColumn(n) = sColumn(n) & _
      IIf(sColumn(n) vbNullString, ",", "") & oCell.Text
      Next oCell
      Next oArea

      ' Apply Filter
      For n = LBound(sColumn) To UBound(sColumn)
      If sColumn(n) vbNullString Then
      oLO.Range.AutoFilter _
      Field:=n, _
      Criteria1:=Split(sColumn(n), ","), _
      Operator:=xlFilterValues
      End If
      Next n
      End If

      End Sub

  4. Gary Lundblad says:

    I like the idea of this macro; however; when I copied the code to my personal workbook I got a couple of errors. The first one said "Compile error: Ambiguous name detected: resetFilters." It worked when I first opened Chandoo's test workbook and ran the macro. Then a couple of minutes later, when opening another unrelated workbook I received this error "Excel is running into problems with the 'c\users\glundblad\appdata\roaming\Microsoft\excel\xlstart\personal.xlsb' add-in. If this keeps happening, disable this add-in and check for available updates. Do you want to disable it now?"

    Any idea why I got these errors?

    Thank you!

    Gary

  5. jim says:

    hi, cool code...

    question... can u point me in the right direction for code that will filter a table based on inputs on a userform? my goal is to have a userform modify the filter, and then have the code update a listbox on said form with the results of the filter..

    thank you!

  6. Kuldeep says:

    Nice to see the idea... In practical setting up table and one value per coloum is not sufficient. it would have been awesome if this VBA would have been worked on Ranges (Not Table) and multiple selection per coloum as (OR) condition. adding this will make it perfect for industry use.

  7. Xiq says:

    This his a very cool macro! Love it!

  8. Chirayu says:

    For those of you who do not use tables much. But instead dump your data into a data sheet & just add borders around it. Here a file I made after reading this post which will work with data range rather than table.

    http://chandoo.org/forum/threads/vba-filter-data-range.24540/

    • Ryan says:

      Simply changing the tableObj to be a Range and tidying up a few things allows you to use Chandoo's original code on a data range.

      Sub combinationFilter()
      Dim cell As Range, tableObj As Range, subSelection As Range
      Dim filterCriteria() As String, filterFields() As Integer
      Dim i As Integer

      If Selection.Rows.Count > 1 Then
      MsgBox "Cannot apply filter to multiple rows within the same column. Please make another selection and try again."
      Exit Sub
      End If

      i = 1
      ReDim filterCriteria(1 To Selection.Cells.Count) As String
      ReDim filterFields(1 To Selection.Cells.Count) As Integer

      Set tableObj = Selection.CurrentRegion
      For Each subSelection In Selection.Areas
      For Each cell In subSelection
      filterCriteria(i) = cell.Text
      filterFields(i) = cell.Column - tableObj.Cells(1, 1).Column + 1
      i = i + 1
      Next cell
      Next subSelection

      With tableObj
      For i = 1 To UBound(filterCriteria)
      .AutoFilter field:=filterFields(i), Criteria1:=filterCriteria(i)
      Next i
      End With

      Set tableObj = Nothing

      End Sub

      • Chirayu says:

        Actually it doesn't function the same as the orginal version for tables because the Selection.Row.Count > 1 argument doesn't work. Which means you can select multiple rows.

        Try selecting individual cells in different rows & columns & running the code. The code will run instead of giving a warning.

        My version is geared to stop that from happening.

        • Chirayu says:

          By the way when I mean individual cells I mean using CTRL button & selecting single cells either in same column/row or different column/row. Macro won't stop that.

  9. SamCal says:

    Very useful macro - something I've tried to implement but with a lot more work.

    One suggestion to improve clarity. I had a lot of trouble understanding the line "2. Check if more than one row is selected. If so, exit as we don’t want to filter based OR conditions, we just want to filter based on AND conditions." Especially since the animation shows cells in several rows being selected. I suggest changing to read as follows:
    "2. For each column with a selected cell, check if more than one row has cells selected. If so, exit as we don’t want to filter based OR conditions, we just want to filter based on AND conditions.

  10. cali34 says:

    this is so useful, thank you

  11. srinivasan says:

    benefitted a lot

  12. Luis Marin says:

    Greetings!

    This VBA code is great, as several users had alredy replied, it would be great if this can also filter by not just one cell in each column, any chance this code can be updated to do this??

  13. AhliPakar says:

    Great macro. While we reset the filter, we automatically view the top of the rows. How can we stuck at the cursor when we reset the filter? Thank you.

  14. AhliPakar says:

    Also please resolve this problem: why the "file filter-selection.xlsm" always automatically open when I run the macro (from the QAT or menu bar in the other file?

  15. DWB says:

    I have a table that has two date columns. I am trying to select date (one per column) for each. When I do this, the table will not filter properly. I can select a single date in either column and it works. I can select values in two columns that are not dates and the filter appears to work fine. Any idea on why this might be happening.

    In Date = 1/1/2017
    Out Date = 1/1/2017

    I want to show all lines that have either the In Date or Out Date equal to the values selected. Just curious why this would be killing the filter function.

  16. Dwb says:

    I am using the filter code in this exampke. My table has two date colums. Filtering works great except when i select a single date in each column. When i sect a date from each column, all lines are filtered out. I was curious as why this woukd happen. I will repost in another thread as well.

    • Chandoo says:

      @Dwb... I tested this with 2 date columns and few other stuff and it seems to work ok. Can you explain more? If possible, upload the file you are using to dropbox and link it here, so I can investigate.

  17. Yugesh says:

    Hi,
    Filter works great. Can someone help me with resetting filter code please. it should be looking at the table first, and reset filters if any.

  18. millawitch says:

    This is really good! Shame you can only select 1 row in each column, any way to fix that? I work mainly with Ctrl+T tables (as Mr. Excel calls them) and don't know VBA to edit it myself. Thanks!

Leave a Reply