Here is a common problem. Imagine you are looking a complex spreadsheet, aptly titled “Corporate Strategy 2020.xlsx” which as 17 tabs, umpteen formulas and unclean structure. Whoever designed it was in insane hurry. The workbook has formulas like this, =SUM(Budget!A2:A30, 3600)+7925 .
It was as if Homer Simpson created it while Peter Griffin oversaw the project.
So how do you go about detecting all cells containing formulas with hard-coded values?
Alas, the usual methods fail
The usual methods to audit formulas are of no help here. Let’s see:
Show formulas (CTRL+`): Since we have way too many formulas, this approach requires a lot of squinting and gallons of coffee.
Go to special > Constants: This will only detect constant cells (ie input cells), but not cells containing formulas like =IF(2=2, Budget2014!A2, Budget2015!A2)
Trace Precedents: This can be used only for formulas that contain all hard-coded values (ex: SUM(1,2,3) will have no arrows, where as SUM(A1,A2, 7) will have some arrows
FORMULATEXT(): There is a new function called as FORMULATEXT() introduced in Excel 2013. This can tell us what is the formula in a cell. But we still need to develop additional logic to see if the formula text contains any constants.
Let’s build ‘Detect hard-coded formulas’ feature for Excel
The beauty of Excel is that, if there is something you can’t do with on screen features, you can build it. This is where VBA comes handy.
So we can create a hasConstants() user defined function that takes a cell as input and tells us TRUE or FALSE. True if the cell has constants (or hard-coded values) as formula parameters and False otherwise.
But what should be the logic for hasConstants()?
The process for detecting hard-coded values can be defined like this:
- Read the formula from left to right
- For each argument of the formula
- See if the argument is a valid reference or name
- If not, break the loop and return TRUE
- Return FALSE
How do we detect only the parameters?
There is no direct way to extract only the parameters of a formula. So what we do is we split the formula in to an array using the delimiter COMMA.
And we check each item of this array to see if it is
- a function call (like SUM, COUNT, VLOOKUP)
- a valid name or reference
What about nested functions?
The approach works the same way.
What about arithmetic, text or comparison operations?
For example, a formula like =A1+A2+17 should throw TRUE as it has hard-coded value.
So what we do is, we replace all such operators with delimiter (COMMA) before splitting the formula text.
We can consider +-*/%&><= as operators.
So how does the code look like?
Here is how it looks like:
Const COMMA = ","
Const OPERATORS = "+-*/%^&><="
Public Function hasConstants(thisCell As Range) As Boolean
'finds out if thisCell has a formula with constants in it
'i.e. hardcoded values
Dim formula As String, args As Variant, i As Long
Dim testRange As Range
formula = replaceOperators(Mid(thisCell.formula, 2))
args = Split(formula, COMMA)
For i = LBound(args) To UBound(args)
If Not (Len(args(i)) = 0 Or Right(args(i), 1) = "(" Or args(i) = ")") Then
'not a function or null, must be one of the parameters
'see if it is a valid name or reference
If Not nameExists(CStr(args(i))) Then
'name or reference doesn't exist, must be a constant / hard-coded value
hasConstants = True
Exit Function
End If
End If
Next i
End Function
Function replaceOperators(formula As String) As String
'replace operators such as +-/%^&>< with COMMA
Dim char As Long
For char = 1 To Len(OPERATORS)
formula = Replace(formula, Mid(OPERATORS, char, 1), COMMA)
Next char
formula = Replace(formula, "(", "(" & COMMA)
formula = Replace(formula, ")", COMMA & ")")
replaceOperators = formula
End Function
Function nameExists(name As String) As Boolean
'Check if a name or reference is valid
Dim testR As Range
On Error GoTo last
Set testR = Range(name)
nameExists = True
Set testR = Nothing
last:
End Function
How to use this code?
Simple. Copy this code and add it to your personal macros workbook. (Tip: how to setup personal macros workbook?)
Then use it in your complex workbook like this:
- To check if a cell contains hardcoded formulas, write =hasConstants(A1)
- To check if an entire range has hardcoded values,
- Select the range
- Go to home > conditional formatting > new rule
- Select formula type rule
- Type =hasConstants(top-left-cell relative reference)
- Format by filling a color or changing font style to detect easily
- Done
Does it work in all cases?
For most normal formulas this approach should work. I have tested it with various combinations and it seems to hold up good. I suggest you to double check the results for any type II errors (ie missed hard coded formulas) during initial few rounds.
Also, please share your observations in the comments so that we can improve this code.
Download Example Workbook
Click here to download this VBA code. After downloading the file, go to Module 1 (press ALT+F11) to see the code. Copy it or modify it as you see fit.
Your comments please?
I never had the need to check for hard-coded values until recently. But once I had that need, I found there is no simple way to do it. I believe this kind of check can be very useful for people in modeling, risk management or auditing positions.
What about you? How do you check for hard coded formulas? What methods do you use? Please share your thoughts and tips in the comments section.
More on spreadsheet auditing & risk management:
Check out below articles to learn more about how to audit spreadsheets and prevent risk of miscalculation:
- Spreadsheet risk management – 4 part series
- Show all names & references
- Go to special, a powerful way to navigate your workbooks
14 Responses to “How to Add your Macros to QAT or Excel toolbars?”
We have only just got excel 2007 so this is helping me navigate my way through the differences cheers.
For Macro's i always add a Command Button, rename it something obvious, change the colour of it and finally add the following to its View Code section.
Application.Run "MAcro1"
This way anyone opening the file knows what to do if i ever win the lottery and dont make it in 🙂
Hi,
Good article. But I have this problem.
1) Customized QAT with a macro. Macro name = MacroX
2) Runs OK from original location (e.g. C:\TestLoaction1\TestFile.xls)
3) Copy past file to new location (e.g. C:\TestLoaction2\TestFile.xls)
Menu button now fails:
Cannot run the macro "C:\TestLoaction1\TestFile.xls'!MacroX' The macro may not be available in this workbook...
Of course the code is there, and macros are enabled.
Could get it to work after deleting and recreating macro custom buttons. So have to re-assign macro to QAT button every time I move the file?
If I put a form button on he worksheet and assign the macro to that, it's location independent.
Any ideas?
Thanks
@Ron
What you have said is correct
Macros within a worksheet are stored within the worksheet and hence follow it.
Macros referenced by a button in the QAT or elsewhere are locaed in a file and if that file is moved the linkages don't follow.
The easiest way around this is to store all your macros in a location that doesn't move and is in fact reloaded everytime that Excel starts and that is called the Personal.xlsx/b file.
These are refered to several time at Chandoo.org or have a read of
http://www.rondebruin.nl/personal.htm
or
http://office.microsoft.com/en-us/excel-help/deploy-your-excel-macros-from-a-central-file-HA001087296.aspx
In Excel 2003 and prior versions, a button added to the Toolbar maintained a DYNAMIC link to the file (e.g. Personal.xlsb) holding the assigned macro, such that if the file was relocated for any reason (by using Excel's native Save As command rather than just moving it via Windows Explorer), the link between the button and the file was updated.
I expected the same to occur with Excel 2007+, but alas, Microsoft in their infinite wisdom have removed another feature useful to advanced users (just as they did by removing the ability to design your own buttons)!!
So having just done some reorganisation of my files, I now have to remove and recreate every friggin macro button on my QAT (I have lots) - what a pain in the proverbial!!
Hi Hui,
Thanks for the help, that's really useful.
1) The macros I'm adding are for one specific Excel application, so I really wanted the macros to follow the file
2) I didn't want to have to pass other files around too and have users installing those - either Personal.xlsx/b or as an Add-In.
3) I realise now that the QAT additions will appear for other Excel workbooks in which I don't want the macros available.
So, it looks like I need to keep it local, by using a button on the worksheet. Unless you can suggest any way of adding to menus just for a specific workbook.
Thanks again for your help. Great site, so I'll be signing up for the emails.
Ron
I know I'm a little late jumping on this post, but wondering if anyone knows how to add a UDF to the QAT? I've saved my UDF in my personal workbook, but it does not show up in my list when I choose Macros when customizing my QAT. Suggestions? Thanks!!
@Cheryl: UDFs cannot be accessed like Macros. You can use them from other macros or from worksheet cells as formulas...
@David: If you save your macros file and then install it as an add-in then it will be always available for you.
The instructions work great when you are creating a new file, and it is still open. I find that I can't access macros after I've saved a file as an xlam and closed it. When I reopen the xlam, either by browsing to it, or by having it set to open as an addin using Excel Options, the macros are no longer available in the macros list when I go to edit the QAT. Any way around that?
[...] Add this macro as a button to Quick Access Toolbar [...]
I need to create a button that will run a macro. Once you click the button it needs to open up a browser asking you to select a report/file. Once you select the file, it will run the macro on the selected file and then save it as a new report with a name and the current date. I created the macro to sort/modify the report but I do not know how to do what I mentioned above. I hope this makes sense.
I'm having trouble adding a macro to the QAT. I've done everything up to step 5 but my macro isn't showing up. What am I doing wrong?
[...] Add Macros to Quick Access Toolbar (works in Excel 2003 & above) [...]
Hi,
Thank you for the explanation. Very useful for a recent switcher from office 2003 to office 2010.
My follow-up question is: in Excel (or ppt) 2010, can you customize the macro button that you put in the QAT?
In office 2003, once you chose the custom button for your Macro, you could then edit pixel by pixel the said button.
For instance, I've created 2 Macros in PPT that are converting all my slides to either English or French language, so I'd like one button to show EN and the other FR... that would be more meaningful that any of the possible "custom" office 2010 buttons
I read all the post and one important aspect to the QAT was never mentioned. That is, you have a macro driven worksheet that you want to share with other. You have customized the QAT with two icons to run the macros (VBA programs in reality). However, when the others receive the workbook, the icons are no where to be found. It's my understanding those "customized buttons" have been saved to an outside file, Excel.qat. QUESTION: Could one simply attach that file to your email, along with the worksheet, and tell the recipients to copy that file to correct location on their computer - C:\Users\\AppData\Local\Microsoft\Office|\
Would the customize macro buttons then appear in the worksheet and, more importantly, work? Thanks for your thoughtfulness and thanks for well written instructions Chandoo!
MortW