Undocumented, Unloved and Unused Excel Functions
Following on from Chandoo’s MLookup function published on 1st April 2011, I thought it might be worth documenting a few undocumented, no-longer documented and rarely used Excel functions.
Although some of the functions below aren’t documented they still work as of Excel 2010.
Users should be cautious with their use going forward as Microsoft may withdraw them from future versions of Excel.
But if you see them appear in older Excel models at least you’ll be the full bottle.
This post will look at the following functions:
- Datedif
- Roundup
- RoundDown
- Evaluate
- Convert
- Roman
- FactDouble
- Bahttext
Worked examples of all these functions are presented in the Example File which is compatible with all versions of Excel.
Datedif
The DATEDIF function computes the difference between two dates in a variety of different intervals, such number of years, months, or days.
This function is available in all versions of Excel since at least version 5/95, but is documented in the help file only for Excel 2000.
By the way, do not confuse the DATEDIF worksheet function with the VBA DateDiff function.
Use:
=DATEDIF(Start Date, End Date, Interval)
Where:
Start Date must be less than the End Date.
Interval is the interval type to return.
Interval value must be one of the following:
| Interval | Meaning | Description |
| m | Months | Complete calendar months between the dates. |
| d | Days | Number of days between the dates. |
| y | Years | Complete calendar years between the dates. |
| ym | Months Excluding Years | Complete calendar months between the dates as if they were of the same year. |
| yd | Days Excluding Years | Complete calendar days between the dates as if they were of the same year. |
| md | Days Excluding Years And Months | Complete calendar days between the dates as if they were of the same month and same year. |
If you are including the Interval string directly within the formula, you must enclose it in double quotes:
=DATEDIF(Date1,Date2,”m”)
Examples:
| Start Date | 13/01/1963 | ||
| End Date | 12/05/2011 | ||
| Years | =DATEDIF($B$5,$C$5,”Y”) | 48 | |
| Months | =DATEDIF($B$5,$C$5,”M”) | 579 | |
| Days | =DATEDIF($B$5,$C$5,”D”) | 17651 | |
| Months Exc. Years | =DATEDIF($B$5,$C$5,”ym”) | 3 | |
| Days Exc. Years | =DATEDIF($B$5,$C$5,”yd”) | 119 | |
| Days Exc. Years & Months | =DATEDIF($B$5,$C$5,”mD”) | 29 | |
| Start Date > End Date | =DATEDIF($D$5,$D$4,”Y”) | #NUM! | |
Use of the Datedif function on Chandoo.org:
Datedif has been used a number of times at Chandoo.org
http://chandoo.org/forums/topic/how-to-calculate-age-from-their-dob
http://chandoo.org/wp/2009/09/22/elapsed-time-excel/
http://chandoo.org/wp/2008/08/26/date-time-tips-ms-excel/
Disclaimer:
Although the Datedif function above isn’t documented it still works as of Excel 2010. Users should be cautious with their use going forward as Microsoft may withdraw support for them in future Excel versions.
ROUNDUP() and ROUNDDOWN()
The Roundup and Rounddown functions rounds a number up or down, away from zero and have pretty much been replaced by the Round function.
Use:
The Roundup function rounds a number up, away from zero.
=ROUNDUP(number, num_digits)
The Rounddown function rounds a number down, towards zero.
=ROUNDDOWN(number, num_digits)
Roundup() behaves similarly to the Round() function, except that it always rounds a number up based on the following rules:
- If num_digits is greater than 0, then number is rounded up to the specified number of decimal places.
- If num_digits is 0 or omitted, then number is rounded up to the nearest integer.
- If num_digits is less than 0, then number is rounded up to the left of the decimal point.
Examples:
ROUNDUP(4.1,0) equals 5
ROUNDUP(106.9,0) equals 107
ROUNDUP(3.14159, 3) equals 3.142
ROUNDUP(-3.14159, 1) equals -3.2
ROUNDUP(31415.926, -2) equals 31500
Rounddown() behaves similarly to the Round() function, except that it always rounds a number down based on the following rules:
- If num_digits is greater than 0, then number is rounded down to the specified number of decimal places.
- If num_digits is 0 or omitted, then number is rounded down to the nearest integer.
- If num_digits is less than 0, then number is rounded down to the left of the decimal point.
Examples:
ROUNDDOWN(4.1, 0) equals 4
ROUNDDOWN(106.9,0) equals 106
ROUNDDOWN(3.14159, 3) equals 3.141
ROUNDDOWN(-3.14159, 1) equals -3.1
ROUNDDOWN(31415.92654, -2) equals 31400
Use on the Roundup and Rounddown functions on Chandoo.org:
The Roundup and Rounddown functions have been used several times at Chandoo.org
Roundup
http://chandoo.org/wp/2010/04/29/quarterly-totals-from-monthly-data/
http://chandoo.org/wp/2010/04/30/quarterly-totals-multi-year-data/
Rounddown
http://chandoo.org/wp/2010/04/30/quarterly-totals-multi-year-data/
http://chandoo.org/wp/2009/07/06/excel-formulas-round-sort/
Evaluate
Evaluate is an Excel ver 4.0 macro function which is still supported and functional in Excel 2010.
The Evaluate function allows for the evaluation of a text equation as an algebraic equation.
The evaluate function cannot be used as a spreadsheet function but can be used in Named Ranges.
It is probably best described by example; Evaluate 1, from the Example File.
Example:
Say you have a polynomial equation in a cell as Text A1: ‘=X2 + 5*Y – Z
Setup 3 named ranges, X, Y , Z with values X=10, Y=5 and Z=3
You can use Evaluate in a a Named Range eg: Result =Evaluate(SheetName!$A$1)
And then on a worksheet =Result, which will return the answer 122 = 102 + 5*5 – 3
Evaluate can be used to allow graphing of equations without use of worksheet functions or even worksheet ranges, an example of each is shown in the examples file as Evaluate 2 and Evaluate 3 .
Evaluate 2: Uses a Range as the X Values and a Named Range using the Evaluate function as the calculated Y Values
Evaluate 3: Uses Named Ranges as the X Values and as the calculated Y Values based on an Evaluate function
Use of the Evaluate function on Chandoo.org:
Not Used
Convert
Converts a number from one measurement system to another.
For example, CONVERT can translate a table of distances in Kilometres to a table of distances in Miles.
Convert includes 49 units spread amongst the following 10 categories
| Category | No Units |
| Weights & Mass, | 5 |
| Time | 5 |
| Force | 3 |
| Power | 2 |
| Temperature | 3 |
| Distance | 8 |
| Pressure | 3 |
| Energy | 9 |
| Magnetism | 2 |
| Liquid Measures | 9 |
Use:
=Convert(number, From Unit, To Unit)
A list of all the Conversion Units and Conversion Prefixes is included on the Conversion Factors tab of the Examples File.
Examples:
| Example | Result | Description (Result) |
| =CONVERT(5, “lbm”, “kg”) | 2.27 | Converts a 5 pound mass to kilograms (2.267) |
| =CONVERT(80, “F”, “C”) | 6.67 | Converts 80 degrees Fahrenheit to Celsius (26.6) |
| =CONVERT(1, “ft”, “kg”) | #N/A | Data types are not the same so an error is returned (#N/A) |
| ‘=CONVERT(CONVERT(100,”ft”,”m”),”ft”,”m”) | 9.29 | Converts 100 square feet into square meters (9.290304). |
A list of all the Conversion Units and Conversion Prefixes is included on the Conversion Factors tab of the Examples File.
Use of the Convert function on Chandoo.org
http://chandoo.org/forums/topic/convert-function
Roman
The Roman function converts a number to Roman format.
Use:
=ROMAN(number, form)
=ROMAN(45 ) = XLV
Form is a number specifying the type of roman numeral you want. The roman numeral style ranges from Classic to Simplified, becoming more concise as the value of form increases.
| Form | Type |
| 0 or omitted | Classic. |
| 1 | More concise. See example below. |
| 2 | More concise. See example below. |
| 3 | More concise. See example below. |
| 4 | Simplified. |
| TRUE | Classic. |
| FALSE | Simplified. |
Example:
| Example | Formula | Description (Result) | |
| =ROMAN(2011) | MMXI | Converts 2011 to Roman (MMXI) | |
| =ROMAN(499,0) | Classic or Omited | CDXCIX | Converts 499 to Roman (CDXCIX) |
| =ROMAN(499, True) | Classic | CDXCIX | Converts 499 to Roman (CDXCIX) |
| =ROMAN(499,1) | More Concise | LDVLIV | Converts 499 to Roman (LDVLIV) |
| =ROMAN(499,2) | More Concise | XDIX | Converts 499 to Roman (XDIX) |
| =ROMAN(499,3) | More Concise | VDIV | Converts 499 to Roman (VDIV) |
| =ROMAN(499,4) | Simplified | ID | Converts 499 to Roman (ID) |
| =ROMAN(499, False) | Simplified | ID | Converts 499 to Roman (ID) |
Use of the Roman function on Chandoo.org:
Nil
Factdouble
Factdouble returns the double factorial of a number and is expressed in mathematics as n!!
Double factorials are used in probability theory and other higher levels of mathematics and is really just a way to simplify an otherwise complex expression
If the number is Even Factdouble = n(n-2)(n-4)…(4)(2)
If the number is Odd Factdouble = n(n-2)(n-4)…(3)(1)
So it is simpler to write 10!! than 10x8x6x4x2
Use:
=Factdouble( number )
Example:
| Example | Result | Description (Result) |
| =Factdouble(8) | 384 | Factdouble of 8 = 8x6x4x2 = 384 |
| =Factdouble(9) | 945 | Factdouble of 9 = 9x7x5x3x1 = 945 |
Use of the Factdouble function on Chandoo.org
Not used
Bahttext
Converts a number to Thai Text represention of the number
Use:
=Battext( Number)
Example:
=Bahttext(250) , Returns 
Use of the Bahttext function on Chandoo.org:
Not used
Examples
An example file with worked examples from all the above functions is available from the following link; Example File
The file is compatible with all Excel versions.
What Functions Have You Discovered?
What Functions Have You Stumbled Onto?
Let us know in the comments below:
129 Responses to “Write a formula to check few cells have same value [homework]”
=NOT(STDEV(A1:A4))
this also works for large ranges of numerical values (but not for text)
@Arie
Nice formula Arie
Except that it doesn't work for Text values
I'll submit
=COUNTIF(A1:A4,A1)=COUNTA(A1:A4)
which works for Numbers and Text
and answers the two bonus questions as well
This is waaay more elegant than my solution. Nice one :).
I had =NOT(COUNTIF(A1:A4,A1:A4)-COUNTA(A1:A4)), somehow I keep forgetting we can use more than one "=" sign on a given formula :-/
Hi
Works for numbers, text and logical values on a range from A1:An.
=COUNTIF(A1:An,A1)=ROWS(A1:An)
well if you name the range, you could use following:
=IF(SUMPRODUCT(1/COUNTIF('range','range'))=1,1,0)
Hello lockdalf
The IF()-part is not necessary.
=SUMPRODUCT(1/COUNTIF(‘range’,'range’))=1
Not Working for =IF(SUM($C$1:$F$1)=0,"",SUM($C$1:$F$1)) in cell A1 to A4
My solution is a, perhaphs slightly complex, array formula as follows:
{=IFERROR(AVERAGE(IF(ISBLANK(A1:H1),9999,SUBSTITUTE(A1:H1,A1,9999)*1))=9999,FALSE)}
Assuming there is a value (numerical, text, logic etc) in cell A1, this formula will work - and it will 'ignore' any cells that are 'blank' within the range A1:H1 (which can be extended to the required size).
Breaking the formula down, the SUBSTITUTE(A1:H1,A1,9999) replaces all values (be it text / numerical) in the range A1:H1 that MATCH the value of cell A1 with the number 9999 (this should be changed to any number that WON'T APPEAR IN THE RANGE).
These values are then multiplied by 1 (as SUBSTITUTE results in a text answer).
Wrapping this in an IF(ISBLANK(A1:H1),9999,.........) formula takes care of any blank cells, setting them to this default value of 9999 also - this allows you to set the formula up once for a large range and then not have to alter as more data comes in.
An Average is then taken of all these values - if all cells that contain values are the same, the average will come back to 9999.
If all values are numerical but some differ, the average will differ from 9999 and will result in a FALSE answer. If some / all of the values are text and some differ from that in cell A1, the AVERAGE function will result in an Error, but in these instances the Match needs to return FALSE, hence the IFERROR function.
Sure there's a simpler way to do this though!!
`{=IF(AND(COUNTA(RANGE)-SUM(--ISNUMBER(FIND(UPPER(FIRST ELEMENT IN RANGE),UPPER(RANGE))))=0,LEN(FIRST ELEMENT IN RANGE)=MAX(LEN(RANGE))),TRUE,FALSE)}`
so if your data was in Column 1 and began in A1, you'd use
`{=IF(AND(COUNTA($1:$1)-SUM(--ISNUMBER(FIND(UPPER($A$1),UPPER($1:$1))))=0,LEN($A$1)=MAX(LEN($1:$1))),TRUE,FALSE)}`
This will work for strings and things, if you want it to be case sensitive (I don't), just remove the UPPER() part.
What this does:
`COUNTA($1:$1)`
tells you how many entries you're looking at over your range (so we can work with an undetermined size).
`--ISNUMBER()`
ISNUMBER will return TRUE or FALSE depending on if the value inside is a number or not. the -- part converts TRUE/FALSE in to 1 or 0.
`UPPER()` OPTIONAL
converts the value in to upper case. If passed a number it changes it to text format. This is what stops it from being case sensitive.
`FIND($A$1,$1:$1)`
will return a number if A1 is contained in each cell containing an entry in column 1.
`LEN($A$1)=MAX(LEN($1:$1)`
checks that all elements are the same length. This is needed to avoid partial matches (without it, if A1 contained zzz and A2 contained azzza it would flag as true).
REMEMBER this is an array formula, so enter with ctrl+shift+enter.
{=MIN(--(A1=OFFSET(A1,,,COUNTA(A1:A4))))}
Gives 0 if false and 1 if true
=COUNTIF(A:A,A1)/COUNTA(A:A) = 1
This meets both bonus requirements and is dynamic. Keep adding more contents in column A and it will include these automatically.
I like this a one a lot. I would make one small change by inserting a table for my data range. Makes it dynamic without selecting the whole column
=IF(COUNTIF(tableName[colName],A2)/COUNTA(tableName[colName])=1,TRUE,FALSE)
For only Numeric values
=MAX(A:A)=MIN(A:A)
Awesome!
=(A1=B1)*(B1=C1)*(C1=D1)
Case sensitive.
=SUMPRODUCT(0+EXACT(A1:A4,A1))=COUNTA(A1:A4)
Regards
I'd use this
=COUNTIF(range,INDEX(range,MODE(MATCH(range,range,0))))=COUNTA(range)
It takes Hui's formula but ensures that the test value for the countif is the value or string that is most common in the range. Just in case you get a false but the problem is just with your test value being the odd one out.
=SE(E(A1=A2;A1=A3);SE(E(A1=A4;A2=A3);SE(E(A2=A4;A3=A4);"ok")))
SE = IF
E = AND
Seems you could shorten it with
=AND(A1=A2,A1=A3,A1=A4)
Bonus question 1 & 2
Array formula: {AND(A1=A1:AN)}
This will test all cells in range, including text and numbers.
Cheers
A very simple solution uses Excel's Rank function. Insert in B1 = Rank(A1, $A$1:$A$4). Copy down this formula to B4. If the answers in B1 thru B4 are all 1, the values are equal. For an open range of cells, label the range of input (example "TestData") and place the label in the funtion (= Rank(A1, TestData) then copy down to an equivelent length of rows as the range.
=IF(SUM(A1:A4)/COUNT(A1:A4)=A1,TRUE,FALSE)
=IF(SUM(A1:D1)/4=A1,"True","False")
I enjoy your emails. I have learned a lot from them. Thank you for what you do.
.
{=PRODUCT(--(A1=A1:A4))}
.
Change A4 to An.
Greate
{=PRODUCT(- -(A1=A1:A4))}
=IF((SUM(A1:A4)/COUNT(A1:A4))=A1,"TRUE","FALSE")
I would use the formula which is mentioned below:-
=IF(PRODUCT($A:$A)=A1^(COUNTIF($A:$A,A1)),"Yes","No")
At last a homework assignment that I could answer on my own. And I even understand some of the elegant answers from other readers this time.
My solution was to nest IF statements:
=IF(A4=A3,IF(A3=A2,IF(A2=A1,TRUE,FALSE),FALSE),FALSE)
This satisfies bonus question 2 but I think the structure makes it impossible to modify this solution to satisfy bonus question 1. And I wouldn't want to use this strategy to compare very many values...
This answers all of your questions:
=PRODUCT(--(INDIRECT("$A$1:$A$"&$B$1)=$A$1))
where column A contains the values and $B$1 has the number of rows to assign to last A-cell.
Sorry, forgot the braces:
{=PRODUCT(–(INDIRECT(“$A$1:$A$”&$B$1)=$A$1))}
=IF(A1=A2:A2=A3:A3=A4>1,"TRUE","FALSE")
=IF(A1=A2:A2=A3:A3=An>1,"TRUE","FALSE")
=SUM(HELLO, A1)
{=IF(SUM(IF(A1:A4=A1,0,1))=0,TRUE,FALSE)}
This will work for numbers or text, and will work for any number of cells (A4 would just be An)
Here's another alternate, assuming values in cells a1:d1
=IF((A1*B1*C1*D1)^(1/COUNT(A1:D1))=AVERAGE(A1:D1),1,0)
{=IF(AND($A$1:$A$4=OFFSET(A1,0,0)),1,0)}
=SUM(IF(FREQUENCY(MATCH(A1:A4,A1:A4,0),MATCH(A1:A4,A1:A4,0))>0,1))
REVISED FORMULA
=IF((A1=A2)*AND(A1=A3)*AND(A1=A4),"TRUE","FALSE")
Regards
=IF(SUMPRODUCT(--(A2:A5=A2))/COUNTA(A2:A5)=1,1,0)
- should be --
I would use something like this: =COUNTA(A1:A4)=COUNTIF(A1:A4,A1)
You can even do a whole range and as you enter data into the range it tells you if they all match. Going down to row 5000: =COUNTA(A1:A5000)=COUNTIF(A1:A5000,A1).
Thanks,
B
Just saw Hui response. I really did come up with this and didn't just copy his.
{=SUM(--(A1:A101=A1))=(COUNTA(A1:A10)+COUNTBLANK(A1:A10))}
For numeric values:
=(OFFSET(list,,,1,1)=AVERAGE(list))
where list = A1:A4
I need to retract my own post here guys.
It is WRONG! Let me explain.
Suppose we have
A1 = 1
A2 = 0
A3 = 2
then Average = 1 and OFFSET(list,,,1,1) = 1
so 1 = 1 but all the elements are NOT equal.
correction
{=SUM(--(A1:A10=A1))=(COUNTA(A1:A10)+COUNTBLANK(A1:A10))}
=IF(A1=B1,IF(B1=C1,IF(C1=D1,TRUE,FALSE),FALSE),FALSE) ....
=COUNTIF(OFFSET($A$1,0,0,COUNTA($A:$A),1),$A$1)=ROWS(OFFSET($A$1,0,0,COUNTA($A:$A),1))
I have a little more flexible approach. Suppose the value of 'n' is known. There is a possibility that only some of the cells in a row are filled up. For example if n = 10, then in a row, A1 to A10 must be compared. But in case only cells upto A7 are filled up. The formula thus has to adapt accordingly. Below formula does that:
=COUNTIF(INDIRECT(ADDRESS(ROW(),1)&":"&ADDRESS(ROW(),COUNTA(A1:J1))),A1)=COUNTA(INDIRECT(ADDRESS(ROW(),1)&":"&ADDRESS(ROW(),COUNTA(A1:J1))))
In A1:A100 is word/number
In B1 is word/number we look
C1=MAX(FREQUENCY(IF(A1:A100=B1,ROW(A1:A100)),IF(A1:A100<>B1,ROW(A1:A100)))) array formula
We can use an array formula
{=PRODUCT(--(A1:An=A1))}
OR if we want n variable
{=PRODUCT(--(INDIRECT("A1:A"&COUNTA(A:A))=A1))}
Just as an add on...
The range could be 2D as well
{=PRODUCT(–(A1:Zn=A1))}
{=AND(A1=A2:An)}
I would use this one (simlpe)
=(COUNTA(A:A)=COUNTIF(A:A;A1))
try this
=MAX(A1:A4)=MIN(A1:A4)
Olso try this
{=SUM(RANK(A1:A10,A1:A10))=COUNT(A1:A10)}
Please notice it is an Array Formula
Dear All,
i used that formula
{=IF(COUNTIF(A1:A4,A1:A4)=COUNTA(A1:A4),TRUE,FALSE)}
Love the variety of responses.
=MAX(A1:A4)=MIN(A1:A4)
and
=COUNTA(A1:A4)=COUNTIF(A1:A4,A1)
will return true if the input range has blank cells
My personal fave is the array formula {=AND(A1=A1:A4)}. Short and sweet, and easy to read. Blank cells will tally as a mismatch.
A close second is
=SUMPRODUCT(1/COUNTIF(A1:A4,A1:A4))=1
which will throw an error if blanks are present.
=PRODUCT(B1:D1)=B1^COUNT(B1:D1)...will return TRUE or FALSE
Dear Sir,
My answer is =exact(a2,a1)
=IF((a1=a2=a3=a4),1,0)
4 equal values gives me a 0 ???
Hello Chandoo,
We can also use Conditional Formatting......
For Numerics..
=SUM(A1:AN)/A1=COUNT(A1:AN)
results in True/False.
=AND(IF(A1=B1,1,0),IF(B1=C1,1,0),IF(C1=D1,1,0))
=AND(A1=A2:A4) array entered
Generic
=AND(A1=A2:An) array entered
=--(COUNTIF(A1:A4,A1)=COUNTA(A1:A4))
will give value as 1 or 0
Hi there, here's a simple formula to determine not only whether all 4 cells (A1 --> A4) are equal, but also whether any of the cells are equal and identifies which cells they are ...
=COUNTIF($A$1:$A$4,A$1)*1000+COUNTIF($A$1:$A$4,A$2)*100+COUNTIF($A$1:$A$4,A$3)*10+COUNTIF($A$1:$A$4,A$4)*1
A result of 1111 means no cells are equal, 4444 means all cells are equal, 1212 would mean there are 2 cells the same & they are in A2 & A4, etc
=((A1=B1)+(A1=C1)+(A1=D1))=3
Obviously doesn't cover bonus question 1, but does so for q2 🙂
If formula
=MIN(A1:A4)=MAX(A1:A4)
Try this formula
=IF(COUNTIF(A1:A4,A1)-ROWS(A1:A4)=0,"True","Flase")
I used the Swiss knife of excel: SUMPRODUCT, works for numeric as well as for non-numeric cell content and A1:A4 is obviously easily changed to any range.
=IF(SUMPRODUCT(--(OFFSET($A$1:$A$4,0,0,ROWS($A$1:$A$4)-1,1)=OFFSET($A$1:$A$4,1,0,ROWS($A$1:$A$4)-1,1)))=ROWS($A$1:$A$4)-1,TRUE(),FALSE())
All of the individual non-array formulas (didn't test the array ones) have one flaw or another - mostly specifically if all the columns are blank, the result would still be false.
Another formula in the comments worked for these but didn't work for when all columns had "0.00" in them. My solution was to OR the two. If H3 through H149 have your values, then this is what worked for me:
=IF(OR(COUNTIF(H3:H149,H3)=COUNTA(H3:H149),SUMIFS(H3:H149,H3:H149,1)=COUNT(H3:H149)),IF(H3="","Blank",H3),"")
This solution puts "Blank" if all the rows are blank, otherwise, it puts whatever the value that's in all of the rows - "0.00" or whatever.
Thanks for all the answers!
I used a nested if statement which also showed, via the false message, the first instance of cells which were not equal for the cells a1 to a5.
=IF(A1=A2, IF(A2=A3, IF(A3=A4, IF(A4 = A5, "True","False A4"), "False A3"), "False A2"))
Hi,
First, let me begin by saying, I am a big fan of all your posts and read your emails, mostly on the same day as you send them. I have not replied as much as I wanted to.
This is my first attempt at answering a question on your post
I came up with a simple check which will test if all values in a range A1:An are same or not
Assuming range you want to check is A1:A10,
In Cell B1, insert the formula
=IF(COUNTIFS(A1:A10,A1)=COUNTA(A1:A10),"All cells are same","All cells are not same")
The idea I applied is counting total number of non-blank cells and then counting the number of cells which match cell A1. If these are same, then it means
a) all cells have the same value! (All can be blank, then both counts will be zero)
I am working on finding the range automatically 🙂
Can extend this into VBA and use InputBox etc to generate some user interaction
Thanks
Shailesh
=IF(COUNTIF(A1:A4,A1)=COUNT(A1:A4),TRUE,FALSE)
For homework & Bonus Question 3
=IF(AND(A1=A2,A2=A3,A3=A4),1,0)
=IF(SUMIFS(A12:A15,A12:A15,1)=COUNT(A12:A15),1,0)
One possible solution could be =+IF(COUNTIF(A1:A4,A1)-COUNT(A1:A4)=0,1,0)
where A1:A4 is data range which can be a dynamic range and the formula can be modified accordingly.
Rgds,
Sanjeev Sawal
I got the right result with this one:
=IF(A1=B1;IF(C1=D1;IF(B1=C1;1;0);0);0)
=and(a1=a2,a1=a2,a1=a3)
ANSWER FOR bONUS 1
=MAX(A1:A10)-MIN(A1:A10)
=AND(A1:A3=A2:A4)..Confirm with Ctrl+Shift+Enter (As as array formula). Works well for Text values and large range of values as well.
suppose cells contain 2 values ==== Yes | no
formula :
1
=counta(a1:a4)=countif(a1:a4,"yes")
It will return True or False.
2
=IF((COUNTA(A1:A4)=COUNTIF(A1:A4,"yes")),"Same value","Mis-match")
it will return Same Value OR Mis-match.
Hope you like it.
Regards
Istiyak
Also can use this formula
=IF(AND(A1=A2,A1=A3,A1=A4),"1","0")
Let say the values are in the range $B$1:$E$1, then the formula is:
If(sumproduct(--($B$1:$E$1=$B$1))=CountA($B$1:$E$1);1;0)
Please check that:
* $B$1 was used as pivot value and could be randomly selected
* It works well if parenthesis is omitted for values "1" and "0"
* This formula applies also to "n-values" and non-numeric values (text, logical, etc.)
Regards,
A
This formula is equivalent to
If(CountIF($B$1:$E$1,$B$1)=CountA($B$1:$E$1),1,0) mentioned before...
Hi, first time trying to solve a probleme.
New at this but really enjoying Chardoo.org
Think the following will work in all 3 questions
{=IF(SUM(IF(A1=$A:$A,1,0))=COUNTA($A:$A),TRUE,FALSE)}
Regards
Jorrie
use below formula for to get True / False
=COUNTA(A1:A4)=COUNT(A1:A4)
and use below formula for to get {1/0} or {match / Mismatch}
=IF(COUNTA(A1:A4)=COUNT(A1:A4),{1,0} or {match,Mismatch})
=IF(COUNTA(A1:A4)=COUNT(A1:A4),1,0) or =IF(COUNTA(A1:A4)=COUNT(A1:A4),"Match","Mismatch")
[...] Last week in Write a formula to check few cells have same value [Homework], [...]
Hi, sorry if it's repeated, this array formula works well with numbers or text, the range can easily be dynamic: {=AND(A1:An=A1)} Now, after three days, I understand a lot more about array formulae, thanks?
=IF(AND(A1=A2,A2=A3,A3=A4),"TRUE","FALSE")
What if there are not only four cells to compare but An?
how will I determine if there is one cell that is not equal from any other cells?
=IF(COUNTA(A1:A4)=COUNT(A1:A4),1,0)
=IF(COUNTA(A1:A4)=COUNT(A1:A4),”Match”,”Mismatch”)+
=IF(AND(A1=A2,A2=A3,A3=A4),”TRUE”,”FALSE”)
=iF(AND(EXACT(C15,D15),EXACT(E15,F15)),"Match","Mis-match")
how this formula works in excel (B4+E4)/50*20
I'm a little late to the party, but I figured I'd post anyways.
For numbers only:
=NOT(VAR.P(A1:An))
The formula given below will fulfill the all criteria including bonus questions
=IF(COUNTA(A:A)=COUNTIF(A:A,A1),"True","False")
REGARDS
=IF(MATCH(A1,A2:A4,0),TRUE,FALSE)
=IF(COUNTIF($A$1:$A$4,A1)>1,"true","false")
=IF(COUNTIF(A:A,A1)>1,"true","false")
@Naveen
You can simplify your formulas as below:
=COUNTIF($A$1:$A$4,A1)>1
=COUNTIF(A:A,A1)>1
Excel will return True or False without the need for the If() function
Hi ,
This question is similar to the one in the post.
I have Text values in cell A1 and A2.
If A1 = A2, update 10 in cell A3 , else 0.
Is there any formula for this. I am new to VB and hence do not have much knowledge. Eager to learn!!
Thanks in advance !!!
=AND(A1=A2,A1=A3,A1=A4)
also =IF(AND(A1:A4=A1),TRUE,FALSE)
my question is
finding the total of values in cell A1,A2,A3,A4,andA5
@Norine
Is it as simple as =Sum(A1:A5)
One can use "IF, AND" formula.
=IF(AND(A1=A2,A2=A3,A3=A1),"True","False")
=COUNTIF(A:A,A1)=COUNTA(A:A)
Enter array formula like, = IF($B$16:$B$21=$B$17:$B$22,"Yes","No")
Sorry, Enter a array formula like this: =IF(AND($B$16:$B$21=$B$17:$B$22),"Yes","No")
=IF(AND($E$5=$E$6,$E$6=$E$7,$E$7=$E$8),"true","flase")
it can work try this one
A question for you
sheet 1 table A1:C10
What formula in sheet 2 A1 will give me what is entered in the table sheet 1 A1:C10
There is usually only one entry made in the table but if you can supply the answer to 1 or 2 entries I would be grateful
=max(A:A)=min(A:A)
FOR TEXT DATA
=COUNTIF(A1:A5,a1)=COUNTIF(A1:A5,"*?")
FOR VALUE DATA
=COUNTIF(A1:A5,A1)=COUNTA(A1:A5)
Both Return TRUE or FALSE
=if({sum(1/countif($A$1:$A$n,A1:An)}=1,"All Same","Not All Same")
I use formula A1=B1 and get value of TRUE / FALSE in C1. I had dragged this formula for 10 rows. Now in cell D2 i tried to put formula..
=if(and(c1="False", c2="true"), "conflict", "no conflict")
but even when the condition is true i am still getting no conflict.
Can you please advice?
thanks,
Manish
@Manish
Remove the " from around True and False
=if(and(c1=False, c2=True), "conflict", "no conflict")
In C1 and C2 you have a Boolean expression and it evaluates as True/False
These are not text, although they do appear as Text, they are not 1/0 although they sometimes behave as 1/0, they are in fact Boolean values True/False
So in your example you can simplify it as
=If( And( Not(C1), C2), "conflict", "no conflict")
=SUMPRODUCT(MATCH(A1:A4,A1:A4,0))=COUNTIF(A1:A4,A1)
Answer to both bonus questions 2 and 3:
=COUNTIF(A1:An,A1)=COUNT(A1:An)
answer to all questions:
={IF(ISERROR(MATCH(FALSE,((A1:An)=$A$1),0)),"same","different")}
this works with numeric, non-numeric, and blanks:
COUNT will not count numeric
COUNTA will count blanks as one
=SUMPRODUCT(1/COUNTIF(B1:J1,B1:J1))
This will tell you how many unique values exist in the selected range. Text or numeric mixed.
{=IF(AND(A1:A9=A2:A10),"EQUAL","NOT EQUAL")}
this is an array formula, insert it with CSE.
COUNTA/UNIQUE
=SUMPRODUCT(A:A)/A1=COUNT(A:A)
=COUNTIF(A1:A4,A1) = COUNTA(A1:A4)