Count except Sa and Su.

[Belleke]

Hi see the picture
I would like a formula that counts how many times 25, except saterday and sunday (Za, Zo)

Thanks

 

[vletm]

As with Your sample, but with COUNTIF-formula.

 

[GraH - Guido]

Hi Belleke, I think you are after (in your case)
=AANTALLEN.ALS($B7:$AF7;25;$B$6:$AF$6;"<>"&{"za";"Zo"})

 

[Ajesh]

Not sure if the weekday names in row 2 are text or dates formatted as day names but this should help. Fill formula down as required

In case weekday are text:
=SUMPRODUCT((B$2:AF$2<>"Sa")*(B$2:AF$2<>"Su")*($B3:$AF3=25))

In case weekday are underlying dates:

=SUMPRODUCT((WEEKDAY(B$2:AF$2)<6)*($B3:$AF3=25))

Or if you have dates in row 1:

=SUMPRODUCT((WEEKDAY(B$1:AF$1)<6)*($B3:$AF3=25))

BR/Ajesh

 

[bosco_yip]

Or,

=COUNTIFS(B7:AF7,25,B$5:AF$5,"<>za",B$5:AF$5,"<>zo")

Regards
Bosco

 

[Belleke]

I tested the formula of Grah Guido and is working fine.
A have another question for the same file.
I am looking for a formula that sums the values except Sa en Su.
Everybody thanks for thelp

 

[vletm]

Belleke
as from Your picture case:
prev was =COUNTIF(
test now =SUMIF(

 

[GraH - Guido]

Hi @Belleke,

It is actually not working. I should have evaluated my formula, but being so pleased it seemed to work - wanted to do a Bosco trick, I should know better then that - I kinda rushed to publish. I apologize.
It just worked because of the merged cells. So it only evaluates "za".

Please do use the given alternatives that are correctly working.

So for the sum use
=SOMMEN.ALS(B7:AF7;B$5:AF$5;"<>za";B$5:AF$5;"<>zo")

 

[Ajesh]

I tested the formula of Grah Guido and is working fine.
A have another question for the same file.
I am looking for a formula that sums the values except Sa en Su.
Everybody thanks for thelp

Small correction to the count formula above (Considering week start from Monday):

=SUMPRODUCT((WEEKDAY(B$1:AF$1,2)<6)*($B3:$AF3=25))

Now to sum values other than weekends:

=SUMPRODUCT((WEEKDAY(B$1:AF$1,2)<6)*($B3:$AF3=25)*($B3:$AF3))

BR/Ajesh