create submit button in excel

[Indranee]

Hi,

Please help to create submit button in excel to send email with the attached excel file.

Thank you.

 

[Kellis]

Hi Indranee,

Here is a code I use you just need to create the button assign the code. Just change the sheet names etc.

Sub Mail_ActiveSheet()
'Working in Excel 2000-2016
'For Tips see: http://www.rondebruin.nl/win/winmail/Outlook/tips.htm
    Dim FileExtStr As String
    Dim FileFormatNum As Long
    Dim Sourcewb As Workbook
    Dim Destwb As Workbook
    Dim TempFilePath As String
    Dim TempFileName As String
    Dim OutApp As Object
    Dim OutMail As Object
    Dim Tom As Date
    With Application
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    Set Sourcewb = ActiveWorkbook
   

    'Copy the ActiveSheet to a new workbook
    ActiveSheet.Copy
    Set Destwb = ActiveWorkbook
   
  'Delete all Objects except Comments
    On Error Resume Next
    ActiveSheet.DrawingObjects.Visible = True
    ActiveSheet.DrawingObjects.Delete
    On Error GoTo 0
   
    '~~>To Hide Rows 2 to 4
    'Rows("2:4").EntireRow.Hidden = True
   
    '~~>Locks cells
   
    Worksheets("Sheet Name").Protect UserInterfaceOnly:=True
   
    '~~>Changes Title
    Application.Worksheets("Sheet Name").Range("A1") = "New Title"

   
    'Determine the Excel version and file extension/format
    With Destwb
        If Val(Application.Version) < 12 Then
            'You use Excel 97-2003
            FileExtStr = ".xls": FileFormatNum = -4143
        Else
            'You use Excel 2007-2016
            Select Case Sourcewb.FileFormat
            Case 51: FileExtStr = ".xlsx": FileFormatNum = 51
            Case 52:
                If .HasVBProject Then
                    FileExtStr = ".xlsm": FileFormatNum = 52
                Else
                    FileExtStr = ".xlsx": FileFormatNum = 51
                End If
            Case 56: FileExtStr = ".xls": FileFormatNum = 56
            Case Else: FileExtStr = ".xlsb": FileFormatNum = 50
            End Select
        End If
    End With

    '    'Change all cells in the worksheet to values if you want
    With Destwb.Sheets(1).UsedRange
    .Cells.Copy
    .Cells.PasteSpecial xlPasteValues
    .Cells(1).Select
    End With
    Application.CutCopyMode = False

    'Save the new workbook/Mail it/Delete it
    TempFilePath = Environ$("temp") & "\"
    TempFileName = Sourcewb.Name & " " & Format(Now, "dd-mmm-yy h-mm")

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    With Destwb
        .SaveAs TempFilePath & TempFileName & FileExtStr, FileFormat:=FileFormatNum
        On Error Resume Next
        With OutMail
            .To = "add e-mail address"
            .CC = ""
            .BCC = ""
            .Subject = "Add Title"
            .Body = "Good morning," & vbNewLine & vbNewLine & "Please see attached ***" & Format(Date + 1, " dd mmmm yyyy.") & vbNewLine & vbNewLine _
            & "If you have any queries regarding this e-mail please contact ****." _
            & vbNewLine & "Regards," & vbNewLine & vbNewLine & "the Contact."
            .Attachments.Add Destwb.FullName
            'You can add other files also like this
            '.Attachments.Add ("C:\test.txt")
          'Add send using account to send from group account
           
            'SendUsingAccount is new in Office 2007
        'Change Item(1)to the account number that you want to use
        .SendUsingAccount = OutApp.Session.Accounts.Item(1)

           
            .Send  'or use .Display
        End With
        On Error GoTo 0
        .Close savechanges:=False
    End With

    'Delete the file you have send
    Kill TempFilePath & TempFileName & FileExtStr

    Set OutMail = Nothing
    Set OutApp = Nothing

    With Application
        .ScreenUpdating = True
        .EnableEvents = True
    End With
End Sub

 

[Indranee]

Hi Kellis,

I am not sure. Is I need to copy all or how?

Please help. I am blank

 

[Belleke]

Hi,
Working example see attached.
In the choose sheet select name you want to mail to. (Select Yes)
Multiple names are possible.
Sheet with the name Attachement wil be send as attachement.
See also https://www.rondebruin.nl/win/s1/outlook/mail.htm.
Post an example workbook if you can't make it work or if you want another solution