Total and Weekly Average with formula

[Soleblue]

Good morning guys and good Sunday!

I would like to know if there is a formula that can help me with a sheet that I make every week to make a total and average (from Monday to Sunday) of what my animals have eaten.

In red I have put what I always do "manually".
I gave the example of only animal 1 but I would need all 3 animals.

Thank you very much to those who use their time to help me

 

[bosco_yip]

Try,

1] J2, copied down:

=SUMIFS(C:C,B:B,">="&H2,B:B,"<="&I2,A:A,F2)

2] K2, copied down:

=J2/7

Regards

 

[Soleblue]

Try,

1] J2, copied down:

=SUMIFS(C:C,B:B,">="&H2,B:B,"<="&I2,A:A,F2)

2] K2, copied down:

=J2/7

Thank you so much Bosco for your time
My excel is Italian
I translated =SOMMA.PIU.SE but it tells me there is an error. Maybe I need to correct some "." or some ","
I'm tryng and I tell you

 

[Soleblue]

I'm not succeeding, it gives me this error

"This formula is missing a reference to a defined range or name"

I don't understand where I'm wrong, have you tried it in your excel?

 

[pecoflyer]

Bosco's formula works great

=SOMMA.PIU.SE(C:C;B:B;">="&H2;B:B;"<="&I2;A:A;F2)

Do you need an accent over the U in PIU?

 

[bosco_yip]

I'm not succeeding, it gives me this error

"This formula is missing a reference to a defined range or name"

I don't understand where I'm wrong, have you tried it in your excel?

I enclosed a English version Excel file for your action.

 

[Soleblue]

Grazie!!!!!!!!!!!!!!! Yes, Yes ....I put the "U´´" but

I found the error. I copied your formula:
=SUMIFS(C:C,B:B,">="&H2,B:B,"<="&I2,A:A,F2)
but the problem was:
=SOMMA.PIÙ.SE(C:C,B:B,">="&H2,B:B,"<="&I2,A:A,F2)
that in your formula there was "," and I had to change it to ";"

Now I'll try to put everything in the original file and I'll tell you in a few minutes
thank you for your time

 

[Soleblue]

It's perfect, you saved me a lot of time and above all eliminated the margin for errors.

Thank you very much and I love Excel more every day!

 

[pecoflyer]

=SOMMA.PIÙ.SE(C:C,B:B,">="&H2,B:B,"<="&I2,A:A,F2)
that in your formula there was "," and I had to change it to ";"

I indicated that in post #5. No idea if you read it. BTA I'm not an XL Ninja...

 

[p45cal]

A pivot table will get you this without formulae. See attached.

 

[Peter Bartholomew]

The is an Excel 365 solution that exploits the regularity of the input date to manipulate the dataset as arrays. The bad news is that the formula is something of a monster: the good news is that there is only one cell with any formula!

= LET(
    sortedByNombre,  SORTBY(ComidoTbl, Nombre),
    animalNombres,   CHOOSECOLS(sortedByNombre,1),
    animalNombre,    TAKE(WRAPROWS(animalNombres, 7),,1),
    days,            WRAPROWS(CHOOSECOLS(sortedByNombre, 2), 7),
    period,          CHOOSECOLS(days,{1,-1}),
    sortedComido,    CHOOSECOLS(sortedByNombre, 3),
    amountsByPeriod, WRAPROWS(sortedComido, 7),
    totalsByPeriod,  BYROW(amountsByPeriod, SUMλ),
    averageByPeriod, BYROW(amountsByPeriod, AVERAGEλ),
    SORT(HSTACK(animalNombre, period, totalsByPeriod, averageByPeriod), 2)
  )

[my apologies for introducing so much English into the formula]