# find unique names

#### tanwarrahul1988

##### Member
Hello Guys I am finding a formula to find unique names but not show the name which contains a number like this "6. Sandhya Enterprises"
So, when I try this below formula it shows the below example results. Pls help me guys
=UNIQUE(SORT(FILTER(D2:D73,D2:D73<>"")))

Examples :

6. Sandhya Enterprises
7. Nirmal Enterprises
9. Sunny
Dilip
Party
Self A/C

#### herofox

##### Active Member
Please upload an excel file showing what is required accurately in order to avoid wasting the time of everyone who looks at your participation without benefit or importance.

#### tanwarrahul1988

##### Member
now I attach the file. Required data in J coloumn

#### Attachments

• 16.2 KB Views: 7

#### p45cal

##### Well-Known Member
Looks for first character a number:
=UNIQUE(SORT(FILTER(D2:D73,(D2:D73<>"")*(NOT(ISNUMBER((VALUE(LEFT(D2:D73,1)))))))))

#### John Jairo V

##### Well-Known Member
Hi to all!
Another option could be:
PHP:
``=SORT(UNIQUE(TOCOL(FILTER(D2:D72,ISERR(-LEFT(D2:D72))),1)))``
Blessings!

#### tanwarrahul1988

##### Member
Hi to all!
Another option could be:
PHP:
``=SORT(UNIQUE(TOCOL(FILTER(D2:D72,ISERR(-LEFT(D2:D72))),1)))``
Blessings!
when i copy and paste your formula its showing "#NAME?"

#### tanwarrahul1988

##### Member
Looks for first character a number:
=UNIQUE(SORT(FILTER(D2:D73,(D2:D73<>"")*(NOT(ISNUMBER((VALUE(LEFT(D2:D73,1)))))))))
this formula works, thanks buddy, but one last help can you also remove "party" name in this formula

#### pecoflyer

##### Well-Known Member
Any other requirements before we go any further?

#### tanwarrahul1988

##### Member
No sir only that was tha last

#### p45cal

##### Well-Known Member
=UNIQUE(SORT(FILTER(D2:D73,(D2:D73<>"")*(D2:D73<>"Party")*(NOT(ISNUMBER((VALUE(LEFT(D2:D73,1)))))))))

#### Peter Bartholomew

##### Well-Known Member
This is the @p45cal solution. Only the styling is different. Firstly, I do not ever use direct cell references, I avoid the practice of relative referencing and I use the locally-scoped LET variable to expand the formula to avoid nesting and explain the intermediate calculations until there is no further benefit in terms of readability. Doing all that, I got
Code:
``````= LET(
isNumbered?, ISNUMBER(VALUE(LEFT(party,1))),
isNonBlank?, party<>"",
isData?,     party<>"party",
criterion?,  isData? * isNonBlank? * NOT(isNumbered?),
matches,     FILTER(party,criterion?),
SORT(UNIQUE(matches))
)``````
The only thing I haven't done here is encapsulate the formula using LAMBDA to conceal the unnecessary detail. That would have given
Code:
``= ListPartiesλ(party)``
Code:

#### tanwarrahul1988

##### Member
Thanks a lot, all of you guys. Best forum on internet. once again thanks a lot guys