Loop through items in drop down of a field on website

[YasserKhalil]

Hello everyone

I have this URL
https://www.sptv.ch/trainersuche

There is a field of region and I need a way to loop through the regions existed in this drop down menu
Thanks advanced for help

 

[Marc L]

Hi !

It first depends on which way you use to read the URL !
As I can't see any code …
Easy just by reading webpage code and
using webbrowser inner inspector tool.
​

 

[shahin]

Run this script. It will fetch you all the "areas of application" and "region" from two drop down menus.

Sub Dropdown_Items()
    Dim IE As New InternetExplorer, html As HTMLDocument
    Dim posts As Object, post As Object, elem As Object

    With IE
        .Visible = True
        .navigate "https://www.sptv.ch/trainersuche"
        Do Until .readyState = READYSTATE_COMPLETE: Loop
        Set html = .document
    End With
  
    Application.Wait (Now() + TimeValue("00:00:005"))
    Set posts = html.getElementsByClassName("upme-p upme-search-p upme-multiselect-p")
  
    Set post = posts(0).getElementsByTagName("select")(0).getElementsByTagName("option")
    For x = 0 To post.Length - 1
        Cells(x + 1, 1) = post(x).innerText
    Next x
  
    Set elem = posts(1).getElementsByTagName("select")(0).getElementsByTagName("option")
    For y = 0 To elem.Length - 1
        Cells(y + 1, 2) = elem(y).innerText
    Next y
  
    IE.Quit
End Sub

Reference to add to the library:

1. Microsoft Internet Controls
2. Microsoft Html Object Library

 

[shahin]

Or with xmlhttp request (the fastest method):

Sub WebData()
    Dim http As New XMLHTTP60, html As New HTMLDocument
    Dim posts As Object, post As Object, elem As Object

    With http
        .Open "GET", "https://www.sptv.ch/trainersuche/", False
        .send
        html.body.innerHTML = .responseText
    End With
    Set posts = html.getElementsByClassName("upme-p upme-search-p upme-multiselect-p")

    Set post = posts(0).getElementsByTagName("select")(0).getElementsByTagName("option")
    For x = 0 To post.Length - 1
        Cells(x + 1, 1) = post(x).innerText
    Next x

    Set elem = posts(1).getElementsByTagName("select")(0).getElementsByTagName("option")
    For y = 0 To elem.Length - 1
        Cells(y + 1, 2) = elem(y).innerText
    Next y
End Sub

Reference to add to the library:

1. Microsoft html Object Library
2. Microsoft xml, v6.0 or whatever version you have

 

[YasserKhalil]

That's amazing Shahin. Thank you very much for great and awesome help
Best Regards