Do you know that we can easily calculate the critical path for a project using Excel formulas?
For a long time, it has been tricky to calculate the Critical Path using Excel formulas. But thanks to the arrival of new Dynamic Array functionality in Excel, we can now calculate critical path. In this article let me describe the approach with an example.
Put on your hardhats, this one is going to blow your minds.
What is Critical Path Method (CPM)?
Critical Path Method gives us a framework to analyze and optimize a project plan. Let’s say you have a project with 6 activities, as depicted below. Then we can find a critical path that determines the total duration of the project using Critical Path Method.
The critical path is the longest sequence of tasks that must be completed to execute a project. The tasks on the critical path are called critical activities because if they’re delayed, the whole project completion will be delayed.
How do you calculate the Critical Path?
To calculate the critical path, you need below details about the project plan:
- Complete list of all planned activities
- Estimated duration for all activities (t)
- Dependencies for each activity
In many real-world scenarios, accurately listing all three of them is impossible. And that is why CPM technique is often criticized.
Once you have all of them, we need to apply critical path algorithm to calculate below 5 values.
- Earliest Starting time (ES): This is maximum Earliest Finish (EF) of all predecessors of an activity.
- Earliest Finish time (EF): This is ES + duration of the activity (t)
- Latest Finish time (LF): This is the minimum Latest Start time (LS) of all successors of an activity.
- Latest Starting time (LS): This is LF – duration of the activity (t)
- Float or Slack (F): This is the gap between Latest Start (LS) and Earliest Start (ES). For activities on critical path this value would be 0.
Learn more about Critical Path Method:
Critical Path Calculations with an Example
Let’s go back to our 6 activity project. We can assign durations for each activity like this:
We can use below notation when capturing this data in Excel table.
Calculating ES, EF, LS, LF & Float with Formulas
Adjacent to the input data table, add 6 columns for all our calculations. Our table should look like this:
Now, lets understand the formulas for Successors, Early Start (ES), Early Finish (EF), Latest Start (LS) and Latest Finish (LF).
Early Start Formula (ES)
Early Start is the earliest an activity can begin. An activity can only start when all of its predecessors have finished. So this is same as the maximum of Early Finish (EF) for all the predecessors. If an activity has no predecessors, then it can start right away.
As we have the list of predecessors in the cell [@Predecessors], we can loop thru them and find the maximum finish time for them.
Here is the formula I used.
=IF([@Predecessors]="",0, MAX(CHOOSEROWS([EF],TEXTSPLIT([@Predecessors],",")+0)))
For activities without predecessors, we set the value of ES as 0.
For all other activities, we split the [@Predecessors] by comma (using TEXTSPLIT) and convert these text values to numbers (by adding a 0 to them). We then pick the maximum of all these activity’s earliest finish time [EF] using MAX & CHOOSEROWS functions.
Early Finish Formula (EF)
This is easy. We just add duration to early start (ES).
=[@ES]+[@[Estimated Duration]]
🤔Did you notice the circular nature of these formulas?
Even though ES formula depends on EF and EF formula depends on ES (head hurts, innit?), you need not worry. Excel will calculate both of these values fine as long as there are no loops in your project data (ie. Activity 1 depends on 2 and 2 depends on 1)
Successors Formula
Before we calculate the Latest Start (LS) and Latest Finish (LF) times, it is a good idea to calculate the list of successors for each activity.
I used this formula for that:
=TEXTJOIN(",",TRUE,FILTER([ID],IFERROR(BYROW([Predecessors],LAMBDA(a, OR(TEXTSPLIT(a, ",")+0=[@ID]))),FALSE),""))
How it works?
For each activity, the list of successors is defined as all the activities that begin immediately after that activity.
So for example, going back to our image of project plan (see below),
the list of successors for activity 1 is {2,3}
To obtain this list for a given activity x:
- We need to filter all the activities
- where x is one of the predecessors
We can use a cocktail of FILTER(), BYROW(), LAMBDA() and TEXTSPLIT() for this.
Here is the basic approach:
- We filter the [ID] column
- by checking for each row (hence BYROW)
- if the [Predecessor]s has the [@ID]
- To perform the check, we first split the predecessors using TEXTSPLIT
- and then compare if any of them equal to [@ID]
- At the end of this BYROW looping, we end up with either TRUE or FALSE values against each [ID]
- After filter fetches all the successors, we just apply TEXTJOIN to combine them to a list. For ex: 2,3
Latest Finish Formula (LF)
Latest Finish (LF) is defined as the latest an activity can finish without derailing the project.
For the activities without any successors, this is same as EF.
For all other activities, we look for the minimum (earliest) LS value of all it’s successors.
Here is the formula:
=IF([@Successors]="",[@EF],MIN(CHOOSEROWS([LS],TEXTSPLIT([@Successors],",")+0)))
How this formula works?
If an activity has no successors (ie it is last activity in the project diagram) we set LF as EF.
For all other activities, we split the [@Succssors] by comma (using TEXTSPLIT) and convert these text values to numbers (by adding a 0 to them). We then pick the minimum of all these activity’s Latest Start time [LS] using MIN & CHOOSEROWS functions.
Latest Start Formula (LS)
This is Latest Finish (LF) minus Duration (T)
=[@LF]-[@[Estimated Duration]]
Float (or Slack)
Now that we have all the calculations done, we can figure out the float (or slack) for each activity. This is the difference between Latest Start (LS) and Earliest Start (ES) for an activity.
=[@LS]-[@ES]
Findout out which activities are on Critical Path
Any activity with ZERO (0) float is on the critical path. It means, there is no wiggle room for that activity.
We can use Excel’s conditional formatting feature to visually identify all such activities.
- Select the table and add a new conditional formatting rule (formula based)
- Use the rule float_column=0 and set the necessary formatting. (see my rule in the below screenshot).
Here is my final project plan table with critical path activities identified.
Critical Path Analysis with Excel - FREE Template
Please download my FREE Critical Path Analysis Template and use your own data to calculate the critical path automatically.
Critical Path Calculations in Excel - Watch the Video
Still confused about these calculations? I made a video explaining the CPM concept & Excel formulas. Check it out below or on my YouTube Channel.
More on Project Management using Excel
If you are a project manager, you are going to love my site. I have articles & templates on all aspects of Project Management. Check them out below:
- Interactive Gantt Chart Template with Excel
- Quick & easy Gantt Chart in Excel
- Project Timeline Chart with Excel
- Project Management Dashboard with Excel
- Project Portfolio Dashboard with Excel
- Complete Project Management Template Pack (Excel)
41 Responses to “Calculate Elapsed Time in Excel [Quick Tips]”
Hi Chandoo,
To calculate time lapses in excel I usually use the DATEDIF function. Even though is undocumented by MS there is a great explanation of its use in Chip Pearson's site :
http://www.cpearson.com/excel/datedif.aspx
Is pretty easy to use and has great flexibility.
See you and keep Excelling!!!
Another great article, I will be linking to it on my blog.
Oliver:
Yes, I think that DATEDIFF do it better.
Great post! This a fantastic tutorial on calculating elapsed time in Excel that could be helpful even to a novice user. Keep up the useful tips!
Also, the Office community on Facebook could really benefit from you knowledge! Check it out at http://www.facebook.com/office
Cheers,
Andy
MSFT Office Outreach Team
hi, Chandoo !!!
for elapsed time , we can use this unique formula either for hours, minutes or seconds : NOW()-A1)
but using respective special number formats
for hours : [h] ==> 46553
for minutes : [m] ==>2793212
for seconds : [s] ==> 167592763
We can also use mean duration for years (orbital period of the Earth around the Sun : i-e tropical year) which is : 365.25 days
and mean duration for month : 365.25/12 days
be Excelent !!!!
@Oliver... Thanks for the pointer to datediff(). I will update the post with information about this as well.
@Glen... thanks for the linklove 🙂
@Andy... Welcome. Thanks for telling us about the office community on FB.
@Modeste ... that is very cool. I will remember these formatting codes for an upcoming article on number formatting codes 🙂
Great tip Chandoo! I use the formula to calculate years elapsed all the time. It can seriously help save a ton of time with calculations. Also, NETWORKDAYS is one that helps and can seriously impress a boss. Keep up the great work here!
No problem! I will definitely be directing people with tough Excel questions to your blog. Keep up the great posts!
Andy
MSFT Office Outreach Team
Hi,
always great posts and a good way to start my day
but regarding the elapsed time calculations: have you never noticed that there is a result difference between using =TODAY()-A1 and using =NETWORKDAYS(A1,TODAY())?
try it for A1= a Monday such as 21sep09 and "today" is e.g. a Thursday; you get 3 or 4 respectively as a result, depending on the formula used; this is because formula =networkdays() always includes both the startdate and the end date and not only the time between these 2.
This is easily corrected/compensated bij always adding a -1 to the =networkdays() formula because the majority of us will count startday as day 0 and then the result will be consistent across the different formulas.
However, you then get into trouble if you calculate the networkdays for a date further in the past and where either the start or end date falls in a weekend.
just thought to point this out as to me these formula's are not interchangeable just like that!
have a great day!
Paul
=DATEDIF([DOJ],TODAY(),"Y") & " Y, " & DATEDIF([DOJ],TODAY(),"YM") & " M, " & DATEDIF([DOJ],TODAY(),"MD") & " D"
This will fix your 30 Days problem
I calculated the time diff between two date+ times by subtracting 2 cells & custom formatted it to "d hh:mm" format.
E.g.
Cell A1 04-Jan-12 6:00 PM
Cell A2 05-Jan-12 4:45 PM
Cell A3 0 22:45 (formula: =A1-A2)
Wat shud i do 2 not display the "zero" values i.e. no. of days in this case is zero hence the cell shud display " 22: 45" and not "0: 22: 45".
@Amol
Try the Custom Format code:
[
<1] hh:mm ; [>=1] d “d” hh:mmHi Chandoo,
If possible to compute the interval of time and date in one column.
In column C I would like to compute the total days and hours . What formula ? Please help
Example.
Column A Column B
2/13/12 3:30 AM 2/14/12 12:00 AM
In referenc to Elapsed time in months
To calculate the elapsed time in months, we can use the formula =(NOW()-A1)/30. This returns the value in 30 day months.
I use to apply formula =ROUND((TODAY()-A1)/30,0). Today, I faced a peculiar situation, A1 has date 01-Mar-2009, and today being 01-Mar-2012, it should be 36 months, but it is showing 37 months!!
Any suggestions to avoid such errors?
Regards,
Prasad DN
All I want to do is add up a series of times and receive a reply that gives me a total. What I used to do was subtrace the end time from the start time and format the result as [hh]:mm but this doesn't seem to work anymore. How has Bill Gates confounded me?
@Pete
I use Excel 2010 and it still works
The times must be entered as times in the format hh:mm:ss or hh:mm without seconds
Adding up times is as simple as =Sum(Range) or =Sum(A2:A10)
then using a Custom Number format as you have mentioned [h]:mm
If this isn't working, 2 ideas
1. Check your times are times and not text
2. Can you share your data or file with us?
My hospital tracks times from patient arrival to various procedures or treatments. When those times cross over midnight, the regular formulas (2nd time minus first time) don’t work because the result is negative and Excel (2007) won’t show a negative number in time format.
I couldn’t find a solution here (chandoo.org) but found one elsewhere that worked and it’s very simple. I would like to share it.
Assuming 1st time in A1 (column for patient arrival time) (11:00 PM), and 2nd time in B1 (column for x-ray given) (12:30 AM)). Should be 1:30 elapsed time.
=B1-A1+(B1<A1) [This comparison is the key to the solution.]
=12:30 AM – 11:00 PM + (12:30 AM < 11:00 PM)
=0.0208 – 0.9583 + (True)
=-0.9375 + (1) [This is the key! If it is false, Excel adds 0. If it’s true, Excel adds 1 and that is what corrects the negative number. Now Excel can interpret the number as a time.]
=0.0625
Converted to hh:mm = 1:30
I wrapped this formula inside an IFERROR one to alert my data entry person if she messed up and applied it to lots of different columns and it has worked wonderfully. No more complaints from the data entry person who just plugs in times from medical charts.
Very interesting solution. Thank you so much for sharing it with all of us.
HI,
I am working on a Xl application..
I want to capture time between two clicks.
Ex, in my application during run somewhere I press OK button and then I click Cancel.. I want to measure time between these two clicks... Is it possible??
Pls help on this...
@shashidhar
The answer is Yes
You will have to add an appropriate VBA event to start and stop a timer.
There are techniques which can time to the millisecond so maybe look those up on the net
WOW!!!!!! I truly love your excel time format program! WHOOOO! I am very interested in how the time formats "update" (manually on a physical keyboard) that "updates" the time into its respective decimal time formats, such as:
YYYY.yyyy, HH.hhh, etc...
How do those formulas or equations work if not in Excel mode? Example: TI calculators, Word, or any other computer language programming? Just wanted to see how it works. E-mail me at Ultra64848689Ti@gmail.com.
Thanks again for an EXCELLENT Excel program into decimal time formats!
Here's an idea: how about creating an APP for iOS and Android? Just wanted to point that out. =-D
Regarding the elapsed time in months:
I made this function to determine the time elapsed since a date using the number of days in each respective month. It's a simple subtraction and I think it works very well:((Year Today-Year A1)*12++(Month Today - Month A1)+(Day Today/Days in Month Today)-Days A1/Days in month A1)
Here's the function:
=((YEAR(TODAY())-YEAR(A1))*12)+(MONTH(TODAY())-MONTH(A1))+(DAY(TODAY())/DAY(DATE(YEAR(TODAY()),MONTH(TODAY())+1,0))-DAY(A1)/DAY(DATE(YEAR(A1),MONTH(A1)+1,0)))
Have a Merry Christmas everyone!!
I need the ability to calculate how much progress we have made between two dates and I want to represent that as a percentage.
I am thinking this would be a combination of today, networkdays & dividing the days elapsed vs the total days. Then it should be as easy as formatting my cell. Any help would be greatly appreciated.
@Christian
Your correct
dates are just numbers and so you can use simple math to derive the percentage
=(Date Now-Start Date)/(End date-Start date)
that will give you a number between 0 and 1
which you can format as a %'age
is there a way out to calculate the productivity for an employee
The day start is at 08:00 and day end is 20:00
The start date / time is recorded and end date / time is recorded
I want to calculate the timelapse taking into consideration the day begin and dayend time.
If the work begins and ends the same day, a simple formula b1-a1 would compute the productivity.
But if the process remains incomplete and is carried over to the next day, then timelines to be computed accordingly
to clarify,
if start time of an activity is 03/15/2015 18:00 hrs and end time is 03/16/2015 11:00 hrs, then the resultant formula should be 5 hrs (ie 18:00 to 20:00 hrs on day1 + 08:00 to 11:00 hrs on day2) ie 2+3
please guide.
Venkatesh, try (b1-a1)-0.5
This will subtract the fixed amount of time between shifts, 12 hours. If the time between shifts varies, then you could reference other cells that contain the variables.
Please help. when I use the networking days formula I get a date (2-may-00) I want actual number of days. I managing projects and I need to know how many days have passed since we received a project to the current date. Please help Thanks
@Aria: Just format the cell as general or number. that will fix the problem.
You rock! I looked at 17 other sites and they all did not work. Yours did. Thanks!
Hi folks ...
calculating age in years , months and days
=text(now()-a1,"yy")&" y " &text(now()-a1,"mm")-1 &" m "&text(now()-a1,"dd") & " d"
Hi, the Elapsed time in days [ =TODAY()-A1 ] works great however, if I do not have a date in A1, it shows 42157. Anyway to get it to display 0 or a Null value?
@Dan
=If(A1="",0,TODAY()-A1)
I get #NAME? and the formula does not work.
Hi Chandoo,
This might be a challenge - I am looking to calculate elapsed time between two columns
Start date Complete date
9/9/2015 7:21 10/2/2015 11:01
I need to take into account the following:
1) The employee works 7:00-3:15 pm each day
2) Std Work hours are 7hrs 45 min each day
3) Need to take into account all holidays in between start and end date
4) Work week is Mon through Friday.
Can you help?
Thanks!
Hi, i have a certain name (wilium) in column A and against this name i have 2 option, 1 Done and 2 Inprogress. i want that i count done again wilium and count inprogress against wilium separately. which formula will work for it??
Hi, i have a certain name (wilium) in column A and against this name i have 2 option, 1 Done and 2 Inprogress in column C. i want that i count done again wilium and count inprogress against wilium separately. which formula will work for it??
Year, month, day results for DoB.
The formulas I have found on the net and the datedif function do not work. This is what I came up with using a Microsoft support paper dated April 1997 with some modifications:
IF(OR(A2>$A$1,ISBLANK(A2)),"",IF(YEAR($A$1)=YEAR(A2),0,IF(MONTH($A$1)>=MONTH(A2),YEAR($A$1)-YEAR(A2),YEAR($A$1)-YEAR(A2)-1))&" years "&MONTH($A$1)-MONTH(A2)+IF(AND(MONTH($A$1)<=MONTH(A2),DAY($A$1)<DAY(A2)),11,IF(AND(MONTH($A$1)=DAY(A2)),12,IF(AND(MONTH($A$1)>MONTH(A2),DAY($A$1)=DAY(A2),ABS(DAY($A$1)-DAY(A2)),DAY(EOMONTH(A2,0))-DAY(A2)+DAY($A$1))&" days")
Check it out...
Hi, Augustin
what about :
calculating age in years , months and days
=YEAR(NOW()-DoB)-1900 & " y " & MONTH(NOW()-DoB)-1 & " m " & DAY(NOW()-DoB) & " d"
Hi Chandoo,
I am looking for help with the elapse time formula. I have a recruitment tracking sheet where we track the number of days the positions are opened, and when they are finally closed.
The opened positions will have a running turnaround time (TAT) formula and I am using this formula:
=NETWORKDAYS (start_date, TODAY (), Holidays2018)
Now, without disrupting the running TAT formula, how do I then get the TAT to stop when we have a final end date? All the information below is row:
- start_date --> Cell A
- TODAY () --> cell B
- end_date --> Cell C
Hope you are able to help. Thanks!
Interesting question. Try this:
Thank you for this helpful article. I was trying for days now to figure it out. Now the only issue I have is that if I do not have a value inputed for =TODAY()-[@[Date Precured]] Date Precured then it shows 44055. How can I get it to leave it blank if there is no data? Thanks again!!!