A few weeks back in the Chandoo.org Forum Melvin asked about Apportioning Sales based on Division and Status to the current sales by store.
Today we will examine how this works and how to develop a solution for the problem.
Apportion/ing
Apportion means to assign or distribute.
In a court the Judge may apportion blame for an accident eg: 50% to the driver, 30% to mechanical failure and 20% to the road conditions, The Judge is assigning or distributing the blame as he deams appropriate.
This is what Melvin wanted to do with his sales. He wanted the sales distributed according to Division and Status based on the current sale by store.
Lets start simple and look at how we can distribute sales on a simple model first.
Let say we have a Distributorship and we buy and sell oranges.
We buy oranges from a supplier and distribute them to 3 stores, Store A, Store B & Store C
We received 1,000 oranges and they were sold as follows
We can see that each store received differing percentages of the original supply:
50% = 500/1000
30% = 300/1000
etc
A week later the supplier give us another 200 oranges and we want to distribute them based on the previous sales
So the new batch of 200 oranges will be distributed according to these previous percentages
100 = 200 x 50%
60 = 200 x 30%
etc
That is as simple and as complicated as apportioning is.
Melvin’s Problem
When we look at Melvin’s problem he has a more complex set of data
You can follow along using a sample file: Download Sample File
We can see that Melvin has 14 stores located in 4 Divisions (N, S, W & C) and each can have a status of Open or Open1
But if we simplify this and look at one set of data we can devise a formula which will adjust to each set of data
Lets develop a formula for cell F11 which is dealing with Store 1 in the N Division and has a Status of Open
We see it has sales of 100 (Cell E11)
Total sales of Division N and status Open are 600 (100+100+100+150+150) highlighted below (Lower table)
Looking at the Upper Table we can see that we need to distribute 200 units based on the Division N and Status Open (Cell C4)
So we need to distribute 200 units across the 5 stores with Total sales of 600
We know that Store 1. had sales of 100 in cell E11
The Total Sales of Stores in Division N and Status Open can be obtained using a Sumifs function
=SUMIFS($E$11:$E$24, C11:$C$24, $C$11, $D$11:$D$24, D11)
=600
So the proportion of Store 1’s sales 100 to Total Sales ( Division N and Status Open ) 600 is 100/600 = 16.66%
This is calculated by
=E11/SUMIFS($E$11:$E$24, $C$11:$C$24, C11, $D$11:$D$24, D11)
=0.1667
=16.67%
Note: We leave the references to C11, D11 & E11 variable, so that when the formula is copied down it will refer to the next row
We can use an index/match formula to get the 200 based on the criteria from row 11
=INDEX($C$4:$D$7, MATCH(D11,$B$4:$B$7,0), MATCH(C11,$C$3:$D$3,0))
What this is doing is doing a 2D Lookup in the Range $C$4:$D$7
It is looking up the Division Row no. MATCH(D11,$B$4:$B$7,0)
and looking in the Status Column No. MATCH(C11,$C$3:$D$3,0)
Note: Once again we leave the references to C11 & D11 variable, so that when the formula is copied down it will refer to the next row
So the proportion of the 200 sales attributable to Store 1 is:
=Distribution Qty * Actual Sales / Total Sales
=INDEX($C$4:$D$7, MATCH(D11, $B$4:$B$7, 0), MATCH(C11, $C$3:$D$3, 0)) * E11 / SUMIFS($E$11:$E$24, $C$11:$C$24, C11, $D$11:$D$24, D11)
= 33.33
We can now copy this down to all the cells matching our criteria of Division N and Status Open
Notice that the total matches the total to be distributed 200 showing that the formula is working
Although we copied the formula down to the cells that had matching criteria each part of the formula was setup to work on the appropriate criteria for the store in the current row
If we now copy F11 down to the other stores you will see that in fact all the stores sales have been apportioned according to the correct criteria.
eg: If we look at Stores 7, 8 & 9 we can see that they are in the W Division and have a Status of Open1
The distributed Proportions are each 16.67, totaling 50, which matches the distribution in the Upper table.
You may also notice that Division C has not been accounted for.
I assume that Melvin has sent us a subset of the data and that is why it is missing.
Download
You can download a copy of the above file and follow along, Download Sample File.
A Challenge
Can you solve the problem another way ?
Post your solutions in the comments below.
Other Posts in this Series
The Formula Forensics Series contains a wealth of useful solutions and information specifically about how Normal Formula and specifically Array Formula work.
You can learn more about how to pull Excel Formulas apart in the following posts: http://chandoo.org/wp/formula-forensics-homepage/
If you have a formula and you want to understand how it works contact Hui and it may be featured in future posts.
15 Responses to “Compare 2 Lists Visually and Highlight Matches”
Hi,
I solved this in a little different way.
We have 2 lists, one starts at A1 and other at B1, both are vertical arrays.
First thing is define 2 named ranges, list1 and list2:
list1 refers to "=OFFSET(Sheet1!$A$1;0;0;SUMPRODUCT(--(Sheet1!$A$1:$A$1000""));1)"
list2 refers to "=OFFSET(Sheet1!$A$1;0;0;SUMPRODUCT(--(Sheet1!$B$1:$B$1000""));1)"
this way lists will be dynamically sized when you had or remove elements (you can't have blanks and you can't have more than 1000 elements).
Then I use conditional formatting in column A when this formula is true:
"=NOT(ISERROR(MATCH(A1;list2;0)))"
and "=NOT(ISERROR(MATCH(B1;list1;0)))" to list2.
This way we eliminate the need for auxiliary columns or lists.
Hope you like my way! 😀
Nunes
Simple conditional formatting formula.
Assuming lists vertical lists starting in A1 & B1
To highlight just one column (assume B for example)
Conditional formatting>New Rule>by formula
=MATCH(B1,$A$1:$A$99,0)
Set the cell fill to what ever color you prefer & press OK
To highlight both columns repeat with this formula for cell in column A
=MATCH(A1,$B$1:$B$99,0)
This approach doesn't require named fields or addtl columns
glw
Say I had 1 list in A2:A20 and another in B2:B20.
To format all the items in column A that are repeated in column B I would use the following Conditional Formatting rule.
=IF(ISNA(VLOOKUP(A2,$B$2:$B$20,1,false)),true,false)
All the duplicates are highlighted. It us a very simple example of comparison.
I may be missing something here, but I usually highlight both my lists by holding ctrl eg A1:A20 E10:E40 then choose conditional formatting from the ribbon and then highlight duplicates, and this does it?
Lee, I was perplexed as well. I do the same thing you do with the conditional formating. A drag and click to highlight range and choose highlight duplicates does the trick for me.
I believe these methods are to check if an item from one list also appears in the other list. So if an item mentioned many times in one list if also mentioned in the other list or not.
The Conditional Formatting highlight duplicates feature will do this, but it will also highlight an item if it appears multiple times in the one column or list.
Hi, I would just like to know (if you are willing to share) which image editing program you use to make your image like above, like they are torn apart from bottom? I've been looking for long.
@i48998
Chandoo is on Holidays, but Chandoo uses Paint.Net
Paint.net is a free download available at http://www.paint.net/
.
I use CorelDraw/PhotoPaint
.
We both use the Snipping Tool (a freebe with Win Vista/10)
.
We both use Camtasia for doing screen captures to make animated GIFs where you see animation.
Here is how I would accomplish
(1) Define Names: List_1, List_2
(2) =ISNA(MATCH(D4,List_2,0))-1 (Conditional Format formula List_1)
(3) =ISNA(MATCH(D4,List_1,0))-1 (Conditional Format formula List_2)
ISNA will return 1 if NO Match and O if Match by adding a -1 will make: NO Match 0 and Match a -1 which is True
Hi all
this my first Post here
i think we can take Unique List for tow list to know what is not Duplicate By this Array formula
=IFERROR(INDEX($D$6:$D$33,SMALL(IF(ISERROR(MATCH($D$6:$D$33,$B$6:$B$33,0)),ROW($D$6:$D$33)-ROW($D$6)+1),ROWS($J$5:J5))),"")
and this one for Duplicate Value
=IFERROR(INDEX($D$6:$D$33,SMALL(IF(ISNUMBER(MATCH($D$6:$D$33,$B$6:$B$33,0)),ROW($D$6:$D$33)-ROW($D$6)+1),ROWS($J$5:J5))),"")
Don't forget to Enter This Formula by Pressing Ctrl+Shift+Enter
without wanting to ruthlessly self promote here, I do have an addin that does neatly compare two ranges, not just in columns, so you might want to check that out.
Having said that this is a pretty neat solution if you dont want to be going down the VBA or purchase route. I like it
however, could you not do something with the remove duplicates feature in Excel 2010 and then compare the resulting data set?
Hi, Chandoo! I've found yesterday your Excel website... What can I say? It's just awesome, Excellent. Being a developer for 30 years, more than 15 with Office products, and wow!, how many things I discovered in a couple of hours, and what pretty resolved.
I decided to take the long path of the newbies and read all your examples and write down by myself all of them, and when I arrived to this (the comparison of two lists) I think I've found a problem:
a) in "Step 4: Apply conditional formatting to Second List - Use the same logic, but this time the rule becomes =COUNTIF(count1s,$H6)" it should say "Step 4: Apply conditional formatting to Second List - Use the same logic, but this time the rule becomes =COUNTIF(count1s,$H6)>0", but this is a typing error that I believe all of us here might have discovered and corrected
b) the very problem: I wrote down two different lists, in different ranges, and with different number of elements, I specified the equivalent conditional formats, et non voilá!, I didn't get what expected. So I downloaded your example book, I checked range names, formulaes, conditional formats and all OK. So I copied -just values- from my book to yours, and I still couldn't achieve the goal.
I'm using Excel 2010 in spanish, I'm from Buenos Aires (Argentina), and my book is at your disposition whenever you considerate it appropiate.
Thanks in advance for your time, and again my congratulations for your work here.
Best regards.
SirJB7
Comparison of 2 lists visually with highlights
Author: SirJB7 / Date: 11-Dic-2011
Pros: no duplicated tables, no matrix formulaes, no named ranges, no VBA code, just conditional formatting
Cons: not found yet, comments and observations welcome
Features:
a) standard problem: highlights in orange/yellow elements existing in the other list
b) optimized problem: idem a) plus highlights in red/violet first occurrence of elements existing in the other list
Sheet contents:
a) conditional format, 1 rule per list (2 methods used)
A1:A20, first list
B1:B20, second list
a1) range A1:A20, condition =NO(ESERROR(BUSCARV(A1;B$1:B$20;1;FALSO))), format Orange ---> in english: =NOT(ISERROR(VLOOKUP(A1,B$1:B$20,1,FALSE)))
a2) range B1:B20, condition =CONTAR.SI(A$1:A$20;B1)>0, format Yellow ---> in english: =COUNTIF(A$1:A$20,B1)>0
b) conditional format, 2 rules per list (2 methods used)
D1:D20, first list
E1:E20, second list
b1) range E1:E20, condition 1 =Y(NO(ESERROR(BUSCARV(D1;E$1:E$20;1;FALSO)));COINCIDIR(D1;D$1:D$20;0)=FILA(D1)), format Red ---> in english: =AND(NOT(ISERROR(VLOOKUP(D1,E$1:E$20,1,FALSE))),MATCH(D1,D$1:D$20,0)=ROW(D1))
same range, condition 2 and format 2, same as a1)
b2) range E1:E20, condition =Y(CONTAR.SI(D$1:D$20;E1)>0;COINCIDIR(E1;E$1:E$20;0)=FILA(E1)), format Violet ---> in english: =AND(COUNTIF(D$1:D$20,E1)>0,MATCH(E1,E$1:E$20,0)=ROW(E1))
same range, condition 2 and format 2, same as a2)
Personally I like the a2) and b2) solutions, I think the formulaes are prettier.
I still don't know the rules of this website and forum, but it any precept is infringed I'm willing to share the workbook with the solution. If it breaks a rule, I apologize and promise that won't happen again.
Best regards for all!
Dear All i have a complicated situation...
1. I have two sheets of data Sheet1 and Sheet2 (from various sources) - Both of these contain data matching and Not matching as well..
2. Now for me i need to build an excel where in i need to get sheet 3 with values that are present in a column of Sheet 1.
What ever Sheet 1 doesn't have i dont want those rows from sheet 2 to be populated into Sheet3.
Can any one help me out.
Hi Team
The above example is to compare partial name from 2 different columns.
If I want to cross check it in a single column. I have both correct and partial correct/match entries in a column. Is there any way I can find both the entries in the column.
Regards