Recently, Bluetaurean asked in the Chandoo.org Forums about ways to allocate work durations for various product lines across 24 hour days to create a daily schedule.
Both formula-based and VBA-based solutions were offered.
Today at formula Forensics we will take a look at the formula-based approach.
As always at Formula Forensics you can follow along, Download Here – Excel 2007-2013.
Set the Scene
Since one might encounter a similar need in a variety of contexts (manufacturing, engineering, project planning, etc.), we will look at a more general problem of allocating a set of tasks and corresponding durations to one or more days, as shown in the following diagram.
We will create two output views:
- One that is a flat list that can then be manipulated further using Excel’s Pivot table feature, and
- Another view that mimics a pivot-table (and is similar to a typical project Gantt view, but with actual values listed instead of a bar chart).
You can follow along using the attached Excel document. Download here Excel 2007+
Problem Specifics
- We have a list of tasks and their durations.
- We need to distribute the tasks to different days, without exceeding the maximum available duration in a given day.
- When the hours in a day are “used up”, we need to allocate the remaining task duration to the next day, and so on.
- On the other hand, if a given task does not use up all of the hours in a given day, we will need to assign more than one task for that day, provided the combined durations do not exceed the available hours for that day.
- In other words, we will need to split a task across one or more days, or combine one or more tasks into a single day, as needed, to maximize the work performed in a given day.
Developing the Approach
Before we tackle this problem in Excel, let us review how we might do this manually. Like most things, we might use the following three step process:
- Take the first task and assign its duration to Day 1. If the task’s duration exceeds the maximum hours available in a day, allocate the portion of the duration that does not fit into Day 1 into Day 2.
- Take the second task, and see whether it can fit into an existing day, or whether it needs to be distributed to multiple days
- Etc. (OK… so that three-step process was a stretch!)
Statistics show that most people think in terms of IF-THEN-ELSE statements. So here it is…
For a given Day, and for a given Task, If [Hours Not Allocated For that Task] > [Hours Available for that Day] Then Set Duration for that Day as [Hours Available for that Day] Else Set Duration for that Day as [Hours Not Allocated for that Task] EndContinue the above evaluation until all tasks have been allocated to days.
Of course, the above IF() logic can be condensed as follows:
MIN( [Hours Not Allocated For that Task] , [Hours Available for that Day] )
Putting it All Together: Output Option 1: Gantt-like View
Let us employ the above approach to create the Gantt-like view.
To make our approach more generic, we will use an Excel Name called “MaxHrsPerDay” to indicate the maximum available hours in a given day. (In the sample worksheet, it has been set to 24 hours.)
Our source data is setup as shown in the diagram below:
- Tasks are in the range A2:A5
- Durations are in the range B2:B5
We will create the output in a separate worksheet, in the range A1:E5 as shown below:
Put the following formula into cell A2 and copy down to A5:
=SourceData!$A2
(This formula is merely referencing the values from the SourceData sheet. The sample workbook also includes an approach to make this reference more location independent.)
Put the following formula in cell B2, and copy it down and right:
=MIN((SourceData!$B2-SUM($A2:A2)), (MaxHrsPerDay-SUM(B$1:B1)))
Setup the header row (B1:E1) as desired. (I have used text values for the header. You could also calculate the header text using formulas. Since that is straightforward, I will leave that as an exercise for the reader.)
Now let us look at what the formula in cell B2 is doing:
- SUM($A2:A2) is calculating the sum of the allocated durations for TaskA. (Please note the use of absolute and relative references. The formula is anchored on column A, but the starting row, ending row and ending column are free to expand.) SUM($A2:A2) returns zero since SUM() ignores text values.
– If you look at cell C2, the reference changes to SUM($A2:B2).
– In cell B3, the reference changes to SUM($A3:A3). You get the idea
- (SourceData!$B2-SUM($A2:A2)) calculates the difference between the duration for TaskA (40 in the example) and the hours allocated as of that point (0), to return 40-0=40.
- SUM(B$1:B1) is calculating the sum of the allocated hours for Day1. (Again, we are using a combination of absolute and relative references to keep the calculation anchored on column B.) In this case, the value is zero, since this is the first allocation for Day1.
- (MaxHrsPerDay-SUM(B$1:B1)) calculates the hours remaining (i.e. available) for Day1. Since this is for cell B2, the calculation returns 24 – 0 = 24.
That is it!
We put those absolute and relative references to good use!
This approach was easy because all we had to do was calculate the duration for a given task for a given day.
On the other hand, if we had to figure out what the Task was, or which Day it was, the calculation gets a little more involved. Since this is “formula forensics”, we would not have it any other way! 🙂
Putting it All Together: Output Option 2: A Sequential List of Tasks and Durations for Each Day (i.e. a Flat List)
As before, we will use the Excel Name “MaxHrsPerDay” to refer to the maximum hours in a Day.
As shown in the following diagram, we will turn the source data into a flat list of Days, Tasks and Durations:
Unlike with VBA, since a formula cannot choose which row and column to write its output, we have to set the formula in every cell where we suspect there might be a value.
In the above sample diagram, we copy the formulas from row 2 to row 9. However, row 9 shows “…” indicating that the list was completed by row 8.
Let us look at how to determine the value for Day, Task and Allocated Duration.
For ease of description, I have created the following Excel Names:
WorkList: =A2:A5 in the source data.
WorkDuration: =B2:B5 in the source data
While creating the Gantt-like view earlier, we were able to take advantage of the static “Day” and “Task” values to determine the Remaining Duration, Available Duration, etc. Since we now have to determine all three values (Day, Task, Allocated Duration), we will need some “helper” data.
We will add a column alongside the source data that shows the cumulative duration (for reasons that will become clear shortly), as shown in the following diagram:
Cumulative Duration is calculated as the sum of all durations up to a given row.
- For example, in cell C2, the Cumulative Duration is 40.
- In cell C3, the Cumulative Duration is 40+20=60
- And so on.
For ease of referencing, we will use an Excel Name called CumulativeDuration =C2:C5.
Let us look at why we need the “CumulativeDuration” helper column:
The circular logic problem
In order to determine the durations already allocated for a given day, we will need to know which Day it is.
We also need to know which Task we are trying to calculate the duration for.
So… do we calculate the Day or the Task or the Duration first?!! As you can imagine, that will soon land us in some circular logic.
Some helpful observations about the output:
- In column C of the output (on worksheet FlatList), the sum of allocated durations adds up to the total duration for all tasks. (No surprise here!)
- If every task had duration equal to the MaxHrsPerDay, you would have the same duration value for all days. (Not surprising, but interesting!)
- In other words, you could think of the Allocated Duration column as the total duration for all tasks, allocated MaxHrsPerDay at a time.
- Now we need a way to iterate through the duration values one at a time and account for the durations already processed. In other words, each value needs to contain all of the previous values. Welcome to an array of the cumulative durations!
- For example, in the cumulative array “{40;60;65;80}”, the value 60 already includes the previous value 40 in it. This allows us to subtract all durations allocated up to a given row, to get the duration value that is remaining to be allocated.
- Since Excel is good with numbers, we will base the calculation for AllocatedDuration and Tasks on the Duration values.
- By calculating the two values separately, we avoid the circular logic.
Let’s now look at the formulas for Day, WorkItem and AllocatedDuration.
It would be easier if we looked at the formulas in reverse order, starting with AllocatedDuration, then WorkItem, and finally Day.
Formula for “AllocatedDuration”
Enter the following formula into cell C2, ending with Ctrl+Shift+Enter, as shown in the following diagram:
=IF(SUM(C$1:C1)>=SUMPRODUCT(WorkDuration), “…”,MIN(INDEX(WorkDuration, MATCH(TRUE, CumulativeDuration-SUM(C$1:C1) > 0, 0)) – SUMIFS(C$1:C1, B$1:B1,B2), MaxHrsPerDay-SUMPRODUCT((A$1:A1=A2)* IF(ISNUMBER(C$1:C1), C$1:C1, 0)))) Ctrl+Shift+Enter
Let us look at the formula closely (using the formula in row 2):
- SUMPRODUCT((A$1:A1=A2)* IF(ISNUMBER(C$1:C1), C$1:C1, 0)) -> This calculates the sum of all allocated durations up to the previous row, where the Day = current row’s day. Please note the use of absolute and relative references. They allow us to expand the range as we go down the rows, while remaining anchored to the first row.
– Since this is the first data row, C$1:C1 returns “Allocated Duration” and the ISNUMBER() function returns FALSE, and consequently, the IF() function returns 0.
– A$1:A1 returns “Day”, and the test A$1:A1=A2 returns FALSE. Please note that in this case, it does not matter whether A2 has a value in it, whether it has the value 1, etc.
– SUMPRODUCT() provides the result of FALSE * 0 = 0
- MaxHrsPerDay – SUMPRODUCT((A$1:A1=A2)* IF(ISNUMBER(C$1:C1), C$1:C1, 0)) -> This calculates the difference between maximum duration available for a day and the sum of durations allocated for the current day. In other words, it calculates the available duration for the current row’s day.
– In this example, the calculation results in MaxHrsPerDay (24 in our example) – 0 = 24
- SUMIFS(C$1:C1, B$1:B1,B2) -> This calculates the sum of all allocated durations for the current row’s task. Since B$1:B1 is the text value “Work Item”, the SUMIFS() returns 0. Again, it does not matter if B2 is blank or has a value like “TaskA”, since Excel correctly evaluates the condition whether B$1:B1 equals B2.
- SUM(C$1:C1) -> This calculates the sum of all allocated durations up to the previous row.
- CumulativeDuration — SUM(C$1:C1) -> CumulativeDuration evaluates to {40;60;65;80}. SUM(C$1:C1) evaluates to zero. As such, the expression evaluates to {40;60;65;80} – 0, or {40;60;65;80}.
– If we look at the calculation for this expression in cell C3 (the expression would be “CumulativeDuration—SUM(C$1:C2)”), we would get the result of {40;60;65;80} – (0+24) = {16;36;41;56}. (As you know, subtracting a scalar value from an array results in an array with each value reduced by the scalar value.)
– If we look at the calculation for this expression in cell C4 (the expression would be “CumulativeDuration—SUM(C$1:C3)”) , we would get the result of {40;60;65;80} – (0+24+16) = {0;20;25;40}
– As you can see, each successive calculation reduces the CumulativeDuration array by the amount of hours already allocated. By reducing the CumulativeDuration array in this fashion, we ensure that we do not “double count” a duration.
– If a value in the array evaluates to zero, it means the corresponding duration has been fully allocated. (In cell C3, the first value in the array is zero, indicating that the original 40 hours has been fully allocated.) We will put this knowledge to good use in the next expression.
- MATCH(TRUE, CumulativeDuration—SUM(C$1:C1) > 0, 0) -> The expression CumulativeDuration—SUM(C$1:C1) > 0 evaluates to ={TRUE;TRUE;TRUE;TRUE} because all values are greater than zero. By performing a MATCH() for TRUE, we are able to find the first location in the array that has a non-zero value.
– If we look at the result of this expression in cell C3, we get {16;36;41;56} > 0 = {TRUE;TRUE;TRUE;TRUE}
– If we look at the result of this expression in cell C4, we get {0;20;25;40} > 0 = {FALSE;TRUE;TRUE;TRUE}
– As you recall, the zero values (or FALSE) correspond to the durations that have been fully allocated, whereas, the non-zero values (or TRUE) correspond to the durations that have NOT been fully allocated.
– It is helpful to note that MATCH() returns the LOCATION of what it finds. As such, the returned location is that of the first duration value that has not been fully allocated! Since the CumulativeDuration array is the same size as the WorkDuration array, we will be able to put this returned location value to good use in the next expression.
- INDEX(WorkDuration, MATCH(TRUE, CumulativeDuration — SUM(C$1:C1) > 0, 0)) -> By using the location value (of the first duration value that has not been fully allocated), we find the corresponding original duration value from the WorkDuration array.
– As we saw earlier, the expression “CumulativeDiration – SUM(C$1:C1)” reduces the CumulativeDuration by the duration values allocated to that point. However, the resulting array could have partial duration values as well. By referencing the corresponding duration value from the WorkDuration array, we ensure that we retrieve the original (full) duration value that was to be allocated.
- MIN(…) -> This expression calculates the value of MIN([Hours Not Allocated For that Task], [Hours Available for that Day])
– [Hours Not Allocated For that Task] is returned by INDEX(WorkDuration, MATCH(TRUE, CumulativeDuration—SUM(C$1:C1) > 0, 0)) – SUMIFS(C$1:C1, B$1:B1,B2)
– [Hours Available for that Day] is returned by second half of the MIN() expression: MaxHrsPerDay—SUMPRODUCT((A$1:A1=A2)* IF(ISNUMBER(C$1:C1), C$1:C1, 0)).
– So, we essentially got back to the logic we started from, which is the same logic we used for creating the Gantt-like view as well.
- The remaining portion of the formula (the IF() check) determines if all of the hours have been allocated. If all hours have been allocated, it returns “…”.
– SUMPRODUCT(WorkDuration) -> This expression calculates the total of all work duration values. In cell C2, it evaluates to SUMPRODUCT({40;20;5;15}) = 80
– SUM(C$1:C1)>=SUMPRODUCT(WorkDuration) -> Determines if the sum of durations allocated up to that point is greater than the total for all durations. (Since this is part of an array formula, you could also use the SUM function in place of SUMPRODUCT. But I am partial to the SUMPRODUCT function!! So, unless you are in a competition where the winner is determined by the shortest formula, feel free to use either one!
Formula for “WorkItem”
Enter the following formula into cell B2, ending with Ctrl+Shift+Enter, as shown in the following diagram.
=IF(SUM(C$1:C1)>=SUMPRODUCT(WorkDuration), “…”,INDEX(WorkList, MATCH(TRUE, (CumulativeDuration-SUM(C$1:C1)) > 0, 0))) Ctrl+Shift+Enter
You are already familiar with most of the formula components since you saw them in the formula for AllocatedDuration. The only difference is that in this formula, we are returning a value from WorkList. (i.e. we locate the position of the first non-zero duration in CumulativeDuration array, and since that array is the same size as the WorkList array, we are able to find the first Task that has not been fully allocated.)
Formula for “Day”
Enter the following formula into cell A2, ending with Ctrl+Shift+Enter, as shown in the following diagram:
=IF(SUM(C$1:C1)>=SUMPRODUCT(WorkDuration), “…”, MAX( N(A1) + (SUMIFS(C$1:C1, A$1:A1, A1)>=MaxHrsPerDay), 1)) Ctrl+Shift+Enter
Let us look at the formula in detail (using the formula in row 2):
- SUMIFS(C$1:C1, A$1:A1, A1) -> This expression calculates the sum of all durations (in column C) where the Days (in column A) equal the previous day.
– In cell A2, this expression evaluates to “SUMIFS(“Allocated Duration”, “Day”, “Day”)” = 0. (Excel smartly ignores any non-numeric values in the first argument.)
– In cell A3, this expression evaluates to “SUMIFS({“Allocated Duration”;24}, {“Day”;1}, 1)” = 24.
- SUMIFS(C$1:C1, A$1:A1, A1)>=MaxHrsPerDay -> This expression checks if the sum of all durations where the Days equal the previous day is greater than or equal to MaxHrsPerDay.
– In cell A2, this expression evaluates to FALSE
– In cell A3, this expression evaluates to TRUE
- N(A1) -> This expression returns the numeric value for its argument. Since N() returns zero for any non-numeric arguments, we use this function to return zero for the heading (“Day”) in A1. (Any numeric values are returned as is.)
- MAX( N(A1) + (SUMIFS(C$1:C1, A$1:A1, A1)>=MaxHrsPerDay), 1) -> The first argument of the MAX function “N(A1) + (SUMIFS(C$1:C1, A$1:A1, A1)>=MaxHrsPerDay)”returns the next increment for day, if the previous day has been fully allocated. Otherwise, it returns the same value as the previous day.
– In cell A2, this expression evaluates to MAX( N(“Day”) + (SUMIFS(“Allocated Duration”, “Day”, “Day”)>=24), 1), which evaluates to MAX( N(“Day”) + (0>=24), 1), which evaluates to MAX( 0 + (FALSE), 1), which finally evaluates to 1.
– In cell A3, this expression evaluates to MAX( N(1) + (SUMIFS({“Allocated Duration”;24}, {“Day”;1}, 1)>=24), which evaluates to MAX( N(1) + (24>=24), 1), which evaluates to MAX( 1+ (TRUE), 1), which finally evaluates to 2 since 1 + TRUE = 2.
Download
You can download a copy of the above file and follow along, Download Here – Excel 2007-2013.
Final Thoughts
While we used the same basic logic for both output options in this article, there are probably many other ways to tackle the age-old problem of production scheduling.
I would love to hear about some of your ideas, as well as ways to extend the concepts described here.
In the meantime, I wish you continued EXCELlence!
Sajan.
Other Chandoo.org Posts related to Scheduling
Here at Chandoo.org you can find the following related posts:
http://www.chandoo.org/wp/2010/11/18/scheduling-variable-sources/
http://chandoo.org/wp/2009/06/16/gantt-charts-project-management/
http://chandoo.org/wp/project-management-templates/gantt-charts/
Thank You
This was Sajan’s second post at Chandoo.org and so a special thank you to Sajan for putting pen to paper to describe the technique here.
You may want to read Sajan’s first post here or thank him in the comments below:
Formula Forensics “The Series”
This is the 31st post in the Formula Forensics series.
You can learn more about how to pull Excel Formulas apart in the following posts: Formula Forensic Series
Formula Forensics Needs Your Help
I need more ideas for future Formula Forensics posts and so I need your help.
If you have a neat formula that you would like to share like above, try putting pen to paper and draft up a Post like Sajan has done above or;
If you have a formula that you would like explained, but don’t want to write a post, send it to Hui or Chandoo.
129 Responses to “Write a formula to check few cells have same value [homework]”
=NOT(STDEV(A1:A4))
this also works for large ranges of numerical values (but not for text)
@Arie
Nice formula Arie
Except that it doesn't work for Text values
I'll submit
=COUNTIF(A1:A4,A1)=COUNTA(A1:A4)
which works for Numbers and Text
and answers the two bonus questions as well
This is waaay more elegant than my solution. Nice one :).
I had =NOT(COUNTIF(A1:A4,A1:A4)-COUNTA(A1:A4)), somehow I keep forgetting we can use more than one "=" sign on a given formula :-/
Hi
Works for numbers, text and logical values on a range from A1:An.
=COUNTIF(A1:An,A1)=ROWS(A1:An)
well if you name the range, you could use following:
=IF(SUMPRODUCT(1/COUNTIF('range','range'))=1,1,0)
Hello lockdalf
The IF()-part is not necessary.
=SUMPRODUCT(1/COUNTIF(‘range’,'range’))=1
Not Working for =IF(SUM($C$1:$F$1)=0,"",SUM($C$1:$F$1)) in cell A1 to A4
My solution is a, perhaphs slightly complex, array formula as follows:
{=IFERROR(AVERAGE(IF(ISBLANK(A1:H1),9999,SUBSTITUTE(A1:H1,A1,9999)*1))=9999,FALSE)}
Assuming there is a value (numerical, text, logic etc) in cell A1, this formula will work - and it will 'ignore' any cells that are 'blank' within the range A1:H1 (which can be extended to the required size).
Breaking the formula down, the SUBSTITUTE(A1:H1,A1,9999) replaces all values (be it text / numerical) in the range A1:H1 that MATCH the value of cell A1 with the number 9999 (this should be changed to any number that WON'T APPEAR IN THE RANGE).
These values are then multiplied by 1 (as SUBSTITUTE results in a text answer).
Wrapping this in an IF(ISBLANK(A1:H1),9999,.........) formula takes care of any blank cells, setting them to this default value of 9999 also - this allows you to set the formula up once for a large range and then not have to alter as more data comes in.
An Average is then taken of all these values - if all cells that contain values are the same, the average will come back to 9999.
If all values are numerical but some differ, the average will differ from 9999 and will result in a FALSE answer. If some / all of the values are text and some differ from that in cell A1, the AVERAGE function will result in an Error, but in these instances the Match needs to return FALSE, hence the IFERROR function.
Sure there's a simpler way to do this though!!
`{=IF(AND(COUNTA(RANGE)-SUM(--ISNUMBER(FIND(UPPER(FIRST ELEMENT IN RANGE),UPPER(RANGE))))=0,LEN(FIRST ELEMENT IN RANGE)=MAX(LEN(RANGE))),TRUE,FALSE)}`
so if your data was in Column 1 and began in A1, you'd use
`{=IF(AND(COUNTA($1:$1)-SUM(--ISNUMBER(FIND(UPPER($A$1),UPPER($1:$1))))=0,LEN($A$1)=MAX(LEN($1:$1))),TRUE,FALSE)}`
This will work for strings and things, if you want it to be case sensitive (I don't), just remove the UPPER() part.
What this does:
`COUNTA($1:$1)`
tells you how many entries you're looking at over your range (so we can work with an undetermined size).
`--ISNUMBER()`
ISNUMBER will return TRUE or FALSE depending on if the value inside is a number or not. the -- part converts TRUE/FALSE in to 1 or 0.
`UPPER()` OPTIONAL
converts the value in to upper case. If passed a number it changes it to text format. This is what stops it from being case sensitive.
`FIND($A$1,$1:$1)`
will return a number if A1 is contained in each cell containing an entry in column 1.
`LEN($A$1)=MAX(LEN($1:$1)`
checks that all elements are the same length. This is needed to avoid partial matches (without it, if A1 contained zzz and A2 contained azzza it would flag as true).
REMEMBER this is an array formula, so enter with ctrl+shift+enter.
{=MIN(--(A1=OFFSET(A1,,,COUNTA(A1:A4))))}
Gives 0 if false and 1 if true
=COUNTIF(A:A,A1)/COUNTA(A:A) = 1
This meets both bonus requirements and is dynamic. Keep adding more contents in column A and it will include these automatically.
I like this a one a lot. I would make one small change by inserting a table for my data range. Makes it dynamic without selecting the whole column
=IF(COUNTIF(tableName[colName],A2)/COUNTA(tableName[colName])=1,TRUE,FALSE)
For only Numeric values
=MAX(A:A)=MIN(A:A)
Awesome!
=(A1=B1)*(B1=C1)*(C1=D1)
Case sensitive.
=SUMPRODUCT(0+EXACT(A1:A4,A1))=COUNTA(A1:A4)
Regards
I'd use this
=COUNTIF(range,INDEX(range,MODE(MATCH(range,range,0))))=COUNTA(range)
It takes Hui's formula but ensures that the test value for the countif is the value or string that is most common in the range. Just in case you get a false but the problem is just with your test value being the odd one out.
=SE(E(A1=A2;A1=A3);SE(E(A1=A4;A2=A3);SE(E(A2=A4;A3=A4);"ok")))
SE = IF
E = AND
Seems you could shorten it with
=AND(A1=A2,A1=A3,A1=A4)
Bonus question 1 & 2
Array formula: {AND(A1=A1:AN)}
This will test all cells in range, including text and numbers.
Cheers
A very simple solution uses Excel's Rank function. Insert in B1 = Rank(A1, $A$1:$A$4). Copy down this formula to B4. If the answers in B1 thru B4 are all 1, the values are equal. For an open range of cells, label the range of input (example "TestData") and place the label in the funtion (= Rank(A1, TestData) then copy down to an equivelent length of rows as the range.
=IF(SUM(A1:A4)/COUNT(A1:A4)=A1,TRUE,FALSE)
=IF(SUM(A1:D1)/4=A1,"True","False")
I enjoy your emails. I have learned a lot from them. Thank you for what you do.
.
{=PRODUCT(--(A1=A1:A4))}
.
Change A4 to An.
Greate
{=PRODUCT(- -(A1=A1:A4))}
=IF((SUM(A1:A4)/COUNT(A1:A4))=A1,"TRUE","FALSE")
I would use the formula which is mentioned below:-
=IF(PRODUCT($A:$A)=A1^(COUNTIF($A:$A,A1)),"Yes","No")
At last a homework assignment that I could answer on my own. And I even understand some of the elegant answers from other readers this time.
My solution was to nest IF statements:
=IF(A4=A3,IF(A3=A2,IF(A2=A1,TRUE,FALSE),FALSE),FALSE)
This satisfies bonus question 2 but I think the structure makes it impossible to modify this solution to satisfy bonus question 1. And I wouldn't want to use this strategy to compare very many values...
This answers all of your questions:
=PRODUCT(--(INDIRECT("$A$1:$A$"&$B$1)=$A$1))
where column A contains the values and $B$1 has the number of rows to assign to last A-cell.
Sorry, forgot the braces:
{=PRODUCT(–(INDIRECT(“$A$1:$A$”&$B$1)=$A$1))}
=IF(A1=A2:A2=A3:A3=A4>1,"TRUE","FALSE")
=IF(A1=A2:A2=A3:A3=An>1,"TRUE","FALSE")
=SUM(HELLO, A1)
{=IF(SUM(IF(A1:A4=A1,0,1))=0,TRUE,FALSE)}
This will work for numbers or text, and will work for any number of cells (A4 would just be An)
Here's another alternate, assuming values in cells a1:d1
=IF((A1*B1*C1*D1)^(1/COUNT(A1:D1))=AVERAGE(A1:D1),1,0)
{=IF(AND($A$1:$A$4=OFFSET(A1,0,0)),1,0)}
=SUM(IF(FREQUENCY(MATCH(A1:A4,A1:A4,0),MATCH(A1:A4,A1:A4,0))>0,1))
REVISED FORMULA
=IF((A1=A2)*AND(A1=A3)*AND(A1=A4),"TRUE","FALSE")
Regards
=IF(SUMPRODUCT(--(A2:A5=A2))/COUNTA(A2:A5)=1,1,0)
- should be --
I would use something like this: =COUNTA(A1:A4)=COUNTIF(A1:A4,A1)
You can even do a whole range and as you enter data into the range it tells you if they all match. Going down to row 5000: =COUNTA(A1:A5000)=COUNTIF(A1:A5000,A1).
Thanks,
B
Just saw Hui response. I really did come up with this and didn't just copy his.
{=SUM(--(A1:A101=A1))=(COUNTA(A1:A10)+COUNTBLANK(A1:A10))}
For numeric values:
=(OFFSET(list,,,1,1)=AVERAGE(list))
where list = A1:A4
I need to retract my own post here guys.
It is WRONG! Let me explain.
Suppose we have
A1 = 1
A2 = 0
A3 = 2
then Average = 1 and OFFSET(list,,,1,1) = 1
so 1 = 1 but all the elements are NOT equal.
correction
{=SUM(--(A1:A10=A1))=(COUNTA(A1:A10)+COUNTBLANK(A1:A10))}
=IF(A1=B1,IF(B1=C1,IF(C1=D1,TRUE,FALSE),FALSE),FALSE) ....
=COUNTIF(OFFSET($A$1,0,0,COUNTA($A:$A),1),$A$1)=ROWS(OFFSET($A$1,0,0,COUNTA($A:$A),1))
I have a little more flexible approach. Suppose the value of 'n' is known. There is a possibility that only some of the cells in a row are filled up. For example if n = 10, then in a row, A1 to A10 must be compared. But in case only cells upto A7 are filled up. The formula thus has to adapt accordingly. Below formula does that:
=COUNTIF(INDIRECT(ADDRESS(ROW(),1)&":"&ADDRESS(ROW(),COUNTA(A1:J1))),A1)=COUNTA(INDIRECT(ADDRESS(ROW(),1)&":"&ADDRESS(ROW(),COUNTA(A1:J1))))
In A1:A100 is word/number
In B1 is word/number we look
C1=MAX(FREQUENCY(IF(A1:A100=B1,ROW(A1:A100)),IF(A1:A100<>B1,ROW(A1:A100)))) array formula
We can use an array formula
{=PRODUCT(--(A1:An=A1))}
OR if we want n variable
{=PRODUCT(--(INDIRECT("A1:A"&COUNTA(A:A))=A1))}
Just as an add on...
The range could be 2D as well
{=PRODUCT(–(A1:Zn=A1))}
{=AND(A1=A2:An)}
I would use this one (simlpe)
=(COUNTA(A:A)=COUNTIF(A:A;A1))
try this
=MAX(A1:A4)=MIN(A1:A4)
Olso try this
{=SUM(RANK(A1:A10,A1:A10))=COUNT(A1:A10)}
Please notice it is an Array Formula
Dear All,
i used that formula
{=IF(COUNTIF(A1:A4,A1:A4)=COUNTA(A1:A4),TRUE,FALSE)}
Love the variety of responses.
=MAX(A1:A4)=MIN(A1:A4)
and
=COUNTA(A1:A4)=COUNTIF(A1:A4,A1)
will return true if the input range has blank cells
My personal fave is the array formula {=AND(A1=A1:A4)}. Short and sweet, and easy to read. Blank cells will tally as a mismatch.
A close second is
=SUMPRODUCT(1/COUNTIF(A1:A4,A1:A4))=1
which will throw an error if blanks are present.
=PRODUCT(B1:D1)=B1^COUNT(B1:D1)...will return TRUE or FALSE
Dear Sir,
My answer is =exact(a2,a1)
=IF((a1=a2=a3=a4),1,0)
4 equal values gives me a 0 ???
Hello Chandoo,
We can also use Conditional Formatting......
For Numerics..
=SUM(A1:AN)/A1=COUNT(A1:AN)
results in True/False.
=AND(IF(A1=B1,1,0),IF(B1=C1,1,0),IF(C1=D1,1,0))
=AND(A1=A2:A4) array entered
Generic
=AND(A1=A2:An) array entered
=--(COUNTIF(A1:A4,A1)=COUNTA(A1:A4))
will give value as 1 or 0
Hi there, here's a simple formula to determine not only whether all 4 cells (A1 --> A4) are equal, but also whether any of the cells are equal and identifies which cells they are ...
=COUNTIF($A$1:$A$4,A$1)*1000+COUNTIF($A$1:$A$4,A$2)*100+COUNTIF($A$1:$A$4,A$3)*10+COUNTIF($A$1:$A$4,A$4)*1
A result of 1111 means no cells are equal, 4444 means all cells are equal, 1212 would mean there are 2 cells the same & they are in A2 & A4, etc
=((A1=B1)+(A1=C1)+(A1=D1))=3
Obviously doesn't cover bonus question 1, but does so for q2 🙂
If formula
=MIN(A1:A4)=MAX(A1:A4)
Try this formula
=IF(COUNTIF(A1:A4,A1)-ROWS(A1:A4)=0,"True","Flase")
I used the Swiss knife of excel: SUMPRODUCT, works for numeric as well as for non-numeric cell content and A1:A4 is obviously easily changed to any range.
=IF(SUMPRODUCT(--(OFFSET($A$1:$A$4,0,0,ROWS($A$1:$A$4)-1,1)=OFFSET($A$1:$A$4,1,0,ROWS($A$1:$A$4)-1,1)))=ROWS($A$1:$A$4)-1,TRUE(),FALSE())
All of the individual non-array formulas (didn't test the array ones) have one flaw or another - mostly specifically if all the columns are blank, the result would still be false.
Another formula in the comments worked for these but didn't work for when all columns had "0.00" in them. My solution was to OR the two. If H3 through H149 have your values, then this is what worked for me:
=IF(OR(COUNTIF(H3:H149,H3)=COUNTA(H3:H149),SUMIFS(H3:H149,H3:H149,1)=COUNT(H3:H149)),IF(H3="","Blank",H3),"")
This solution puts "Blank" if all the rows are blank, otherwise, it puts whatever the value that's in all of the rows - "0.00" or whatever.
Thanks for all the answers!
I used a nested if statement which also showed, via the false message, the first instance of cells which were not equal for the cells a1 to a5.
=IF(A1=A2, IF(A2=A3, IF(A3=A4, IF(A4 = A5, "True","False A4"), "False A3"), "False A2"))
Hi,
First, let me begin by saying, I am a big fan of all your posts and read your emails, mostly on the same day as you send them. I have not replied as much as I wanted to.
This is my first attempt at answering a question on your post
I came up with a simple check which will test if all values in a range A1:An are same or not
Assuming range you want to check is A1:A10,
In Cell B1, insert the formula
=IF(COUNTIFS(A1:A10,A1)=COUNTA(A1:A10),"All cells are same","All cells are not same")
The idea I applied is counting total number of non-blank cells and then counting the number of cells which match cell A1. If these are same, then it means
a) all cells have the same value! (All can be blank, then both counts will be zero)
I am working on finding the range automatically 🙂
Can extend this into VBA and use InputBox etc to generate some user interaction
Thanks
Shailesh
=IF(COUNTIF(A1:A4,A1)=COUNT(A1:A4),TRUE,FALSE)
For homework & Bonus Question 3
=IF(AND(A1=A2,A2=A3,A3=A4),1,0)
=IF(SUMIFS(A12:A15,A12:A15,1)=COUNT(A12:A15),1,0)
One possible solution could be =+IF(COUNTIF(A1:A4,A1)-COUNT(A1:A4)=0,1,0)
where A1:A4 is data range which can be a dynamic range and the formula can be modified accordingly.
Rgds,
Sanjeev Sawal
I got the right result with this one:
=IF(A1=B1;IF(C1=D1;IF(B1=C1;1;0);0);0)
=and(a1=a2,a1=a2,a1=a3)
ANSWER FOR bONUS 1
=MAX(A1:A10)-MIN(A1:A10)
=AND(A1:A3=A2:A4)..Confirm with Ctrl+Shift+Enter (As as array formula). Works well for Text values and large range of values as well.
suppose cells contain 2 values ==== Yes | no
formula :
1
=counta(a1:a4)=countif(a1:a4,"yes")
It will return True or False.
2
=IF((COUNTA(A1:A4)=COUNTIF(A1:A4,"yes")),"Same value","Mis-match")
it will return Same Value OR Mis-match.
Hope you like it.
Regards
Istiyak
Also can use this formula
=IF(AND(A1=A2,A1=A3,A1=A4),"1","0")
Let say the values are in the range $B$1:$E$1, then the formula is:
If(sumproduct(--($B$1:$E$1=$B$1))=CountA($B$1:$E$1);1;0)
Please check that:
* $B$1 was used as pivot value and could be randomly selected
* It works well if parenthesis is omitted for values "1" and "0"
* This formula applies also to "n-values" and non-numeric values (text, logical, etc.)
Regards,
A
This formula is equivalent to
If(CountIF($B$1:$E$1,$B$1)=CountA($B$1:$E$1),1,0) mentioned before...
Hi, first time trying to solve a probleme.
New at this but really enjoying Chardoo.org
Think the following will work in all 3 questions
{=IF(SUM(IF(A1=$A:$A,1,0))=COUNTA($A:$A),TRUE,FALSE)}
Regards
Jorrie
use below formula for to get True / False
=COUNTA(A1:A4)=COUNT(A1:A4)
and use below formula for to get {1/0} or {match / Mismatch}
=IF(COUNTA(A1:A4)=COUNT(A1:A4),{1,0} or {match,Mismatch})
=IF(COUNTA(A1:A4)=COUNT(A1:A4),1,0) or =IF(COUNTA(A1:A4)=COUNT(A1:A4),"Match","Mismatch")
[...] Last week in Write a formula to check few cells have same value [Homework], [...]
Hi, sorry if it's repeated, this array formula works well with numbers or text, the range can easily be dynamic: {=AND(A1:An=A1)} Now, after three days, I understand a lot more about array formulae, thanks?
=IF(AND(A1=A2,A2=A3,A3=A4),"TRUE","FALSE")
What if there are not only four cells to compare but An?
how will I determine if there is one cell that is not equal from any other cells?
=IF(COUNTA(A1:A4)=COUNT(A1:A4),1,0)
=IF(COUNTA(A1:A4)=COUNT(A1:A4),”Match”,”Mismatch”)+
=IF(AND(A1=A2,A2=A3,A3=A4),”TRUE”,”FALSE”)
=iF(AND(EXACT(C15,D15),EXACT(E15,F15)),"Match","Mis-match")
how this formula works in excel (B4+E4)/50*20
I'm a little late to the party, but I figured I'd post anyways.
For numbers only:
=NOT(VAR.P(A1:An))
The formula given below will fulfill the all criteria including bonus questions
=IF(COUNTA(A:A)=COUNTIF(A:A,A1),"True","False")
REGARDS
=IF(MATCH(A1,A2:A4,0),TRUE,FALSE)
=IF(COUNTIF($A$1:$A$4,A1)>1,"true","false")
=IF(COUNTIF(A:A,A1)>1,"true","false")
@Naveen
You can simplify your formulas as below:
=COUNTIF($A$1:$A$4,A1)>1
=COUNTIF(A:A,A1)>1
Excel will return True or False without the need for the If() function
Hi ,
This question is similar to the one in the post.
I have Text values in cell A1 and A2.
If A1 = A2, update 10 in cell A3 , else 0.
Is there any formula for this. I am new to VB and hence do not have much knowledge. Eager to learn!!
Thanks in advance !!!
=AND(A1=A2,A1=A3,A1=A4)
also =IF(AND(A1:A4=A1),TRUE,FALSE)
my question is
finding the total of values in cell A1,A2,A3,A4,andA5
@Norine
Is it as simple as =Sum(A1:A5)
One can use "IF, AND" formula.
=IF(AND(A1=A2,A2=A3,A3=A1),"True","False")
=COUNTIF(A:A,A1)=COUNTA(A:A)
Enter array formula like, = IF($B$16:$B$21=$B$17:$B$22,"Yes","No")
Sorry, Enter a array formula like this: =IF(AND($B$16:$B$21=$B$17:$B$22),"Yes","No")
=IF(AND($E$5=$E$6,$E$6=$E$7,$E$7=$E$8),"true","flase")
it can work try this one
A question for you
sheet 1 table A1:C10
What formula in sheet 2 A1 will give me what is entered in the table sheet 1 A1:C10
There is usually only one entry made in the table but if you can supply the answer to 1 or 2 entries I would be grateful
=max(A:A)=min(A:A)
FOR TEXT DATA
=COUNTIF(A1:A5,a1)=COUNTIF(A1:A5,"*?")
FOR VALUE DATA
=COUNTIF(A1:A5,A1)=COUNTA(A1:A5)
Both Return TRUE or FALSE
=if({sum(1/countif($A$1:$A$n,A1:An)}=1,"All Same","Not All Same")
I use formula A1=B1 and get value of TRUE / FALSE in C1. I had dragged this formula for 10 rows. Now in cell D2 i tried to put formula..
=if(and(c1="False", c2="true"), "conflict", "no conflict")
but even when the condition is true i am still getting no conflict.
Can you please advice?
thanks,
Manish
@Manish
Remove the " from around True and False
=if(and(c1=False, c2=True), "conflict", "no conflict")
In C1 and C2 you have a Boolean expression and it evaluates as True/False
These are not text, although they do appear as Text, they are not 1/0 although they sometimes behave as 1/0, they are in fact Boolean values True/False
So in your example you can simplify it as
=If( And( Not(C1), C2), "conflict", "no conflict")
=SUMPRODUCT(MATCH(A1:A4,A1:A4,0))=COUNTIF(A1:A4,A1)
Answer to both bonus questions 2 and 3:
=COUNTIF(A1:An,A1)=COUNT(A1:An)
answer to all questions:
={IF(ISERROR(MATCH(FALSE,((A1:An)=$A$1),0)),"same","different")}
this works with numeric, non-numeric, and blanks:
COUNT will not count numeric
COUNTA will count blanks as one
=SUMPRODUCT(1/COUNTIF(B1:J1,B1:J1))
This will tell you how many unique values exist in the selected range. Text or numeric mixed.
{=IF(AND(A1:A9=A2:A10),"EQUAL","NOT EQUAL")}
this is an array formula, insert it with CSE.
COUNTA/UNIQUE
=SUMPRODUCT(A:A)/A1=COUNT(A:A)
=COUNTIF(A1:A4,A1) = COUNTA(A1:A4)