Greater than, Less than, Equal to, Between assistance

[DonVman]

Hello,

I am trying to figure out how to write the following formula. I need this all combined into one formula.

Ex.
A1 = 5000

Is A1 less than or equal to 10000 then ".02"
Is A1 between 10001 and 100000 then ".04"
Is A1 between 100001 and 500000 then ".06"
Is A1 greater than or equal to 500001 then ".08"

I need the result to be filled in based on the value of cell A1
Not sure how to go about it.

 

[AlanSidman]

=IF(A1<=10000,0.02,IF(AND(A1>10000,A1<100000),0.04,IF(AND(A1>100000,A1<500000),0.06,0.08)))

 

[Hui]

=IF(A1<=10000,0.02,IF(A1<=100000,0.04,IF(A1<=500000,0.06,0.08)))

 

[DonVman]

=IF(A1<=10000,0.02,IF(A1<=100000,0.04,IF(A1<=500000,0.06,0.08)))

This did the trick. The previous code did not unfortunately. Many thanks to you both.

 

[Hui]

Alan's had a small issue with Less Than Equal signing

=IF(A1<=10000,0.02,IF(AND(A1>10000,A1<=100000),0.04,IF(AND(A1>100000,A1<=500000),0.06,0.08)))

 

[AlanSidman]

Thanks Hui.

Alan

 

[GraH - Guido]

or =LOOKUP(A2,{0,10001,100001,500001},{0.02,0.04,0.06,0.08})

 

[bosco_yip]

Or..........

=MATCH(A2,{0,10001,100001,500001})*0.02

or,

=SUM((A2>={0;10001;100001;500001})*0.02)

Regards
Bosco

 

[DonVman]

Very impressive responses. I really appreciate the varying ways to approach the solution. Many thanks to all.