Using Arrays To Update Table Columns

Posted on September 16th, 2013 in Automation , Excel Howtos , VBA Macros - 21 comments

Using Arrays To Update Table Columns

We are creating a lot of reports everyday and these reports contain a lot of data which is presented in various styles as per the requirements. The data that allows us to create the reports is usually referred as raw data and in most of the cases is stored in hidden sheets.

I am sure you all are aware of a feature called as Excel Tables OR Structured References in Excel. Excel Tables is (in my opinion) the best way to store your raw data and put Formulas in the columns where necessary, this way you eliminate the need of a Cell Based Reference formula (example =SUM(B4:B50) and replace them with =sum(YourTable[YourTableColumnName]).

Another good feature of the Excel Tables is you just need to put the formula in 1 cell and it is replicated for that column by Excel.

Sometimes these formulas take a lot of time to calculate when we have really huge data points. In this scenarios it is better to have hard-coded values instead of the formulas to gain on speed.
In this post we will learn about how we can make use of Array’s to quickly populate the excel columns with the desired results before publishing our reports and other documents.

Here is a demo of what I mean:

using-array-to-update-table-columns

Below is the code that allows us to add a new column to our data table and then taking input from the Date Time column provides us with the Week Of column.

Sub UpdateWeek()
Dim myarray As Variant
Dim theRange As Range, startCellRow As Long
Dim tempStr As String
Dim myNewCol As ListColumn

‘If our column already exists then delete it
On Error Resume Next
Worksheets(“Data”).ListObjects(“cs”).ListColumns(“WeekOf”).Delete

‘adding our new column
Set myNewCol = Worksheets(“Data”).ListObjects(“cs”).ListColumns.Add
myNewCol.Name = “WeekOf”

‘Selecting the first cell of the column that contains our dates
Worksheets(“Data”).ListObjects(“cs”).ListColumns(“Date Time”).Range.Cells(2).Select

‘building a temporary Range address, this will be used to upload the entire range into the array

tempStr = ActiveCell.Address
startCellRow = ActiveCell.Row
tempStr = tempStr & “:$” & Mid(Sheets(“Data”).ListObjects(“cs”).ListColumns(“Date Time”).Range.Cells(2).Address, 2, 1) & “$”

tempStr = tempStr & LastRowInOneColumn(Mid(Sheets(“Data”).ListObjects(“cs”).ListColumns(“Date Time”).Range.Cells(2).Address, 2, 1))
‘loading the range into the array

myarray = Range(tempStr).Value

‘Looping through the array and converting each element to the relevant Week format
For i = LBound(myarray) To UBound(myarray)
myarray(i, 1) = Format(myarray(i, 1) – Weekday(myarray(i, 1), vbMonday) + 1, “ddd dd-mmm”)
Next

‘Setting the range address for our output column

Set theRange = Range(Cells(startCellRow, Worksheets(“Data”).ListObjects(“cs”).ListColumns(“WeekOf”).Range.Column), Cells(UBound(myarray) + (startCellRow – 1), Worksheets(“Data”).ListObjects(“cs”).ListColumns(“WeekOf”).Range.Column))
‘storing the values from our array to the WeekOf Column

theRange.Value = myarray
End Sub

Let’s Understand the code

We first delete the column if it is already existing to make sure we always get the new values as output. This is done by the below line of code.

Worksheets("Data").ListObjects("cs").ListColumns("WeekOf").Delete

Once we have deleted the column, we add it again as a blank column and change the name to “Week Of”.

Set myNewCol = Worksheets("Data").ListObjects("cs").ListColumns.Add
myNewCol.Name = "WeekOf"

After this we need to select the first cell of the column that contains the Date Time.

Worksheets("Data").ListObjects("cs").ListColumns("Date Time").Range.Cells(2).Select

Once we have selected the first cell of you Date Time column we then make use of the LastRowInOneColumn function to get the last row and create a range address. We use this range address to assign all the values contained in the Date Time column to an array.

tempStr = ActiveCell.Address
startCellRow = ActiveCell.Row
tempStr = tempStr & ":$" & Mid(Sheets("Data").ListObjects("cs").ListColumns("Date Time").Range.Cells(2).Address, 2, 1) & "$"

tempStr = tempStr & LastRowInOneColumn(Mid(Sheets(“Data”).ListObjects(“cs”).ListColumns(“Date Time”).Range.Cells(2).Address, 2, 1))
‘loading the range into the array
myarray = Range(tempStr).Value

Once we have loaded all the Date Time values into an array, we do a simple For loop to change the value in the array to the relevant Week Of

For i = LBound(myarray) To UBound(myarray)
myarray(i, 1) = Format(myarray(i, 1) - Weekday(myarray(i, 1), vbMonday) + 1, "ddd dd-mmm")
Next

We perform this operation on the same element and store the modified value in itself.
Once we have all these done, we need to define the Output range, that is where we need to the Week Of values to be stored. This is done by using the Range and Cell functions.

Set theRange = Range(Cells(startCellRow, Worksheets("Data").ListObjects("cs").ListColumns("WeekOf").Range.Column), Cells(UBound(myarray) + (startCellRow - 1), Worksheets("Data").ListObjects("cs").ListColumns("WeekOf").Range.Column))
'storing the values from our array to the WeekOf Column

theRange.Value = myarray

And lastly we assign all the values stored in the array to the new range address we have create above.

Download Demo File

Click here to download the demo file & use it to understand this technique.

What about you? Do you use them often? Please share your experiences, techniques & ideas using comments.

If you are new to VBA, Excel macros, go thru these links to learn more.

Join our VBA Classes

If you want to learn how to develop applications like these and more, please consider joining our VBA Classes. It is a step-by-step program designed to teach you all concepts of VBA so that you can automate & simplify your work.

Click here to learn more about VBA Classes & join us.

About Vijay

Vijay (many of you know him from VBA Classes), joined chandoo.org full-time this February. He will be writing more often on using VBA, data analysis on our blog. Also, Vijay will be helping us with consulting & training programs. You can email Vijay at sharma.vijay1 @ gmail.com. If you like this post, say thanks to Vijay.

Your email address is safe with us. Our policies

Written by Vijay Sharma
Tags: , , , , , ,
Home: Chandoo.org Main Page
? Doubt: Ask an Excel Question

21 Responses to “Using Arrays To Update Table Columns”

  1. Greg says:

    chandoo,
    I do a lot of raw data reference and then i add formulas on each data set as pirmary keys or UIDs for cross reference. I then use VBA with variables to gather my ranges and then apply the formula and then remove the formula. Are you saying i would be better off by putting my raw data as a table instead? which is faster?

  2. Bryan says:

    Hello,

    Instead of calculating the ranges by selecting a cell and calculating the last row you can use:

    tempStr = Worksheets(“Data”).ListObjects(“cs”).ListColumns(“Date Time”).DataBodyRange.Address

    This will give you the range and the same for the theRange array so that you can consolidate your code to:

    Sub UpdateWeek()
    Dim myarray As Variant
    Dim theRange As Range, startCellRow As Long
    Dim tempStr As String
    Dim myNewCol As ListColumn

    'If our column already exists then delete it
    On Error Resume Next
    Worksheets("Data").ListObjects("cs").ListColumns("WeekOf").Delete

    'adding our new column
    Set myNewCol = Worksheets("Data").ListObjects("cs").ListColumns.Add
    myNewCol.Name = "WeekOf"

    'loading the range into the array
    tempStr = Worksheets("Data").ListObjects("cs").ListColumns("Date Time").DataBodyRange.Address
    myarray = Range(tempStr).Value

    'Looping through the array and converting each element to the relevant Week format
    For i = LBound(myarray) To UBound(myarray)
    myarray(i, 1) = Format(myarray(i, 1) - Weekday(myarray(i, 1), vbMonday) + 1, "ddd dd-mmm")
    Next

    'Setting the range address for our output column

    Set theRange = Worksheets("Data").ListObjects("cs").ListColumns("WeekOf").DataBodyRange
    'storing the values from our array to the WeekOf Column

    theRange.Value = myarray
    End Sub

  3. Gleb says:

    Hi! You can do it even more easier with DateBodyRange. Look:

    Sub UpdateWeek()

    Dim myarray As Variant
    Dim myNewCol As ListColumn, DateTimeCol As ListColumn
    Dim i As Long

    ‘If our column already exists then delete it
    On Error Resume Next
    Worksheets(“Data”).ListObjects(“cs”).ListColumns(“WeekOf”).Delete

    ‘adding our new column
    Set myNewCol = Worksheets(“Data”).ListObjects(“cs”).ListColumns.Add
    myNewCol.Name = “WeekOf”

    ‘setting up datetime column
    Set DateTimeCol = Worksheets(“Data”).ListObjects(“cs”).ListColumns(“Date Time”)

    ‘making array
    myarray = DateTimeCol.DataBodyRange.Value

    ‘Looping through the array and converting each element to the relevant Week format
    For i = LBound(myarray) To UBound(myarray)
    myarray(i, 1) = Format(myarray(i, 1) – Weekday(myarray(i, 1), vbMonday) + 1, “ddd dd-mmm”)
    Next

    ‘send array to new column
    myNewCol.DataBodyRange.Value = myarray

    End Sub

  4. Gleb says:

    But I thing it will be more fast to calculete this column once with formula and then copy the whole column as values only.

  5. zurman says:

    GOOD HELP

  6. Andreas says:

    A non-VBA approach is to wrap the formula in the expression IF(YesNoCell=YES, theFormulaHere, “”).

    This let’s me turn on and off calculation using e.g. a dropdown cell named YesNoCell.

    This helps a great deal to keep my Monte Carlo simulation worksheets snappy.

  7. Rudra says:

    If we were to do this work by formula, what would be that for updating “WeekOf”column?

  8. Jason H says:

    Hi,

    I know you’re demonstrating how you can easily convert between a range and a variant array, but I thought you might like to see a simpler way of achieving the same:

    Option Explicit

    Sub UpdateWeek()
    Dim myNewCol As ListColumn
    Dim i As Long

    With ThisWorkbook.Worksheets(“Data”).ListObjects(“cs”)
    ‘If our column already exists then delete it
    On Error Resume Next
    .ListColumns(“WeekOf”).Delete
    On Error GoTo 0 ‘ restore normal error handling so if the remaining code fails we can debug it

    ‘adding our new column
    Set myNewCol = .ListColumns.Add
    myNewCol.Name = “WeekOf”
    End With

    ‘ use a formula to update the output (note using Excel 2010, different versions may require different formula)
    With myNewCol.DataBodyRange
    .Formula = “=TEXT([@[Date Time]]-WEEKDAY([@[Date Time]], 2)+1, “”Ddd dd-Mmm””)”
    .Copy
    .PasteSpecial xlPasteValues
    End With

    ‘ remove the marching ants
    Application.CutCopyMode = False

    End Sub

    • Jason H says:

      Doh, left the Dim i as Long in there when it’s not needed anymore; safe to remove that. Although it was naughty that it wasn’t declared in the original post ;)

      I’d recommend you always put Option Explicit at the top of any module you create. In fact you can make this automatic if you tick ‘Require Variable Declaration’ in the Tools->Options menu.

      Can I also just say, whilst on the subject of good VBA practice, using select, the selection object, or activecell for anything other than interacting with the user’s selections is inefficient and harder to maintain in code. Better to declare a Range object and set it to the area you want to interact with (or use ‘With… End With’ like I did above). It also replaces the need to construct address strings if used properly.

  9. Gino says:

    Weird – code appears to work on a different workbook. Columns created and names assigned to the columns but the cells under those columns come up blank. No error message – something simple I’m missing I’m sure! Any ideas?

    Thanks,
    Gino

    • Jason H says:

      The original code depends on the workbook the data is in being the active one when the code is run. When you press the button on the sheet this will be a safe assumption.

      Are you running it from a different location?

      • Gino says:

        thanks Jason – no, I’m running it from the same workbook. I basically swapped out the fake data with some other data, made sure the sheet and table names were the same, run the code and it appears to work but for whatever reason, the cells under the WeekOf or Month columns come up blank. Went in and formatted the Month column cells as “mmm – yyyy” too. Just blank cells…
        Hmmm….

        • Jason H says:

          Without seeing your data it’s difficult to say for sure, but it might be to do with your new “Date Time” column, can you check that it’s a represented as a real date in Excel, should be aligned to the right by default and have a number format of Date, or a custom one like “m/d/yyyy hh:mm:ss” which is the one used in the example file.

          If you’re date is aligned to the left then it might be text masquerading as a date. When the formula looks at it then it will error because it can’t convert it, but because “On Error Resume Next” was put in near the beginning of the code it will not show any error messages.

  10. Gino says:

    Thanks, Jason – it’s a real date in Excel. Commented out the On Error statement and get a “Out of Memory” error! Fails at “myarray=Range(tempStr).value. I’ve got 24GB of RAM onboard, running Win7 Excel 2010. Of course the data set is about 300k rows…

    Not sure what it is that would cause it to run out of memory as I’ve run massive VLOOKUPs and other macros on the data without issue. I’ll have to keep investigating – sure do appreciate your comments though!

    Cheers,
    Gino

    • Jason H says:

      Hi Gino,

      A very unusual error to receive. I’ve had a play around with the example file, even going so far as to extend the range down to 1048567 rows of data, and it still runs fine for me.

      It might be interesting in your test version to examine the ‘tempStr’ value. If you insert a line saying “MsgBox tempStr” just before the line you get the error on, the result might help. I’m wondering if the range created is even bigger than the single column it’s meant to be.

      Might be worth trying adding an extra column manually to your data with the following formula in it:

      =TEXT([@[Date Time]]-WEEKDAY([@[Date Time]], 2)+1, “Ddd dd-Mmm”)

      If any of the cells say #VALUE! or anything odd that’ll help you pick up errors too.

Leave a Reply