Use NUMBERVALUE() to convert European Number format

If you deal with customers or colleagues in Europe, often you may see numbers like this:

• 1.433.502,50
• 9.324,00
• 3,141593

When these numbers are pasted in Excel, they become text, because Excel can’t understand them.

Here is a simple way to convert the European numbers to regular ones.

Use NUMBERVALUE() Function.

How to convert European number formats with NUMBERVALUE() ?

Let’s say you have a European format number in cell A1, something like 1.433.502,50

Syntax of NUMBERVALUE():

NUMBERVALUE() takes 3 parameters.

• Number you want to convert
• Decimal separator
• Group separator

So, we can use =NUMBERVALUE(A1 , "," , ".") to convert number in A1 from European format.

Since , is the decimal point and . is the group separator in European format, NUMBERVALUE() returns 1433502.5

How to convert European number formats in earlier versions of Excel

NUMBERVALUE() is a new function added in Excel 2013. So if you are using an earlier version of Excel, then you need to come up with an alternative function. Here is one that works:

=SUBSTITUTE(SUBSTITUTE(A1, "." , "" ), "," , ".")+0

How does this work?

• We first substitute all .s with nothing – Inner SUBSTITUTE
• Then we substitute , with . – Outer SUBSTITUE
• Then we add 0 to convert text to number

Convert regular numbers to European format

Let’s say for some reason you need convert numbers to European format. Here is one formula you can use:

=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(FIXED(A1,2,FALSE),".","$"),",","."),"$",",")

How it works?

• FIXED(A1,2,FALSE) converts the number in A1 to a comma formatted number with 2 decimal points
• SUBSTITUTE(FIXED(...), ".", "$") replaces the decimal point with $ symbol (you can replace it with any symbol)
• SUBSTITUTE(SUBSTITUTE(FIXED(...),...), "," ,".") replaces all the commas with .s
• SUBSTITUTE(...., "$", ",") replaces the $ with comma

More tips on number conversions in Excel

If you deal with data that needs conversion, check out below tips.

• Quickly convert numbers stored as text
• Extract numbers from text using VBA
• Splitting a number in to integer and decimal portions
• Presenting values in Indian currency format

How do you convert numbers to European format?

I never saw the NUMBERVALUE function until yesterday. I think it is a cool function to solve the format problem.

What about you? How do you convert numbers to / from European format (or back)? Please share your formulas in comments.