Extract Specific text from a cell

[Ady Zavala]

Hello.
I am trying to extract 2 specific words from a list.
As you can see, in Colum B, I have a list with names. In this list, there are 2 key words I am looking for: HRG and Elite.


In E1 and G1, I would like to show how many HRG and ELITE are there is total:
In other words, from list in column B, I need to know how many are there with the word "HRG" and how many "Elite" there are.


At the end it should look like this:

Is it possible to be done?

Thank you so much in advance.

 

[vletm]

Could You use something like this?
cell E1 =ROWS(FILTER(B3:B12,LEFT(B3:B12,3)="HRG",0))
cell G1 =ROWS(FILTER(B3:B12,LEFT(B3:B12,5)="Elite",0))

 

[Ady Zavala]

I used the formula and it displays the following message: That function isn't valid.I am using Microsoft Office 2019

 

[p45cal]

Does it have to be vba?
In cell E1:
=SUM(--ISNUMBER(SEARCH("HRG",B3:B12)))
This is a case-insensitive search, for a case-sensitive version change SEARCH to FIND
Depending on your version of Excel, you may have to commit this formula to the cell with Ctrl+Shift+Enter rather than the usual Enter.
The ELITE count would be in cell G1:
=SUM(--ISNUMBER(SEARCH("ELITE",B3:B12)))

If you have a more recent version of Excel you can use REGEXTEST and it will give a more correct result (it won't count elite in preliterate):
SUM(--REGEXTEST(B3:B12,"\bELITE\b",1))
which is case-insensitive, to make it case-sensitive, change the 1 to a 0.

 

[Ady Zavala]

I have tried
=SUM(--ISNUMBER(SEARCH("HRG",B3:B12)))
=SUM(--ISNUMBER(SEARCH("ELITE",B3:B12)))

=SUM(--ISNUMBER(FIND("HRG",B3:B12)))
=SUM(--ISNUMBER(FIND("ELITE",B3:B12)))

and none worked.

It is not necessary to be VBA.

 

[Ady Zavala]

Wait,
I worked
I used Ctrl+Shift+Enter rather than the usual Enter
and it worked perfectly.

 

[Ady Zavala]

Thank you @vletm and @p45cal