Celebrate 'The VLOOKUP Book' birthday with us. Get 50% discount on the e-book today & tomorrow (30 & 31 October only).

Click here for details

Robust Dynamic (Cascading) Dropdowns Without VBA

Posted on February 25th, 2014 in Learn Excel , Posts by Jeff - 24 comments

Recently I posted about how you could construct dynamic (cascading) dropdowns that could easily handle multiple levels, like this:
Chandoo_CascadingDropdowns_Earliglow

…and we saw that users could subsequently change upstream dropdowns in a way that would make downstream choices invalid, like this:
Chandoo_CascadingDropdowns_Embarrassing
In my previous post I used some VBA to clear out any ‘downstream’ choices if anything ‘upstream’ changed:
Chandoo_CascadingDropdowns_Downstream Reset

 

A much simpler alternative

My sample file drew on Roger Govier’s excellent approach on the Contextures website, which used two dynamic named ranges to feed the data validation lists, one called MainList and one called SubList. Roberto commented that you could achieve pretty much the same thing with no VBA and with just one validation formula. His approach is pure genius!

Here’s a sample file that utilizes Roberto’s approach:

Click here to download the file

This approach uses a validation formula with a couple of relative references in it. Relative references look for cells that are some predetermined distance left/right and up/down from the active cell. Here’s his formula, which was entered into the Name Manager while cell B8 was selected:
=IF(ISBLANK(Sheet1!C8),IF(DataEntry[#Headers] Sheet1!B:B = DataEntry[[#Headers],[Main Category]],OFFSET(ValidationLists[[#All],[Main Categories]],1,,COUNTA(ValidationLists[Main Categories])),OFFSET(ValidationLists,0,MATCH(Sheet1!A8, ValidationLists[#Headers],0)-1,COUNTA(OFFSET(ValidationLists,,MATCH(Sheet1!A8, ValidationLists[#Headers],0)-1,,1)),1)))

This formulas assumes:

  • You use Excel Tables for both the Validation List and the data entry area, and so uses the associated Structured References that Table functionality allows.
  • Your validation table is called ValidationLists
  • Your data entry table where the dropdowns are is called table is called DataEntry.
  • The column containing your initial dropdowns is called ‘Main Category’
  • The validation list in your validation table that contains your initial categories is called ‘Main Categories’

You will have to amend this formula accordingly if your tables or initial columns have different names.

The relative reference in this formula checks both the cell to the immediate left AND the cell to the immediate right of your current selection. Entering relative references into the Name Manager can be tricky…you first need to select the cell where the formula was originally created - in this case B8 – before you fire up the Name Manager dialog box. (Note that it doesn’t actually matter whether your own file has anything in C8 or not, or whether in fact your dropdowns are somewhere else entirely…rather it’s just that the above formula happens to refer to A8 and C8, and because we want our formula to always reference the cell on the immediate left and immediate right, then we’ve got to select the cell B8 which is in the middle.

Excel Tables – known as ListObjects to VBA developers – were introduced in Excel 2007, and are a very powerful and simple way to store things like lists, chart data, and PivotTable data…especially if you might need to add more data to your spreadsheet at a later date, and want to avoid having to repoint all your formulas to include the additional data. If you’re not familiar with Excel Tables – or you don’t know what that Table1[#Headers] guff above means – then I strongly suggest you check out Chandoo’s Introduction to Structural References or give GOOGLE a spin.

How does this awesome beast work?

Let’s step through it, bit by bit. Note that I’ve put some extra spaces in after each opening formula bracket, purely so this formula will wrap nicely on your monitor. Excel just ignores these extra spaces, so don’t bother taking them out.

=IF(ISBLANK(Sheet1!C8),IF(DataEntry[#Headers] Sheet1!B:B = DataEntry[[#Headers],[Main Category]],OFFSET(ValidationLists[[#All],[Main Categories]],1,,COUNTA(ValidationLists[Main Categories])),OFFSET(ValidationLists,0,MATCH(Sheet1!A8, ValidationLists[#Headers],0)-1,COUNTA(OFFSET(ValidationLists,,MATCH(Sheet1!A8, ValidationLists[#Headers],0)-1,,1)),1)))

That first bit in bold above checks the cell on the immediate right. If that cell on the right is not blank, then that means that the user has already made ‘downstream’ selections. We don’t want the user to change this ‘upstream’ dropdown without clearing those out. Thanks to the IF statement, if that’s the case then none of the rest of the formula gets executed, and the formula just returns FALSE. Data validation can’t handle this FALSE, so users can click on the dropdown button all they like, but nothing will come up. Consequently, the user simply can’t change this ‘upstream’ selection until they’ve first cleared out any selections they previously made in the cells to the right. Pure genius.

Here’s what that looks like:
Chandoo_Robust Dropdowns without VBA_No dropdown
Chandoo_Robust Dropdowns without VBA_Retrospective change
Sweet! Okay, let’s take a look at the rest of the formula:

=IF(ISBLANK(Sheet1!C8),IF(DataEntry[#Headers] Sheet1!B:B = DataEntry[[#Headers],[Main Category]],OFFSET(ValidationLists[[#All],[Main Categories]],1,,COUNTA(ValidationLists[Main Categories])),OFFSET(ValidationLists,0,MATCH(Sheet1!A8, ValidationLists[#Headers],0)-1,COUNTA(OFFSET(ValidationLists,,MATCH(Sheet1!A8, ValidationLists[#Headers],0)-1,,1)),1)))

That bit in bold above checks whether the dropdown is the Main Category column. It does this using the INTERSECT operator, which is a space between two references (in this case of DataEntry[#Headers] B:B the INTERSECT operator is the space between DataEntry[#Headers] and the column reference B:B. Such a space tells Excel to go to the overlap or intersection of those two references, which in this case is the junction between the header row and the column that our dropdown is in.

  • If the current dropdown is in the Main Category column, then this bold bit:
    =IF(ISBLANK(Sheet1!C8),IF(DataEntry[#Headers] Sheet1!B:B = DataEntry[[#Headers],[Main Category]],OFFSET(ValidationLists[[#All],[Main Categories]],1,,COUNTA(ValidationLists[Main Categories])),OFFSET(ValidationLists,0,MATCH(Sheet1!A8, ValidationLists[#Headers],0)-1,COUNTA(OFFSET(ValidationLists,,MATCH(Sheet1!A8, ValidationLists[#Headers],0)-1,,1)),1)))
    …serves up just the list containing our initial categories (i.e. ‘Fruit’, ‘Vegetables’, or ‘Other Stuff’ in this example).
  • If the current dropdown is not in the Main Category column, then this bold bit:
    =IF(ISBLANK(Sheet1!C8),IF(DataEntry[#Headers] Sheet1!B:B = DataEntry[[#Headers],[Main Category]],OFFSET(ValidationLists[[#All],[Main Categories]],1,,COUNTA(ValidationLists[Main Categories])),OFFSET(ValidationLists,0,MATCH(Sheet1!A8, ValidationLists[#Headers],0)-1,COUNTA(OFFSET(ValidationLists,,MATCH(Sheet1!A8, ValidationLists[#Headers],0)-1,,1)),1)))
    …serves up the particular list relevant given the previous choice made in the dropdown to the left.

Wicked, eh!

Normally I don’t advocate the use of volatile functions such as OFFSET if there is a non-volatile alternate (and you’ll hear more about volatility from me in a forthcoming post). But as Roberto points out in his original comment, in this case it doesn’t matter…choices made via dropdowns are not considered volatile by Excel, even if the formulas used to populate that dropdown are volatile.

Like Roger’s approach, Roberto’s approach can handle any number of cascading levels, provided all the category names are unique. All you need to do is simply add the new subcategories to the right hand side of the validations table.

Thanks Roberto…I learned a lot from those comments. Readers, be sure to visit the Frankens Team and check out the crazy things Roberto, Kris & Gábor get up to with Excel.

Download the sample file

Here’s a sample file that utilizes Roberto’s approach:

Click here to download the file

Updates

You may also want to check out my good pal Doug Glancy’s approach to this. His version of dependent dropdowns uses Conditional Formatting to alert the user, and ultimately, the analyst, that something is amiss. Be sure to say hi to him in the comments while you’re there, and to subscribe to his blog. Anyone who makes up sample files about fictional International Pie Lovers Associations deserves our eyeballs!

About the Author.

Jeff Weir – a local of Galactic North up there in Windy Wellington, New Zealand – is more volatile than INDIRECT and more random than RAND. In fact, his state of mind can be pretty much summed up by this:

=NOT(EVEN(PROPER(OR(RIGHT(TODAY())))))

That’s right, pure #VALUE!

Find out more at http:www.heavydutydecisions.co.nz

Your email address is safe with us. Our policies

Written by Jeff Weir
Tags: , , , , ,
Home: Chandoo.org Main Page
? Doubt: Ask an Excel Question

24 Responses to “Robust Dynamic (Cascading) Dropdowns Without VBA”

  1. Gary says:

    downloaded workbook doesn’t work for me. it’s always missing the first selection.
    so, If I choose fruit, apples is not in the dropdown. if I choose vegetables, beets is not in the dropdown

  2. @Gary, you are right, I try to anticipate the reply of Jeff.
    Here’s the right formula, enter into the Name Manager while cell B8 was selected:

    =IF(ISBLANK(C8),IF(DataEntry[#Headers] B:B = DataEntry[[#Headers],[Main Category]],OFFSET(ValidationLists[[#All],[Main Categories]],1,,COUNTA(ValidationLists[Meat])),OFFSET(ValidationLists,,MATCH(A8, ValidationLists[#Headers],0)-1,COUNTA(OFFSET(ValidationLists,,MATCH(A8, ValidationLists[#Headers],0)-1,,1))-1,1)))

  3. UFFF … i’m sorry … forget my previous comment :-(
    Here’s the right formula, enter into the Name Manager while cell B8 was selected:
    =IF(ISBLANK(C8),IF(DataEntry[#Headers] B:B = DataEntry[[#Headers],[Main Category]],OFFSET(ValidationLists[[#All],[Main Categories]],1,,COUNTA(ValidationLists[Meat])),OFFSET(ValidationLists,,MATCH(A8, ValidationLists[#Headers],0)-1,COUNTA(OFFSET(ValidationLists,,MATCH(A8, ValidationLists[#Headers],0)-1,,1)),1)))

    the errors were due to the fact that ValidationLists does not include the header (as I had initially interpreted)

  4. Elias says:

    Great formula as an always Roberto. However, I think it still need some VBA to clean the subcategory selection if the user delete the previous category.

    Regards

    • Ciao Elias! the formula was born from a discussion with Jeff, everyone added something then he wrote this post and he explained the formula … he gave all the credit to me … but the merit is more his … I’ve only made a mess with these Excel Tables (I’m sorry) :-)
      anyway thanks

  5. Jeff Weir says:

    Gary: Thanks for the heads up. Have fixed post and sample file.

    Elias: No VBA necessary as users CANNOT delete upstream categories without FIRST manually cleaning out downstream categories. Give the sample file a spin.

    • Elias says:

      Hi Jeff,

      Open the file->go to B8 and press the delete key. Do I missing something?
      Also, the new file’s link is giving and error.

      Regards

      • Jeff Weir says:

        No, it’s me that’s missing something…I misunderstood what you were saying. So yes, you’d need VBA to do that, along the lines per my previous post. But this is still a great non-VBA solution, apart from that.

        Link fixed.

        Cheer Elias.

  6. Kuldeep J says:

    Great….i was looking something like this in past but end up with only VBA solutions which i really did not liked them because if anyone unknowingly chnage the upper LOV, All the sub selection get vanished and if the person do not know what those LOV, He/She can only hit his head.

  7. LeonK says:

    What a fantastic solution. I’m currently replacing VBA routines with non-VBA ones and this formula has become a major part of my re-modelling. Thank you so much for debating, creating and sharing this formula.

    LeonK

  8. Jeff Weir says:

    Kuldeep and LeonK: Thanks for you kind comments. Without comments like yours, I tend to think that noone finds this stuff useful.

  9. Oxidised says:

    Great solution! shame I needed it 6 months ago, but I’m sure i’ll find another use for it soon!

    Certainly do find it useful, keep the awesome posts coming!

  10. Doug Glancy says:

    Nice work, Jeff and Roberto. The VBA-free cascading data validation is a worthy goal.

    At my previous job I regularly sent out Excel surveys to dozens of recipients, and of course couldn’t hazard the maintenance nightmare of VBA. I came up with a version of dependent dropdowns that wasn’t as self-correcting as this, but uses Conditional Formatting to alert the user, and ultimately, the analyst, that something is amiss. If anybody’s interested it’s at http://yoursumbuddy.com/user-friendly-survey-without-vba/.

  11. […] Weir explains Robert Mensa’s technique for creating robust dynamic drop downs, without VBA. Just remember, the best we can do is build things that are idiot resistant, not idiot […]

  12. Pablo says:

    Thanks Jeff and Roberto, this is exactly what I was looking for. The timing it’s like a miracle! :)

    I noticed that the validation is not consistent, in some cells I can type anything I want, but in others the validation rule works. I just copied the cell from the one that was working to the rest and now all are fine. I hope I didn’t mess up anything by doing that.
    Thanks again,
    Pablo

  13. […] Howdy folk. Jeff Weir here. You might remember me from shows such as Handle volatile functions like they are dynamite, Did Jeff just Chart, and Robust Dynamic (Cascading) Dropdowns Without VBA. […]

  14. Leonard says:

    Guys, does this work with subcategories beyond 3, per the example? I have a flow chart decision tree with 6 subcategories. My customers are basic users who don’t want to read my guidelines or decision tree. I thought dynamic dependent drop downs the best option for this situation. However, I can’t seem to find anything on the web that shows beyond 3 categories. If anyone can help show how it could work with the learning/example that Jeff published above, I would be grateful…or if there are better options then drop downs…

    • Jeff Weir says:

      Leonard – yes it can. As per the original article: Like Roger’s approach, Roberto’s approach can handle any number of cascading levels, provided all the category names are unique. All you need to do is simply add the new subcategories to the right hand side of the validations table.

      • Leonard says:

        Thanks Jeff!

        Even though I am basic beginner, I managed to emulate and then modify. Maybe it say somewhere, but I discovered that if your last column in the validation table isn’t filled in as far as the 1st column, then you won’t get the full first drop down list. I basically created an extra end column that I filled in with bogus numbers so it would work.

        Thanks again!

Leave a Reply