We all know VLOOKUP (or INDEX+MATCH) as an indispensable tool in our Excel toolbox. But what if you want the lookups to be a little gentler, nicer and relaxed?
Let’s say you want to lookup the amount $330.50 against a list of payments. There is no exact match, but if we look 50 cents in either direction, then we can find a match. Here is a demo of what I mean.
Unfortunately, you can’t convince VLOOKUP to act nice.
Hey VLOOKUP, I know you are awesome and all, but can you cut me some slack here?
VLOOKUP is tough, reliable and has a cold heart. Or is it?
In this post, let’s learn how to do lenient lookups.
Data for the problem
Let’s say you have a simple 2 column table like this. Our table is uninspiringly named data.
Lenient lookup – setting up the formula
Our input amount is in cell C3.
Let’s say when looking up for the amount, we want to follow this logic.
- If an exact match is found, return that
- Else, see if we can find anything with in 50 cents either side (you can change 50 to whatever you want)
- If nothing can be found, we want to return “Not found” or similar message
Formulas to use:
1: we can use good old INDEX+MATCH
2: we can use array based INDEX+MATCH
3: we can use IFERROR.
Let’s put everything together.
Our lenient lookup formula (array):
=IFERROR( INDEX(data[Client], IFERROR(MATCH($C$3,data[Amount],0), MATCH(1, (data[Amount]>($C$3-0.5))*(data[Amount]<($C$3+0.5)),0) ))
,"Not found")
How does it work?
Let’s go inside out.
MATCH($C$3,data[Amount],0): this formula simply looks for C3 in data[Amount] column and returns the position.
MATCH(1, (data[Amount]>($C$3-0.5))*(data[Amount]<($C$3+0.5)),0): This array formula checks for 1 (TRUE) by looking at data[Amount] between C3-0.5 and C3+0.5
The formula has two Boolean arrays multiplied and it returns a bunch of 1s & 0s.
MATCH then picks up the first such amount.
Inner IFERROR(MATCH(…), MATCH(…)): This acts like a fail-safe switch. If there is no exact match (first one), then lenient match (second one) will be used.
Outer IFERROR(): If no matches are found (exact or lenient) then “Not found” will be printed.
As this is an array formula, you need to press CTRL+Shift+Enter to get the result.
Related material – read these if you have questions about the formula techniques used above:
Other lenient / almost lookup problems
There are few more variations to this technique. Let’s review them.
Note: all of these are array formulas, so press CTRL+Shift+Enter.
Ignore decimal portion
We lookup just the whole number portion of the value to find match.
Formula: =INDEX(data[Client], MATCH(G7, INT(data[Amount]),0))
Notes on how it works:
- INT() turns data[Amount] column to whole numbers.
- We then lookup the amount (G7) and return the match
Amount is at least something, client name begins with S
Formula: =INDEX(data[Client], MATCH(1, (data[Amount]>=G8)*(LEFT(data[Client],1)=”S”),0))
- We use a different Boolean structure with >= and LEFT() formulas. The output will be a bunch of 1s & 0s.
- INDEX+MATCH for find the first such value (G8)
Closest Amount to input
This is interesting. We use MIN & ABS to find closest amount to input value (G10) and return the client’s name.
Formula: =INDEX(data[Client], MATCH(MIN(ABS(data[Amount]-G10)), ABS(data[Amount]-G10),0))
- ABS(data[Amount]-G10) gives a bunch of absolute (positive) values. The smallest of these will closest to G10.
- MIN() finds the smallest value
- MATCH looks up the minimum value from ABS(data[Amount]-G10)
- INDEX gives corresponding client’s name
Download lenient lookup example workbook
Click here to download the example workbook. The file contains sample data, several examples of these techniques and additional resources to learn. Give it a go.
More ways to lookup
Lookups are an essential part of any data analysis work you do in Excel. Pick up some nifty tricks from these links.
- Basics:
- Advanced:
Got a lookup tip to share?
Have some lookup stories to tell? I am listening. Please post them in comments.
24 Responses to “10 Supercool UI Improvements in Excel 2010”
The best improvement by far is the Collapse Ribbon ^ button !
Kind of a shame that some of the best improvements are actually returns to old functionality. One thing I don't like is that to get to recent files I need to do an extra click after File - apart from Save As, that's why I'm usually in the File menu. I like the sparkline options, though they are still as not fully featured as some of the free and pay options out there.
The collapse button for the ribbon menu is good news. Can you make the ribbon menus stick too?
Nine improvements, not ten. You can also select multiple objects in 2007. Click on the Find & Select item at the far right of the Home tab, and the dropdown looks remarkably like your 2010 screenshot.
@Jon.. Thank you. Dumb me, I somehow thought we couldnt select objects in Excel 2007. Just saw the "select menu" and it is there. I have corrected the post and removed the point. I have added the "you can make your own ribbons" instead. Thanks once again.
@Arti: what do you mean by make ribbons stick?
@Alex: May be it is my installation, but when I go to "File menu" I see "recent files" by default.
For example, if I am working with one of the contextual ribbon menus (Pivot tables, Drawing/Chart etc), as soon as I click away from the selected object, the menu tabs vanish. If I click on the object again immediately, then Excel will remember what I was looking at, but if I wander away and click on a Pivot, then back again on the Chart, the menus will 'appear' but not get activated, thereby causing much annoyance and additional clicking.
I want to "pin" the whole menu (not invididual commands) somehow, so that I can have the menu there for the length of the time I am working with graphics. Excel 2003 used to have the Drawing toolbar you could detach and hover while you were working, but this functionality disappeared in Excel 2007.
My thought was Excel should just allow a 'pin', similar to the Recently Opened files menu, for the Ribbon Menus as well. If I have not selected any Drawing object, the commands can be greyed out, but I want the menu as a whole to 'stick'.
@Arti... I think MS solved this problem differently. When I select a pivot and go to "design" tab Excel 2010 remembers this and automatically takes me to "design" tab when I reselect the pivot.
Apart from this you can also define your own ribbon with all the things you normally do. See the above article (I have added this after Jon's comments)
Nice feature. About time for a upgrade for MS Office
Oh... okay. That might be a start. I'd probably just copy-paste the Drawing tab haha. Thanks. I'll definitely give Excel 2010 a try.
Btw - have you considered getting into / gotten into the world of Excel as it meets SharePoint?
Actually, the replacement new thing is probably better than all the rest. One thing that the designers of the Office 2007 ignored was allowing regular users to customize their own interface. Office 2010's interface was expanded in this way to address the huge uproar.
Is there still a limit on how many things you can add to the QAT bar? (I'm too lazy to look myself.)
@Jeff.. it seems to take quite a few, but only shows one line and gives a little arrow button at the end. (summary: shucks!)
The best thing is you can edit the ribbon directly from excel, so now i can create my own bar with just the things I use regularly!
One of the annoying things in 07 for me is the Add-Ins menu bar - in 03 I could keystroke directly to menu add ins.. In 07 I needed an extra keystroke just to activate the add-in menu, then the keystrokes as normal.. Hope this marek sense..
John -
If you remember the old Excel 2003 Alt-key shortcuts, you can still use them in 2007. To get to the Add-In dialog:
Alt-T-I
Dear Arti & Chandoo
Seen your comments over some issues. Hope you are form India, gone through your comment expecting a pin to command it as a whole, great, hope if someone out of MS have read it, it may be kept in mind while the next R & D of Office Ver. 16
Just incase someone forgot CTRL+F1 will collapse the ribbon.
[...] was pleasantly surprised when I ran Microsoft Excel 2010 for first time. It felt smooth, fast, responsive and looked great on my [...]
I like the sparklines, and the ability to modify the charts
How do you get rid of the advertisment on the right hand side? If you upgrade then will it take off the ads?
Once again Microsoft has re-decorated the Office and we are NOT pleased!
The graphics object selector can be found in the Home ribbon under Find & Select, Select Objects near the bottom of the drop down. You can make it part of the Quick Access toolbar by right click over it and selecting Add to Quick Access toolbar.
The graphics "cursor" will now appear on the mini-toolbar at the top left of the window.
How to get rid of "Add-Ins" button in Backstage (File)" menu by means of XML code, i.e. to hide, to delete or to disable this button?
This button is usually situated in the Backstage menu between "Help" and "Options" buttons.
Vladimir, did you ever get an answer to your question?
I am tying to customize the ribbon UI for a file using XML, and this is precisely the piece I can't figure out. I can hide other tabs, remove items from QAT and backstage - all except the options that are showing up under add-ins in backstage. If there is an XML syntax for referencing this thing and making it invisible, I cannot find it.
Hey, nice tutorial. Please check my video tutorial on similar topic at the below link and provide your comments:
http://www.youtube.com/watch?v=TeIFc0jYjpA