Combine this formula so that I get only result when cell is not Blank.

[Belleke]

=IF(EXACT(A2,UPPER(A2)),"Upper Case",IF(EXACT(A2,LOWER(A2)),"Lower Case","Upper and Lower Case"))

Now I get Upper Case when cell is empty.

 

[p45cal]

=IF(ISBLANK(A2),"",IF(EXACT(A2,UPPER(A2)),"Upper Case",IF(EXACT(A2,LOWER(A2)),"Lower Case","Upper and Lower Case")))

?

 

[Belleke]

Thanks p45cal, works perfect.
@ vletm, sorry for the mistake, my bad.

 

[GraH - Guido]

IFS might make it a bit easier to understand.
=IFS(ISBLANK(A2), "", EXACT(A2)=upper(A2), "upper case", EXACT(A2) = lower(A2), "lower case", "Mix case")

 

[p45cal]

IFS might make it a bit easier to understand.
=IFS(ISBLANK(A2), "", EXACT(A2)=upper(A2), "upper case", EXACT(A2) = lower(A2), "lower case", "Mix case")

Almost;

=IFS(ISBLANK(A2), "", EXACT(A2,UPPER(A2)), "upper case", EXACT(A2,LOWER(A2)), "lower case", TRUE,"Mix case")

 

[GraH - Guido]

Almost;

=IFS(ISBLANK(A2), "", EXACT(A2,UPPER(A2)), "upper case", EXACT(A2,LOWER(A2)), "lower case", TRUE,"Mix case")

Yes, I forgot the true part, that happens when you reply with your smartphone and you don't have excel on it. Not that smart

 

[bosco_yip]

Almost;

=IFS(ISBLANK(A2), "", EXACT(A2,UPPER(A2)), "upper case", EXACT(A2,LOWER(A2)), "lower case", TRUE,"Mix case")

Another approach, using Find instead of Exact function

=IF(A2="","",IFERROR(IF(FIND(A2,UPPER(A2)&LOWER(A2))=1,"Upper","Lower"),"Mix")&" case")

 

[p45cal]

Another approach, using Find

beware with items in column A like Aa, MAma, CANcan
Can be mitigated with the likes of =IF(A2="","",IFERROR(IF(FIND(A2,UPPER(A2)&"¬"&LOWER(A2))=1,"Upper","Lower"),"Mix")&" case")
I'll get my coat…

 

[bosco_yip]

beware with items in column A like Aa, MAma, CANcan
Can be mitigated with the likes of =IF(A2="","",IFERROR(IF(FIND(A2,UPPER(A2)&"¬"&LOWER(A2))=1,"Upper","Lower"),"Mix")&" case")
I'll get my coat…

Thank you for your great catch.