Often we deal with data where numbers are buried inside text and we need to extract them. Today morning I had such task. As you know, we recently ran a survey asking how much salary you make. We had 1800 responses to it so far. I took the data to Excel to analyze it. And surprise! the numbers are a mess. Here is a sample of the data.
Now, how do I extract the salary amounts from this without typing the values?
My first thought is to write a user defined function to extract the number from text. But I usually shy away from VBA. So I wanted to see if there is a formula based approach to extract the number from text.
Using formulas to extract number from text
To extract number from a text, we need to know 2 things:
- Starting position of the number in text
- Length of the number
For example, in text US $ 31330.00 the number starts at 6th letter and has a length of 8.
So, if we can write formulas to get 1 & 2, then we can combine them in MID formula to extract the number from text!
Finding the starting position of number in text
To find the starting position, we need to find the first character which is a number (0 to 9). In other words, if we can find the positions of 0 to 9 inside the given text, then the minimum of all such positions would be starting position.
Sounds complicated?!? Well, in that case look at the formula and then you will understand why this works.
Assuming the text is in A1 and the range lstNumbers contains 0 to 9, below formula finds starting position
{=MIN(IFERROR(FIND(lstNumbers,A1),””))}
You need to array enter it (CTRL+SHIFT+Enter)
How this formula works?
FIND(lstNumbers, A1) portion: This part finds where each of the numbers 0 to 9 occur in the text in A1. If a match is found, the position is returned. Else we get an error. For US $ 31330.00 the values would be,
{10;7;#VALUE!;6;#VALUE!;#VALUE!;#VALUE!;#VALUE!;#VALUE!;#VALUE!}
Meaning, 0 occurs at 10th position, 1 occurs at 7th position, 3 occurs at 6th position and everything else (2,4,5,6,7,8,9) do not occur in the number.
IFERROR(…,””) portion: Then, we replace errors with empty spaces so that MIN could work its magic.
At this stage, the result would be, {10;7;””;6;””;””;””;””;””;””}
Related: IFERROR Formula – syntax & examples
{=MIN(…)} portion: This would find the minimum of {10;7;””;6;””;””;””;””;””;””} which is 6. The starting position of number inside text.
Because we are finding multiple items, we need to array enter the formula to get correct result.
Finding the length of number
Once we find starting point, next we need to know the length of the number. There are many ways to do this. Depending on the variety in your input data, you can choose a technique that works best.
Approach 1 – counting number of digits in text
My first approach is to count number of digits in the text and use it as length. For this, we can break the text in to individual characters and then see if each of them is a number or not.
Assuming the text is in A1, the number of digits in it are,
=SUMPRODUCT(- -ISNUMBER(MID(A1,ROW($A$1:$A$200),1)+0))
MID(A1,ROW($A$1:$A$200),1) + 0 portion: This breaks the text in A1 in to individual characters (assumes the max length is 200) and then adds 0 to them.
At this stage, you have 200 values some of them numbers, others errors.
ISNUMBER(…) portion: This checks all the 200 values for numbers. After this, we will have 200 true or false values.
— ISNUMBER (…) portion: This converts the true, false values to 0s and 1s. (by double negating Excel will convert boolean values to number equivalents).
SUMPRODUCT(…) portion: This finally sums up all 1s thus giving us the number of digits in the text.
Does it work?
While this approach works well for some numbers, it fails in other cases. For example, a text like US $ 31330.00 has number portion with 8 characters (31330.00) where as our formula would say the length is 7 (because decimal point . is not a number and hence ISNUMBER() would give false for that).
So I had to move on to next approach.
Approach 2 – counting number of digits, commas & decimal points in text
The next approach is to count not only numbers, but also commas & decimal points in the text. For this, first I placed all the digits (0 to 9) and comma & decimal point in a range called as lstDigits.
Below formula counts how many of lstDigits are in text in A1.
=SUMPRODUCT(COUNTIF(lstDigits,MID(A1,ROW($A$1:$A$200),1)))
COUNTIF(lstDigits, MID(…)) portion: This checks how many times each of the 200 characters appear in lstDigits.
This would be an array of counts. For example {0;0;0;0;0;1;1;1;1;1;1;1;1;…} for US $ 31330.00, indicating that first 5 are not in lstDigits and then we have 8 in lstDigits.
SUMPRODUCT(…) portion: just sums all the numbers, hence we get length as 8.
Related: SUMPRODUCT Formula – examples & explanation
Extracting numbers from text
Once we have starting position of number & its length, we can combine them in a MID formula to extract the number. Here is the result for our sample data set.
As you can see, this method works well, but fails in some cases like,
- European number formats (, for decimal point and . for thousands)
- Text with multiple numbers
Fortunately, in my data set, we had only a few incidents like these. So I have decided to manually adjust them than work out even more complicated formula.
Using Macros to extract numbers from text
As you can guess, we can use a simple macro (or UDF) to extract numbers from a given text. We will learn how to do this next week.
Download Example Workbook
Click here to download example workbook with all these formulas. Examine the formulas to understand how you can extract numbers from text in Excel.
How do you Extract numbers from Text?
Often I deal with data like this. I use a mix of techniques. Apart from the one mentioned above I also use,
- getNumber() UDF to extract numbers from text (more on this next week)
- Use SUBSTITUTE to clear formatting (replace dots with empty spaces and commas with dots to convert from European format to standard format)
- Use VALUE to extract the number (works when number is shown as text)
- Use +0 to force convert numbers from text (works when number is shown as text)
What about you? How do you extract numbers from text? What are your favorite techniques? Please share using comments.
Tips on cleaning data using Excel
If you use Excel to clean data, go thru these articles to learn some powerful techniques.
35 Responses to “Quick and easy Gantt chart using Excel [templates]”
"Please share your experiences and ideas using comments"
For those willing to go VBA, XL can do far more w/Gantt Charts. Compare to PapaGantt. https://sites.google.com/site/beyondexcel/project-updates/papagantt-thebigdaddyofxlganttcharts
While making PapaGantt was neither quick nor easy, using PapaGantt is both, not just for displaying Gantts, but for scheduling tasks as well.
is it possible to get a xls(m) file ?
instead of a zip-file with .xml-files ?
i cannot open it with excel :/
Regards
Stef@n
@Stef@n
Try saving the file and then open from Excel as opposed to opening directly from the post
Also try this link: http://img.chandoo.org/pm/quick-gantt-chart-template.xlsx
Thanks very much for this workbook idea.
To slightly up-scale functionality I added:
1. conditional format for when the cell value =2 to be red which could be used for critical path or other activity highlighting needs (milestones perhaps)
2. conditional format for when the cell value =c to be green which could be used for showing activity progress
3. conditional format for the same range where formula =DATE(YEAR(D$5),MONTH(D$5),DAY(D$5))=TODAY() and set custom to ;;; and cell fill colour to a light blue. This will highlight today down the whole table to allow quick assessment of activity progress to plan. Anything not green upto where the date indicator is shows activity is behind the plan. Opposite for tasks ahead of the plan.
(There is probably a better way to get the same result but this works for now. If there is please post for us to share.)
Hope this made enough sense.
Also, thanks Craig for the link. I'll have a better look soon.
Regards,
Darren
Hey Chandoo,
I actually made one of these for a friend of mine but added an extra level of automation.
Rather than putting in 1 on all the dates the activity occurs, I added a column for start and end date of each project. Then I used formula along the lines of :
=IF(AND(DateAtTop >= Start Date, DateAtTop <= End Date),1,"")
Then used the same conditional formatting where 1 was coloured.
I thought this was a nice touch, especially if a project lasts for many days.
Let me know what you think 😉
Lucas
P.S. First time I've posted here, love your work btw!
Hi Lucas... welcome to the comments and thanks for your first of many comments.
I like the idea. In fact, it was one of the first Excel tricks I ever learned (to use conditional formatting to automate things like this). See this (written almost 6 years ago)
http://chandoo.org/wp/2008/03/13/want-to-be-an-excel-conditional-formatting-rock-star-read-this/
and scroll-down to the tip on gantt charts. 🙂
I liked this approach and tried adding it into the Conditional format via Formula = statement. It workd fine with just the AND statement but then I realised you need the "1"'s to calcluate the duration.
I then put the whole IF statemnt in but it hasnt worked. Any thoughts?
Ta
Hi Lucas and Darren,
I tried the conditional formatting but I really don't succeed in getting the solution. Do you have a template of this?
Thanks in advance
Br
[…] http://chandoo.org/wp/2014/02/18/quick-gantt-chart-excel-template/?utm_source=feedburner&utm_med… […]
[…] via Quick and easy Gantt chart using Excel [templates]. […]
Excellent, thanks for this tip and expample.
I had a monthly reporting template very similar to this, but was done in excel which needed more manual inputs.
I used your exmaple and updated my monthly group reporting plan.
I further devided the day into 4 quarters to make it easy for us to followup on different tasks.
Now, I just have to update the start date, and everything gets udpated by itself in fraction of a second.
Thanks once again. love your daily udpates.
Wow.. glad to hear that.
Hi Prahlad,
Can you share ur template even i am looking for similar kind of template .where i want day duration ,split in hrs and each task effort represented in hr spent by each resource .
Thanks
savi
Hi Chandoo,
Can you guide on preparing an indian version of the captioned sheet. We have saturdays working :-(, and only one day weekly off on sunday.
Regards-Prajay
Hi Chandoo,very useful post.i need gantt chart for inventory module.
[…] Quick and easy Gantt chart using Excel […]
Hi.
Really usefull post. I would like to know if i can also include weekends.
Thank you
Hi Chandoo, thank you for the great job, I was wondering if you can customize this sheet for Inventory planning purposes?!
thank you indeed
This was so helpful. ive been through about 10 different tutorial type things and this has to be the best so far, helped me out a great deal. and now my boss is happy i can make gantt charts!
thanks
This's a great post, thanks for sharing
Hi Chandoo,
Thanks for the excel tutorial. I wanted to make a simple modification, however it will cause issues with the duration part. I created another rule/cell marked 2. For my project I want to show a projected timeline and then an actual timeline. The issue is that the duration is being logged for when I enter 2, which I want to be projected and not actual. Will you please assist in letting me know how I can create a duration for both project and actual on the same line?
Thank you,
Steven
Showing vertical line between every week is very useful for me, I used to do it manually. Thanks so much!!
But how about, my gantt chart included Saturday & Sunday, and I want to show the vertical line after Sunday, could any expert teach me how to fix it. Thanks again.
This was so helpful - thank you! I had a bit of trouble with the end of the week conditional formatting over-writing the filled cells but switching the order of the rules sorted it out. Needed to put together a gantt chart quickly for an important bid at short notice and this was just the job - thanks for taking the time to post it. Much appreciated.
This is the first time I'm reading a tutorial that actually makes sense 🙂 This is absolutely great, with only one minor issue I can't seem to figure out on my own. How do I include weekends in (or instead of) the Workday formula? Thank you!
[…] This template I made myself but I inspired from Chandoo.org. […]
Hi,
Sometimes I must work at weekends - it is possible to modify the dates so that you can include Sat + Sun as well?
Thanks,
H
Nice gantt chart template chandoo, simple but useful
Thank you so much for this excellent guide! I have adapted this to show scheduled activities at multiple project sites weekly over the course of the year, including active and proposed work. With just a tiny bit of tweaking to your tutorial, I was able to create a chart that suited my needs perfectly!
Thank you very much for idea sharing .very innovative workday formula is showing 5 days but i want 6 days , is there any other option plz reply..
i got it friends..
=WORKDAY.INTL(F4,1,11)
hhhhhh
@Somnath
I also like the structure using =WORKDAY.INTL(F4,1,"0000001")
where each day is a 0 or 1
Hi thanks a lot for the tuto!! It helped me a lot!!
But can you tell me how can I add a vertical line representing today on it?
@Cynthia
Open the template
Select D7:DS26
Goto Conditional formatting
New Rule
Use a Formula
=D$5=today()
then set the format as a Red Right Hand Border only
Apply
Do not select stop here for the rule
Hi Chandoo,
I purchased your Project Management templates a month ago and have not had the chance to thank you for the great templates. Thank you!!!!! It has saved me a lot of time creating and re creating templates. Unfortunately, I had to do a lot of customization but it's not that bad. I am now in the process of customizing my GANTT which my boss thinks is too granular. He doesn't want to see a weekly grant. Only the months should be showing. I have researched and researched but to no avail. Do you have any examples I can look at?
Hi Chandoo,
thanks so much for all your tips on Gantt Table.
I'm actually building one at the moment and want to use the conditional formatting. However, I always get into trouble with that when I have to add new lines. I don't know the final size of my table yet and I eventually also want other people to be able to work with it.
Conditional formatting tends to "split up" into various "applies to" ranges when you insert a new row or copy and past values from somewhere.
I'm sure you've come across this issue already... So far I couldn't find a feasible solution to this. I was wondering if you had an idea / suggestion for me?
Thanks so much!!!
Nadine