adding extra minutes to time

[Belleke]

I have a result in a cell formated as uu:mm, for example 3:00, Then I need to add 3 times 10 minutes in another cell result should be 3:30 in a another cell. If the first cell is 2:30 then the result should be 2:55 (2 times 10 minutes and 1 time 5 minutes)
The goal is when somebody works on a holiday they get 10 minutes extra for every worked hour.
thanks

 

[p45cal]

when somebody works on a holiday they get 10 minutes extra for every worked hour

So, 30 mins gets them an extra 5 minutes, does 15 minutes get them an extra 2.5 minutes?
Does 6 minutes get them an extra minute?

 

[p45cal]

If so then if C2 contains your original time, try:
=C2*(1+1/6)
formatted the same way.

Edit: This can be shortened to =C2*7/6

 

[Belleke]

Yes,this is what I am looking for.
Except there are 3 more: 9 mintes,18 minutes and 60 minutes
They can be separate formulas, they don't have to be combined.
Extra info: the hours are round up (on 5 minutes)

 

[p45cal]

Except there are 3 more: 9 mintes,18 minutes and 60 minutes

I don't know what you mean by this?

the hours are round up (on 5 minutes)

rounded before adding time, or after adding time?

 

[Belleke]

rounded before adding time, or after adding time?

Rounded before adding time

I don't know what you mean by this?

You gave me the perfect formula to add 10 minutes extra,I need the same formulas for 9,18 and 60 minutes
as example, with your given formula if the cell is 2:00, the end result is 2:20 (2 times 10 minutes) what is 100% correct but I want also for example to add 60 minutes, if the cell is 2:00 the endresult should be 4:00 (2 times 60 minutes)
hope it is more clear.

 

[p45cal]

for 9 minutes per hour:
=C2*69/60
(see how that 69 is made up of 60 minutes + 9 minutes?)

For 18 minutes per hour:
=C2*(60+18)/60
shortened to:
=C2*78/60

For 60 minutes per hour
=C2*(60+60)/60
becomes
=C2*120/60
becomes
=C2*2

Rounded before adding time

In all these, if you want to round up to the nearest 5 minutes, replace C2 in the formulae with
CEILING(C2,TIME(0,5,0))
so for example:
=CEILING(C2,TIME(0,5,0))*69/60

 

[Belleke]

Perfect, thank you so much for your time.

 

[Peter Bartholomew]

Same formula repackaged
= AugmentedHoursλ(holidayHours, 10)
where
AugmentedHoursλ

= LAMBDA(holidayHrs, extraMinutes,
    LET(
      rounded,  CEILING(holidayHrs, TIME(0, 5, 0)),
      rounded * TIME(1, extraMinutes, 0) / TIME(1, 0, 0)
    )
  )

 

[Belleke]

Hi Peter,
Thank you for your contribution