Sum of Values Between 2 Dates [Excel Formulas]

Posted on September 27th, 2011 in Excel Howtos , Learn Excel - 26 comments

Lets just say, you run a nice little orange shop called, “Joe’s Awesome Oranges“. And being an Excel buff, you record the daily sales in to a workbook, in this format.

Sum of Values between 2 Dates in Excel

After recording the sales for a couple of months, you got a refreshing idea, why not analyze the sales between any given 2 dates? for analysis sake.

So you entered 2 dates, Starting Date in cell F5 and Ending Date in cell F6

How would you sum up the sales between the dates in F5 & F6?

This is where use the powerful SUMIFS formula.

Assuming the dates are in column B & sales are in column C,

we write =SUMIFS($C$5:$C$95,$B$5:$B$95,">="&$F$5,$B$5:$B$95,"<="&$F$6)
to calculate the sum of sales between the dates in F5 & F6.

How does this formula work?

  • $C$5:$C$95 portion: This is the range of cells where our Sales values are recorded. We want these to be summed up based on the conditions as below.
  • Condition 1: $B$5:$B$95 >= $F$5: This condition tells SUMIFS to check Column B for any dates on or after F5
  • Condition 2: $B$5:$B$95 <= $F$6: This condition tells SUMIFS to check Column B for any dates on or before F6
  • When combined, the SUMIFS formula checks for both conditions and adds sales only for dates between Starting (F5) and Ending (F6) dates.
  • Learn more about SUMIFS syntax & how to use it.

What formula you should use in Excel 2003?

As you may know, SUMIFS formula does not work in earlier versions of Excel. But you don’t have to shut your orange shop because of that. We can use the all powerful SUMPRODUCT formula for this.

For example, =SUMPRODUCT(($B$5:$B$95>=$F$5)*($B$5:$B$95<=$F$6),$C$5:$C$95) would work the same.

Learn more about SUMPRODUCT formula & why it is awesome.

We can even use SUM & OFFSET formulas if …,

We can also use SUM & OFFSET combination to perform this calculation, provided dates are in smallest first order and all dates are entered. For the example, see download file.

Download Example Workbook:

Click here to download example workbook & play with it.

How would you sum up values between 2 dates?

In reporting situations, showing summary of values between 2 dates is a common requirement. So I use either formulas like above or Pivot Tables to do this.

What about you? How would you sum up values between 2 dates? Please share your ideas & tips using comments.

Learn More Date Related Formulas:

Want to Learn More Formulas? Join Our Crash Course

If you want to learn SUMIFS, SUMPRODUCT, OFFSET and 40 other day to day formulas, then consider my Excel Formula Crash Course. It has 31 lessons split in to 6 modules and makes you awesome in Excel formulas.

Click here to learn more about this.

Excel Formula Crash Course from Chandoo.org

Written by Chandoo
Tags: , , , , , , , , , ,
Home: Chandoo.org Main Page
? Doubt: Ask an Excel Question

26 Responses to “Sum of Values Between 2 Dates [Excel Formulas]”

  1. dexter says:

    I would apply a filter and use function subtotal, with option 9. This way you can see multiple views based on the filter.

  2. Michael Azer says:

    hey Chandoo, the solutions you proposed are very efficient, but if I wanted to be fancy I would do it this way .. the references are as your example workbook.
    =SUM(INDIRECT("C"&(MATCH(F5,B5:B95)+4)):INDIRECT("C"&(MATCH(F6,B5:B95)+4)))

  3. Luke M says:

    I like things simple:
    =SUMIF(B5:B95,">="&F5,C5:C95)-SUMIF(B5:B95,">"&F6,C5:C95)

  4. Matt S says:

    use something like: =SUM(OFFSET(B1,0,0,DATEDIF(A1,D1,"d")))
    and have D1 be the date that I want to sum to.

  5. Tom J says:

    In Excel 2003 (and earlier) I'd use an array formula to calculate either with nested if statements (as shown here) or with AND.

    {=SUM(IF(B5:B95>F5,IF(B5:B95<F6,C5:C95,0),0))}

    Note that I truly made this for BETWEEN the dates, not including the dates

  6. Andrew says:

    I turned the data set into a table named Dailies.
    I named the two limits StartDate and EndDate.

    And used an array formula:

    {=SUM((Dailies[Date]>=StartDate)*(Dailies[Date]<=EndDate)*Dailies[Sales])}

  7. Frank Linssen says:

    If I would still be using the old Excel I would do it as follows:

    SUMIF($B$5:$B$95,"<="&H6,$C$5:$C$95)-SUMIF($B$5:$B$95,"<"&H5,$C$5:$C$95)

    Works as simple as it is.

    Regards

  8. ikkeman says:

    =sum(index(c:c,match(startdate,c:c,1)+1):index(c:c,match(enddate,c:c,1))

  9. ikkeman says:

    =sum(index(c:c,match(startdate,b:b,1)+1):index(c:c,match(enddate,b:b,1))

  10. ram says:

    Great examples and thanks to Chandoo. You have simplified my work.

  11. [...] I'm not sure I understand your question fully, but have a look at this: Sum of Values Between 2 Dates [Excel Formulas] | Chandoo.org - Learn Microsoft Excel Online [...]

  12. Amanda says:

    Thank you! Thank you! Thank you!

  13. abdalurhman says:

    =SUMIF(A2:A11;">="&B13;B2:B11)-SUMIF(A2:A11;"<"&A11;B2:B11)

  14. Eliza says:

    awesome... thank yoo Chandoo!

  15. dockhem says:

    which is most efficient and fast, if all are efficient ?

  16. jmassiah says:

    Thank you for this formula, I've just spent ages trying to find something to work on my data, I knew it would be possible! Don't care if others think there are easier/other ways to do it, you explained it so I understood it and could apply it to what I was doing so I'm happy!

  17. Nagaraju says:

    The above said example is awesome for calculating values between dates,

    can you pls let know how to calculate sale values if we have 10 sales boys for
    ex: 1,rama
    2,krishna
    3,ashwin
    4,naga
    5,suresh

    how much rama sale value between 1/jan/2015 to 10/jun/15
    how much krishna sale value between 10/jan/2015 to 15/july/2015
    i think you understood can you pls let me know the formula for how to calculate the sale between diffrent sale man sale value from master data file

    Thanks,
    Nagaraju

  18. Viv says:

    Hi

    I have a list of people's names in column A, I have a list of dates in column B which records the dates they have been off sick, in column C I have either 1 if it is a full sick day or 0.5 if it is a half day.

    What I would like to do is to add up the number of dates a specific person has been off within two dates.

    For example, I want to look at my list of names and to find Joe Bloggs (column A), then add up all his sick days (column C). The start date will be in cell E1 and the end date will be in F1.

    If this possible using SUMIFS?

    List of names are in range A2:A100

    List of dates in B2:B100

    List of sick days (either 0.5 or 1 in C2:C100

    The start date is in cell E2

    The end date is in cell F2

    Your help would be greatly appreciated.

    • Loknathan says:

      Yes, with the help of SUMIFS you can have the solution.
      Note: you need have an extra col. D2 where you will input Name of the person.
      =SUMIFS(C2:C100,A2:A100,D2,C2:C100,">="&E2,C2:C100,"<"&F2)

      Col. A Col. B Col. C Col.D Col. E Col. F
      Name Date Sales
      ABC 28-Jun-11 1 MNO 28-Jun-11 25-Sep-11
      XYZ 29-Jun-11 0.5
      MNO 30-Jun-11 1
      PQR 1-Jul-11 1

      • Loknathan says:

        Typo ERROR / Correction in formula:
        Yes, with the help of SUMIFS you can have the solution.
        Note: you need have an extra col. D2 where you will input Name of the person.
        =SUMIFS(C2:C100,A2:A100,D2,B2:B100,">="&E2,B2:B100,"<"&F2)

  19. Viv says:

    Hi

    I have a list of people's names in column A, I have a list of dates in column B which records the dates they have been off sick, in column C I have either 1 if it is a full sick day or 0.5 if it is a half day.

    What I would like to do is to add up the number of dates a specific person has been off within two dates.

    For example, I want to look at my list of names and to find Joe Bloggs (column A), then add up all his sick days (column C). The start date will be in cell E1 and the end date will be in F1.

    If this possible using SUMIFS?

    List of names are in range A2:A100

    List of dates in B2:B100

    List of sick days (either 0.5 or 1 in C2:C100

    The start date is in cell E2

    The end date is in cell F2

    Your help would be greatly appreciated.

    Viv

  20. AC says:

    Thanks for this - it solved the problem that I was having. However can someone please explain to me why the "" needs to be around >= and <= as well as why we need to add & in order for the formula to work? Thanks in advance!

  21. Ufoo says:

    This formula works perfectly as well. Any ideas?: =SUM(INDEX(C5:C95,MATCH(H5,B5:B95,1)):INDEX(C5:C95,MATCH(H6,B5:B95,1)))

  22. Ufoo says:

    ikkeman had posted the same thing.

Leave a Reply