Automatically Format Numbers in Thousands, Millions, Billions in Excel [2 Techniques]

Ever wanted to automatically format values in thousands, millions or billions in Excel? In this article, let me show you two powerful techniques to do just that.

Technique 1: Using Custom Format Codes

We can use Custom Number Format codes in Excel to quickly turn the number to thousands, millions or billions. To do this:

1. Select your numbers and go to Format Cells (Ctrl 1)
2. From the number tab, select “Custom” for category and type the code below:

[<1000]##,##0;[<1000000]#,###.0,"K";#,###.0,,"M"

3. Press OK to see the magic.

How does it work?

[<1000]##,##0;[<1000000]#,###.0,"K";#,###.0,,"M"

The above custom format code has 2 rules and a default behavior, each separated by semicolon ;

• [<1000]##,##0 – This portion formats any values under 1,000 as usual numbers
• [<1000000]#,###.0,”K” – Any numbers under 1 million will be formatted in thousands (the extra comma at the end rounds the numbers to thousands) and adds letter “K” at the end.
• #,###.0,,”M” – And finally this is the default rule. Any other numbers (obviously more than 1 million) will be formatted in millions (2 extra commas at the end) and the letter “M” added at the end.

Learn more about custom cell format codes in Excel.

Limitations of Custom Format code

While custom cell format is a great option, it has a few limitations.

• Supports only 3 rules: The custom format codes can only accept up to 3 options. So if you want to have units, thousands, millions, billions (i.e. 4 levels), we can’t do that with custom format codes.
• Negative numbers not supported: As a consequence of 3 rule limitation, we can’t do negative numbers with this approach. If you just want the “thousands” or “millions” formatting for both positive and negative numbers, you can use the below alternative rule.

'Format in thousands, works for both positive and negative numbers:

[<-1000]-#,##0.0,"K";[<1000]#,##0;#,##0.0,"K"

Better Technique 2: Using Format Lookup Table

A better option is to use a lookup table to decide the format code based on the size of your numbers and then automatically switching the format with TEXT function.

First set up a lookup table like this in your workbook. (I normally put this in hidden settings tab for my dashboards).

Then, use the below formula to automatically lookup the value and format it in the corresponding format style based on the table.

'Auto-format numbers based on the lookup table

=TEXT(B5,LOOKUP(B5,$J$5:$J$11,$K$5:$K$11))

How does this formula work?

The formula has 2 key components: TEXT() & LOOKUP()

• LOOKUP() Function: This will lookup the exact value or next lower value. For example, when we lookup the value 12,345 the lookup function (LOOKUP(12345,$J$5:$J$11,$K$5:$K$11)) will return the format code – #,##,.0″K”
• TEXT() Function: Once we have the format code, we use TEXT function to convert the value in B5 to that format and return it as a string value. For example, 12345 when formatted in #,##,.0″K” will become 12.3K

How to auto-format Chart Labels?

We can use the same approach to auto-format chart labels as well. For example, above, I have shown a column chart with dynamic chart labels that auto-format based on the value. To get this:

0. Add “data labels” to your chart.
1. Select the labels and go to “format labels” (press CTRL 1)
2. From the label options tab, go to “Number” area
3. Uncheck “Linked to Source” option.
4. Type the format code as shown above in this article.
5. Click on “Add”
6. That is all. Your chart will now have dynamically auto-formatted labels.

Here is a quick demo of the process:

Using “Formula” approach with Chart Labels

If you have values all over the place and need thousands / millions / billions style format for your labels, you can also use “formula” approach, as discussed above. To do this:

1. First calculate the labels with formula (lookup table) approach.
2. Add labels to the chart and go to “format labels”.
3. From the “label options” area, select “value from cells”.
4. Select the formula label range.
5. Uncheck original “values” from the labels.
6. Done. Your chart now has dynamic labels that are fetched thru formula lookup method.

Why auto-format your numbers?

Auto-formatting numbers helps in reducing clutter of your reports and makes them look professional. I always use this approach when creating executive dashboards or KPI reports in Excel.

In Conclusion: Which method to use?

For simpler situations, use the custom cell format rule method.

But if you have data all over the place or need to go beyond more than 3 rules, use the formula approach.

Download Sample File – Auto format numbers

Here is a sample Excel workbook with all the examples above so you can understand this technique.

Video: Auto format numbers in Excel [2 ways]

Watch this video tutorial to learn how to use these two techniques.

More creative ways to use custom cell formatting in Excel

Learn more about Excel’s custom cell formatting feature using the articles below:

• Custom cell formatting – many examples
• Understand and make your custom format codes
• Show decimal point only if the number is below 1
• Hide away cell contents with format code ;;;
• Automatically coloring cells with custom format codes
• Get tick marks in cells with formatting