excel formula

[Hyxt05]

who can help me with the formula in the attached file

 

[ETAF]

no attached file
perhaps say what you what to do - and include that in the title
otherwise - many people may view but not be able to help
also what version of excel do you want this to work in

 

[Hyxt05]

thank you for the reply. i was trying to use countif function to count range of values (<24hrs and >24hrs). but when i insert the formula it only count the cell values for < and returns 0 for the >.

 

[ETAF]

try
=ROWS(FILTER(A2:A10,A2:A10="<24hrs"))
and
=ROWS(FILTER(A2:A10,A2:A10=">24hrs"))

 

[Hyxt05]

it worked, thank you so much

 

[ETAF]

you are welcone

 

[Peter Bartholomew]

who can help me with the formula in the attached file

Other approaches:
The first using FILTER, as per @ETAF ,

= COUNTA(FILTER(duration, duration="<24hrs"))
= COUNTA(FILTER(duration, duration=">24hrs"))

The next using "=" to override the inequality operators (reducing them to text)

= COUNTIFS(duration, "=<24hrs")
= COUNTIFS(duration, "=>24hrs")

Finally, performing a wildcard match, using "~" as an escape character

= COUNTIFS(duration, "~<*")
= COUNTIFS(duration, "~>*")

 

[pecoflyer]

Simply

=COUNTIF(A2:A10;"="&"<24hrs") and =COUNTIF(A2:A10;"="&">24hrs")

Your syntax was incorrect

 

[AliGW]

These work:

=SUMPRODUCT((A2:A10=E2)*1)
=SUMPRODUCT((A2:A10=F2)*1)